Topic: take attribute and create hyperlink and attach to block

[Drafter X]

Hey all,
I don't normally beg code, but this is one that probably wouldn't be to hard for you gurus and a lot of people would be able to make use of.  I cant code my way out of a paper bag so its beyond me though.

What I would like to do is have a command that lets you click on a section marker that has attributes (detail number and sheet). It would read the sheet attribute and create a hyperlink on the block to pop to that sheet view.  It would just be a nice touch for navigating once these things are dwfs for clients.  I did a search but didn't find this and as most of my work for clients doesn't use SSM that option isn't available.

Any thoughts on how to accomplish this?  I can probably cludge something together given a starting point, any advice?

[Drafter X]

Thanks Mark,

Also, I do know how to do this manually with the hyperlink command, would just love to be able to do it automatically. I tried with diesel but I cant pull the attribute out of the block with diesel.

[kruuger]

Hey all,
I don't normally beg code, but this is one that probably wouldn't be to hard for you gurus and a lot of people would be able to make use of.  I cant code my way out of a paper bag so its beyond me though.

What I would like to do is have a command that lets you click on a section marker that has attributes (detail number and sheet). It would read the sheet attribute and create a hyperlink on the block to pop to that sheet view.  It would just be a nice touch for navigating once these things are dwfs for clients.  I did a search but didn't find this and as most of my work for clients doesn't use SSM that option isn't available.

Any thoughts on how to accomplish this?  I can probably cludge something together given a starting point, any advice?

when you click hyperlink you want to navigate only to correct layout or viewport with detail number ?
with second option it might be a problem. we can refer to detail marker but not to viewport (we don't know where it is).
kruuger

[Drafter X]

Easier then that, just want to go to the sheet.  The person can find the correct detail easy enough with that.  So I only need the SHEET attribute out of the block and have that as the target.

I can do it manually with the hyperlink command of course, just looking to automate it.

[kruuger]

Easier then that, just want to go to the sheet.  The person can find the correct detail easy enough with that.  So I only need the SHEET attribute out of the block and have that as the target.

I can do it manually with the hyperlink command of course, just looking to automate it.

give me your block name, attribute tags.
it shouldn't be a big problem (i hope)
k.

[ronjonp]

When you refer to "sheet" do you mean the layout tabs? A sample drawing may help 

[Drafter X]

ah sorry, yes, just the layout tab name.  I'll get a sample drawing together and get it up when I can.

[kruuger]

ah sorry, yes, just the layout tab name.  I'll get a sample drawing together and get it up when I can.

try this one:

Code - Auto/Visual Lisp: [Select]

1. (defun c:HYP (/ BLK TAG ss n ob# sh al)
2.   (vl-load-com)
3.   (setq BLK "BL-PLAN-RIGHT" ; change to correct block name
4.         TAG "PAGE-NR"       ; change to correct attribute tag
5.   )
6.   (if
7.     (setq ss
8.       (ssget "_X"
9.         (append
10.          '((0 . "INSERT"))
11.           (list
12.             (cons 2 (strcat "`*U*," BLK))
13.           )
14.         )
15.       )
16.     )
17.     (progn
18.       (repeat (setq n (sslength ss))
19.         (if
20.           (wcmatch
21.             (strcase
22.               (vla-Get-EffectiveName
23.                 (setq ob#
24.                   (vlax-ename->vla-object
25.                     (ssname ss (setq n (1- n)))
26.                   )
27.                 )
28.               )
29.             )
30.             (strcase BLK)
31.           )
32.           (progn
33.             (setq sh (LM:vl-GetAttributeValue ob# TAG))
34.             (if (member sh (layoutlist))
35.               (vla-Add
36.                 (vla-Get-Hyperlinks ob#)
37.                 "" "" (strcat "," sh)
38.               )
39.               (setq al (cons (strcat sh "\n") al))
40.             )
41.           )
42.         )
43.       )
44.       (if al
45.         (alert
46.           (strcat
47.             "Wrong markers:\n"
48.             (apply 'strcat al)
49.           )
50.         )
51.       )
52.     )
53.     (princ "\n** No section markers in drawing **")
54.   )
55.   (princ)
56. )
57. ;;----------------=={ Get Attribute Value }==-----------------;;
58. ;;                                                            ;;
59. ;;  resurns the attribute value associated with the specified ;;
60. ;;  tag, within the supplied block, if present.               ;;
61. ;;------------------------------------------------------------;;
62. ;;  Author: Lee Mac, Copyright © 2010 - www.lee-mac.com       ;;
63. ;;------------------------------------------------------------;;
64. ;;  Arguments:                                                ;;
65. ;;  block - VLA Block Reference Object                        ;;
66. ;;  tag   - Attribute TagString                               ;;
67. ;;------------------------------------------------------------;;
68. ;;  resurns:  Attribute TextString, else nil                  ;;
69. ;;------------------------------------------------------------;;
70. (defun LM:vl-GetAttributeValue ( block tag )
71.     (setq tag (strcase tag))
72.     (vl-some
73.         (function
74.             (lambda ( attrib )
75.                 (if (eq tag (strcase (vla-get-Tagstring attrib)))
76.                     (vla-get-TextString attrib)
77.                 )
78.             )
79.         )
80.         (vlax-invoke block 'GetAttributes)
81.     )
82. )

change block name and tag as needed.
k.

[Drafter X]

Lee, just.. WOW, that does all of them in a mass strike, that's amazing.
Does exactly what I was after only even better, I thankee.

Do you mind if I point people to this thread? I have a feeling a lot of folks would find this very useful.

[kruuger]

Lee, just.. WOW, that does all of them in a mass strike, that's amazing.
Does exactly what I was after only even better, I thankee.

Do you mind if I point people to this thread? I have a feeling a lot of folks would find this very useful.

feel free to use, copy, modify, update...
kruuger

[Lee Mac]

Lee, just.. WOW, that does all of them in a mass strike, that's amazing.

All credit to Kruuger 

[Drafter X]

Ah sorry, you name showed there in the code, I was rather blown away. Kruuger, you indeed rock, but most of the people here tend to rock. 

[kruuger]

Ah sorry, you name showed there in the code, I was rather blown away. Kruuger, you indeed rock, but most of the people here tend to rock. 

happy to help 
k.

[Drafter X]

Shared it on my site with credit to Kruuger and the swamp.
http://www.brega-tech.com/?i=downloads
 

[krampaul82]

Ah sorry, you name showed there in the code, I was rather blown away. Kruuger, you indeed rock, but most of the people here tend to rock. 

Agreed