Topic: 3D Polyline Editing

[demesne]

Hi

I'm wondering if anyone has any ideas how I can speed up the follwing process:

The attached dwg shows the following in a graphical manner, by the way.

1 - Take a 3D polyline representing a curve in a road.  This is topographical survey data with too few vertices to accurately show the true road line (vertices currently only at each 'surveyed point').
2 - Create a spline (cubic, zero fit tolerance) through each 3D polyline vertex.
3 - Break the spline at each 3D polyline vertex. This is to ensure that the end result has a vertex at each 'surveyed point'.
4 - Use pedit to convert the splines to 3d polylines.
5 - Join the resulting 3D polyline to form one string.

The reason I convert the spline is to enable the drawing to be used by an earthworks package when creating surface models.

I've tried CAB's BreakAll routines to automatically break the spline but this wasn't written to do what I'm trying to do and so misses some of the breaks.

I'm hoping that one of you will have a routine that does the above with one click.  .....I live in hope. 


Regards
Demesne

[ribarm]

I think that step "3. Break spline" is unnecessary - you create spline that has knots at each 3dpolyline vertex... Consider segmentation of spline curve with points between knots including knots and new object 3dpolyline should have these vertices too...

M.R.

[demesne]

Unfortunately that doesn’t happen. Pedit doesn’t need to use the knots as long as it is creating a 3d polyline that is true to the precision you specify. So, it ignores them.

[ribarm]

I thought that you don't need to pedit spline... I thought that you want to create list of vertices from spline that have precision segmentation you specify within lisp and which includes knots as start-end segment vertices (you would have precision within each segment). With that new list of vertices you can directly create new 3dpolyline...

M.R.

[demesne]

Ah I see.  But I have hundereds of lines to edit and not much idea of how to do what you suggest. 

[ribarm]

I've made this quick...

Code - Auto/Visual Lisp: [Select]

1. (defun c:3dpl-seg ( / OSM 3DPL 3DPLA COORDS ENPAR ENPT INCRPAR K M N PT PT11 PTLST PTLST11 PTN PTNEWLST PTNLST SPL STPAR STPT )
2.   (vl-load-com)
3.   (setq osm (getvar 'osmode))
4.   (setvar 'osmode 0)
5.   (vl-cmdf "osnap" "off")
6.   (prompt "\nPick 3dpolyline to perform curve segmentation between its vertices")
7.   (setq 3dpl (ssname (ssget "_+.:E:S" '((0 . "POLYLINE") (100 . "AcDbEntity") (100 . "AcDb3dPolyline"))) 0))
8.   (setq 3dplA (vlax-ename->vla-object 3dpl))
9.   (setq coords (vlax-safearray->list (vlax-variant-value (vla-get-coordinates 3dplA))))
10.   (repeat (/ (length coords) 3)
11.     (setq pt (list (car coords) (cadr coords) (caddr coords)))
12.     (setq coords (cdddr coords))
13.     (setq ptlst (cons pt ptlst))
14.   )
15.   (setq ptlst (reverse ptlst))
16.   (foreach pt ptlst
17.     (setq pt11 (cons 11 pt))
18.     (setq ptlst11 (cons pt11 ptlst11))
19.     (setq ptlst11 (cons (cons 41 1.0) ptlst11))
20.   )
21.   (setq ptlst11 (reverse ptlst11))
22.   (setq spl (entmakex (append '((0 . "SPLINE") (100 . "AcDbEntity") (100 . "AcDbSpline") (210 0.0 0.0 1.0) (70 . 12) (71 . 2) (72 . 6)) (list (cons 73 (length ptlst)) (cons 74 0) (cons 42 1.0e-010) (cons 43 1.0e-010) (cons 40 0.0) (cons 40 0.0) (cons 40 0.0) (cons 40 1.0) (cons 40 1.0) (cons 40 1.0)) ptlst11 )))
23.   (initget 6)
24.   (setq n (getint "\nInput segmentation precision per segment : "))
25.   (setq k -1)
26.   (setq ptnewlst '())
27.   (repeat (- (length ptlst) 1)
28.     (setq ptnlst nil)
29.     (setq stpt (nth (setq k (1+ k)) ptlst))
30.     (setq enpt (nth (+ k 1) ptlst))
31.     (setq stpar (vlax-curve-getparamatpoint spl stpt))
32.     (setq enpar (vlax-curve-getparamatpoint spl enpt))
33.     (setq incrpar (/ (- enpar stpar) (float n)))
34.     (setq m -1)
35.     (repeat n
36.       (setq ptn (vlax-curve-getpointatparam spl (+ stpar (* (float (setq m (1+ m))) incrpar))))
37.       (setq ptnlst (cons ptn ptnlst))
38.     )
39.     (setq ptnlst (reverse ptnlst))
40.     (setq ptnewlst (append ptnewlst ptnlst))
41.   )
42.   (setq ptnewlst (reverse ptnewlst))
43.   (setq ptnewlst (cons enpt ptnewlst))
44.   (setq ptnewlst (reverse ptnewlst))
45.   (entdel spl)
46.   (vl-cmdf "_.3dpoly")
47.   (foreach pt ptnewlst
48.     (vl-cmdf pt)
49.   )
50.   (while (> (getvar 'cmdactive) 0) (vl-cmdf ""))
51.   (setvar 'osmode osm)
52.   (princ)
53. )
54.  

M.R.

[demesne]

Marko

Thank you very much.  I didn't expect a full solution.  That's excellent.

I had a look at the lisp to see if I could change the knot parameter to 'square root' from 'chord' although I'm lost with that one.  I thought I might see a reference to the SPLKNOTS system variable.  It's not too important though.

Thanks again - you've saved me hours! 

Regards
Demesne