Topic: Arc of a polyline

[Coder]

Hello .

I would like to know how to check if a Polyline has an arc among its segments and how to check if the Polyline is rectangle or with
straight segments .

Is it possible ?

Thank you in advance .

[Lee Mac]

Here are two variations on a function that will return T if the supplied LWPolyline DXF data has non-zero bulge (i.e. the LWPolyline has one or more Arc segments):

Code: [Select]

(defun HasBulge ( elist / pair )
    (and (setq pair (assoc 42 elist))
         (or (not (equal 0.0 (cdr pair) 1e-10))
             (HasBulge (cdr (member pair elist)))
         )
    )
)

Code: [Select]

(defun HasBulge ( elist )
    (vl-some '(lambda ( pair ) (not (equal 0.0 (cdr pair) 1e-10))) elist)
)
e.g.:

Code: [Select]

(HasBulge (entget <LWPolyline Entity>))

[Lee Mac]

how to check if the Polyline is rectangle

Maybe something like:

Code: [Select]

(defun Rectangle-p ( ent / elist p1 p2 p3 p4 )
    (and
        (eq "LWPOLYLINE" (cdr (assoc 0 (setq elist (entget ent))))) ;; Is it an LWPolyline?
        (= 4 (cdr (assoc 90 elist))) ;; Does it have 4 vertices?
        (= 1 (logand 1 (cdr (assoc 70 elist)))) ;; Is it Closed?
        (not (HasBulge elist)) ;; Arc segments?
        (mapcar 'set '(p1 p2 p3 p4) ;; Collect the Vertices for further investigation
            (apply 'append
                (mapcar '(lambda ( pair ) (if (= 10 (car pair)) (list (cdr pair)))) elist)
            )
        )
        (equal (distance p1 p2) (distance p3 p4) 1e-8) ;; Two pairs of
        (equal (distance p1 p4) (distance p2 p3) 1e-8) ;; equal sides?
        (equal (distance p1 p3) (distance p2 p4) 1e-8) ;; Is it a parallelogram?
    )
)

(defun HasBulge ( elist / pair )
    (and (setq pair (assoc 42 elist))
         (or (not (equal 0.0 (cdr pair) 1e-10))
             (HasBulge (cdr (member pair elist)))
         )
    )
)
EDIT: Fixed DXF 70 check.

[Coder]

Thank you so much 

What is the meaning of these ...

Code: [Select]

1e-8
and this

Code: [Select]

le-10

[MP]

Shorthand for (expt 10.0 -8) and (expt 10.0 -10).

[Lee Mac]

Thank you so much 

What is the meaning of these ...

Code: [Select]

1e-8
and this

Code: [Select]

le-10

Scientific Notation

Code: [Select]

1e-8  =  0.00000001
1e-10 =  0.0000000001

Code: [Select]

(equal <expr1> <expr2> [fuzz])
fuzz
A real number defining the maximum amount by which expr1 and expr2 can differ and still be considered equal.

[ I should probably be more consistent with my tolerances... ]

[alanjt]

how to check if the Polyline is rectangle

Maybe something like:

Code: [Select]

(eq (logand 1 (cdr (assoc 70 elist))) 1)

[Lee Mac]

how to check if the Polyline is rectangle

Maybe something like:

Code: [Select]

(eq (logand 1 (cdr (assoc 70 elist))) 1)

Good catch, updated above 

[alanjt]

how to check if the Polyline is rectangle

Maybe something like:

Code: [Select]

(eq (logand 1 (cdr (assoc 70 elist))) 1)

Good catch, updated above 

One time at band camp, I caught someone in the office drawing a rectangle and wasn't aware of the rectangle command.

[MP]

Wee niggle: I prefer this coding style: (eq 1 (logand 1 (cdr (assoc 70 elist)))). To me it's clearer, especially when scanning thru lotsa of code. Mileages vary, 'twas mine. That aside, as noted: good catch.

[alanjt]

Wee niggle: I prefer this coding style: (eq 1 (logand 1 (cdr (assoc 70 elist)))). To me it's clearer, especially when scanning thru lotsa of code. Mileages vary, 'twas mine. That aside, as noted: good catch.

I just prefer to follow the same argument order as wcmatch so everything is formatted the same - looks cleaner to me when looking over.

eg.

Code: [Select]

((eq name "AcDbMText") blah blah)
((wcmatch (strcase name) "*LINE") blah blah)

[MP]

I see and salute your logic.

Mine stems from c/c++ coding where it's better to place literal comparisons on the left side, immediately catching an errant assignment due to a dropped equals sign:

// DOH!! c/c++ compiler allows (c# will catch it):
if (x = 1)
   do_stuff();

// All compilers will complain:
if (1 = x)
   do_stuff();

// Fixed:
if (1 == x)
   do_stuff();

[alanjt]

That makes sense and I actually prefer to see the literal first, especially when the comparison is generally long-winded (logand 1 (cdr (assoc 70 elist))), but I stick with the forced argument placement of wcmatch because the mix and match irritates my OCD.

[MP]

lol, my "need to see" trumps my ocd

♪♫ sung in the key of "gee" of course ♪♫

[alanjt]