Topic: String to List @symbol

[rhino]

Hi,

How would you you turn this string into a list with dotted pairs?

"1@1000+2@3000+3@2000+1@1000" to (1 . 1000) (2 . 3000) (3 . 2000) (1 . 1000)

*both items in the dotted pair should be integers.

and also I'd like to check the string with the total length ie. "1@1000+2@3000+3@2000+1@1000" = (14000).

Thanks in advance.

Chris.

[alanjt]

Code: [Select]

(defun footos (string)
  (read (vl-list->string
          (apply 'append
                 (mapcar '(lambda (a)
                            (cond ((eq a 64) (list 32 46 32))
                                  ((eq a 43) (list 41 40))
                                  ((list a))
                            )
                          )
                         (vl-string->list (strcat "((" string "))"))
                 )
          )
        )
  )
)

Code: [Select]

(footos "1@1000+2@3000+3@2000+1@1000")

Code: [Select]

(apply '+ (mapcar '(lambda (x) (* (car x) (cdr x))) (footos "1@1000+2@3000+3@2000+1@1000")))

[ElpanovEvgeniy]

Code: [Select]

(defun f (s / i)
  (if (setq i (vl-string-search "@" s))
    (cons (cons (atoi s) (atoi (substr s (+ i 2))))
          (if (setq i (vl-string-search "+" s))
            (f (substr s (+ i 2)))
          )
    )
  )
)

Code: [Select]

(f "1@1000+2@3000+3@2000+1@1000")

[ElpanovEvgeniy]

Code: [Select]

(defun f+ (s / i)
  (if (setq i (vl-string-search "@" s))
    (+ (* (atoi s) (atoi (substr s (+ i 2))))
       (if (setq i (vl-string-search "+" s))
         (f+ (substr s (+ i 2)))
         0
       )
    )
    0
  )
)

Code: [Select]

(f+ "1@1000+2@3000+3@2000+1@1000")

[rhino]

Thank you both  :kewl: this helps me out a lot

@Elpanov, could you explain your code i'd like to understand the magic  :kewl:

[Lee Mac]

Another, similar method to Alan:

Code: [Select]

(defun f ( s )
    (if (vl-string-search "@" s)
        (f (vl-string-subst " . " "@" (vl-string-subst ")(" "+" s)))
        (read (strcat "((" s "))"))
    )
)

[rhino]

Dear All,

Wish you complements of the season! and a Happy New Year 2014 in advance

Sorry to restart an old thread but I would like your help again in completing this code;

I like to apply this drawgrid function http://www.theswamp.org/index.php?topic=25575.0(from @ronjonp) to the converted dotted list to drawing vertical grid lines within a rectangle?

The list could start off with 1@dist or end with 1@dist which could result in an error if using foreach.
The other issue is that the first frame (grid) would start at a preset offset (say 500mm) from the total length (sum of the converted string).

@CAB The routine I am working on is very similar to what you worked on for array (albeit has varying spacing for the truss/frame members: http://www.theswamp.org/index.php?topic=2695.0


Thanks in advance,
Chris

[rhino]

Ok here's what I got:

Code - Auto/Visual Lisp: [Select]

1.  
2. ;Variable settings
3. (defun var_set ()
4.   (setq  *var_lst* '("cmdecho" "osmode" "expert" "plinewid" "dynmode")
5.          *var_usr*  (mapcar 'getvar *var_lst*))
6.                     (mapcar 'setvar *var_lst* '(0 0 2 0 0))
7.   (vl-load-com)
8. )
9. (defun var_reset ()
10.  (mapcar 'setvar *var_lst* *var_usr*)
11. )
12.  
13. (defun *error* (msg)
14.     (if (not
15.           (member msg '("console break" "Function cancelled" "quit / exit abort" "" nil))
16.         )
17.       (princ (strcat "\nError: " msg))
18.     )    
19.     (and ;(vl-bt)
20.         (var_reset)
21.       )
22.     (princ)
23.   )
24.  
25. (defun string-list (data) ;by lee-mac @theswamp
26.     (if (vl-string-search "@" data)
27.         (string-list (vl-string-subst " . " "@" (vl-string-subst ")(" "+" data)))
28.         (read (strcat "((" data "))"))
29.     )
30. )
31.  
32.  ;my-getstring function by Tony Tanzillo
33. (defun my-getstring (msg)
34.   (while
35.      (eq ""
36.        (setq response
37.          (vl-string-trim " " (getstring T msg))
38.         )
39.       )
40.      (princ "\nInvalid response...")
41.    )
42.  response
43. )
44.  
45. ;Draw LWPoly function
46. (defun LWPoly (pts cls lay col ext)
47.   (entmakex (append (list (cons 0 "LWPOLYLINE")
48.                           (cons 100 "AcDbEntity")
49.                           (cons 100 "AcDbPolyline")
50.                           (cons 90 (length pts))
51.                           (cons 8 lay)
52.                           (cons 62 col)
53.                           (cons 70 cls))
54.                     (mapcar (function (lambda (p) (cons 10 p))) pts) ext)
55.         )
56.   )
57.  
58. (defun C:Gridlines (/)
59.  (var_set)
60.  
61.  (setq  pt1  '(0.0 0.0 0.0))
62.   (initget 7)
63.   (setq  *wid*  (getreal "\nEnter width: "))
64.     (prompt "\nBay spacing to be entered in MILLIMETERS only
65.            \nBay spacing must be entered in format as 1@7000+2@8000+1@6500 "
66.       )
67.   (setq bay_spc (my-getstring "\nEnter bay spacing: "))
68.   (setq spc_lst (string-list bay_spc));convert string to dotted list
69.   (setq *len* (apply '+ (mapcar '(lambda (x) (* (car x) (cdr x))) spc_lst))) ;add up the bay spacing to get total length
70.  
71.   (setq  pt2  (list (+ (car pt1) *len*) (cadr pt1) 0.0)
72.          pt3  (list (car pt2) (+ (cadr pt1) *wid*) 0.0)
73.          pt4  (list (car pt1) (+ (cadr pt1) *wid*) 0.0)
74.          ctp  (list (+ (car pt1) (/ *len* 2.0)) (- (cadr pt3) (/ *wid* 2.0)))
75.          dmeval (if (>= *len* *wid*) *len* *wid*)
76.         )
77.   (LWpoly (list pt1 pt2 pt3 pt4) 1 "0" 1 nil)
78.   (command "_.zoom" (list (- (car pt1) 5000) (- (cadr pt1) 5000)) (list (+ (car pt3) 5000) (+ (cadr pt3) 5000))); required otherwise error in array cmd.
79.  
80.  
81.   (LWpoly (list pt1 pt4) 1 "0" 1 nil);draw gridline
82.  
83.   ;(setq  frame (ssadd));create selection set for frame
84.   (setq  grdline (entlast))
85.     ;(command "chprop" grdline "" "ltscale" (* *wid* 0.005) "")
86.     ; (ssadd grdline frame)
87.         ;(command "_-layer" "s" "STEEL" ""
88.         ;         "_-insert" "C:/LISP/Block Database/COL_RF.dwg" gl1 "" "" ""
89.         ;  )
90.         ;(setq  col (entlast))
91.         ;(ssadd col frame)
92.         ;(command "_-insert" "COL_RF" gl2 "" "" "-180")
93.         ;(setq  col2 (entlast))
94.         ;(ssadd col2 frame)
95.          
96.   (foreach n spc_lst
97.     (command "-array" grdline "" "rectangular" "1" (1+ (car n)) (cdr n))
98.     (setq grdline (entlast))
99.     )
100. (princ)
101.  
102. (*error* "")
103. (princ)
104.  
105. )
106.  

Code - Auto/Visual Lisp: [Select]

1.  (foreach n spc_lst
2.     (command "-array" grdline "" "rectangular" "1" (1+ (car n)) (cdr n))
3.     (setq grdline (entlast))
4.     )
5.  

The above gets me the gridlines; but I have a block inserted at both ends of the grid line; how do I get the selection of those entities (selection set "frame") after each array?

or I would need to map a point list and draw each grid individually how do I go about that?

[rhino]

anyone there?   

[CAB]

It the new year! 

The young are hung over & the old like me are going to our day time Brunch. 

[rhino]

It the new year! 

The young are hung over & the old like me are going to our day time Brunch. 

Haha Happy New Year CAB and all Swampers!!!