I created this routine to copy objects form one layout tab to the remaining layouts.
All is fine except to blocks. I have an insert with attributes I need to copy.
I don't want to use the "Copy" command because you gave to activate each layout to
use it. All I do in this routine is create a new entity list and replace the 410 code
with the next tab name and entmake it.
Anyone have a 'Insert Copy' routine that I can modify to do the same? The routines
I have recreate the Block & not the insert. If not I'll figure it out but I don't have
much time to spare this week.
;;; Copy2Tabs.lsp by Charles Alan Butler
;;; Copyright 2004
;;; by Precision Drafting & Design All Rights Reserved.
;;; Contact at ab2draft@TampaBay.rr.com
;;;
;;; Version 1.0 Beta June 19,2004
;;;
;;; DESCRIPTION
;;; Copy objects in one layout to all layouts
;;;
;;; Limitations
;;; Can not use in Model Space
;;;
;;; Command Line Usage
;;; Command: c2t
;;;
;;; Options: none
;;;
;;; This software is provided "as is" without express or implied ;
;;; warranty. All implied warranties of fitness for any particular ;
;;; purpose and of merchantability are hereby disclaimed. ;
;;; You are hereby granted permission to use, copy and modify this ;
;;; software without charge, provided you do so exclusively for ;
;;; your own use or for use by others in your organization in the ;
;;; performance of their normal duties, and provided further that ;
;;; the above copyright notice appears in all copies and both that ;
;;; copyright notice and the limited warranty and restricted rights ;
;;; notice appear in all supporting documentation. ;
(defun c:c2t (/ cnt ss ctab omited sslen sscnt elst newent tab)
;; Returns T if Locked
;; nil if Unlocked or not found
;; nil if lname is not a string
(defun islayerlocked (lname / entlst)
(and (= 'str (type lname))
(setq entlst (tblsearch "LAYER" lname))
(= 4 (logand 4 (cdr (assoc 70 entlst))))
)
); defun
(defun count ()
(if (= cnt 0) ; count only once
;; count the omitted from copy
(setq omited (1+ omited))
)
); defun
(if (= (getvar "tilemode") 1)
(alert "\nYou must be in Paper Space to run this routine.\t")
(progn ; else you are in paper space, ok to proceed
(if (/= (getvar "cvport") 1) ; a view port is active
(command "_pspace") ; close the view port
)
(prompt "\nSelect objects to copy")
(if (setq ss (ssget))
(progn
(setq ctab (getvar "ctab"))
(setq cnt 0
omited 0
sslen (sslength ss)
)
(foreach tab (layoutlist)
(if (not (member tab (list "Model" ctab)))
(progn
(setq sscnt (sslength ss))
(while (>= (setq sscnt (1- sscnt)) 0)
(setq elst (entget (ssname ss sscnt)))
(if (assoc 410 elst)
(progn
(if (null (islayerlocked (cdr (assoc 8 elst))))
(progn ; do not copy if layer is locked
(setq newent (subst (cons 410 tab) (assoc 410 elst) elst)
newent (strip newent))
(if (and (/= (cdr (assoc 0 newent)) "INSERT") ; skip blocks
(null(entmake newent)))
(count) ; rejected entity
)
)
(count) ; locked layer
)
)
(count) ; no 410 code
)
)
(setq cnt (1+ cnt))
)
)
)
(prompt
(strcat "\n"(itoa cnt)" Layouts Updated with "(itoa sslen)
" items selected and "(itoa omited)" items not copied.")
)
)
)
)
)
(princ)
)
(prompt "\ncopy2tabs loaded, enter c2t to run.")
(princ)
;; function to strip unwanted dxf codes for a new entity
;; retuens a ent list ready for entmake
(defun strip (entl)
;; ent expected to be an entity name or entlist or ename w/ point list
(cond
((= (type entl) "ENAME")
(setq entl (entget entl))
)
((= (length entl) 2)
(setq entl (car entl))
)
)
(foreach n '(-2 -1 5 102 300 330 331 350 360)
(while (assoc n entl)
(setq entl (vl-remove (assoc n entl) entl))
)
)
entl
)
