Topic: Need help with Object id

[Coder]

Hello everyone .

Is it normal when I am trying to get the object id with the following codes and it returns the number with two digits ?

Code: [Select]

(setq ss (vlax-ename->vla-object (car (entsel "\n Select a circle :"))))
(setq id (vla-get-Objectid ss))

Returns :

#<VLA-OBJECT IAcadCircle 0000000026dee198>
47

Thanks

[Jeff_M]

Sure.
What happens when you reverse the process?

Code: [Select]

(setq newobj (vla-objectidtoobject (vla-get-activedocument (vlax-get-acad-object)) id))
This should return the original vla-object.

[Coder]

Thanks Jeff .

This is what return after implementing your codes ..

; error: Exception occurred: 0xC0000005 (Access Violation)
; warning: unwind skipped on unknown exception

[Lee Mac]

From the length of the object code it looks like you are using a 64-bit system.

For 64-bit systems use either the ObjectID32 property of the object, or the GetObjectIDString method of the Utility object.

[Jeff_M]

Oops, forgot about that, Lee.

Coder, have a look at THIS thread for some talk about the 32/64 bit implementations of this.

[Lee Mac]

I doubt I'll ever forget it again after the troubles it caused me with that thread ^^

[Coder]

A very interesting thread Jeff that you brought . Thank you so much .

I got the correct id with the following codes .

Code: [Select]

(setq id (vlax-invoke-method (vla-get-Utility  (vla-get-ActiveDocument (vlax-get-acad-object)))
  'GetObjectIdString   ss  :vlax-false )
       )
Am I on the right track ?

Many thanks. 

[Coder]

I am still facing a problem which cause the routine not to do the trick .

This code does not work and returns two digits as the function vla-get-objectid .

Code: [Select]

(vla-get-objectid32 vla-obj)
Finally this routine returns error with Field code and something wrong that I could not deal with , Any help with it Please ?

Code: [Select]

(vl-load-com)
(defun c:test (/ ss i sselection vla-obj id pt)
  (if (setq ss (ssget "_:L" '((0 . "CIRCLE"))))
    (repeat
      (setq i (sslength ss))
       (setq sselection (ssname ss 0))
       (setq vla-obj (vlax-ename->vla-object sselection))
       (setq id (vlax-invoke-method
                  (vla-get-Utility
                    (vla-get-ActiveDocument (vlax-get-acad-object))
                  )
                  'GetObjectIdString
                  vla-obj
                  :vlax-false
                )
       )
       (setq pt (cdr (assoc 10 (entget sselection))))
       (vla-addMText
         (vla-get-ModelSpace
           (vla-get-ActiveDocument (vlax-get-acad-object))
         )
         (vlax-3d-point pt)
         2.
         (strcat ("%<\\AcObjProp Object(%<\\_ObjId"
                   (atoi id)
                   ">%).Area \\f \"%lu2\">%"
                 )
         )
       )
    )
    (princ)
  )
  (princ)
)



[gile]

Hi,

The GetObjectIdString method returns a string and you use it with atoi which requires an integer: (atoi id)

By my side I use a function which return the objectId as string and works whatever the AutoCAD version (32 ou 64 bits):

Code: [Select]

(defun gc:GetObjectIdString (obj)
  (or *util*
      (setq *util* (vla-get-Utility (vla-get-ActiveDocument (vlax-get-acad-object))))
  )
  (if  (vlax-method-applicable-p *util* 'GetObjectIdString)
    (vla-GetObjectIdString *util* obj :vlax-false)
    (itoa (vla-get-ObjectId obj))
  )
)
Using example in a field code:

Code: [Select]

         (strcat ("%<\\AcObjProp Object(%<\\_ObjId"
                   (gc:GetObjectIdString vla-obj)
                   ">%).Area \\f \"%lu2\">%"
                 )
         )

[Coder]

Thanks gile .

But I am still suffering of this thread because I could not pass the error that occur form the field .

The is the return error ...

; error: bad function: "%<\\AcObjProp Object(%<\\_ObjId"

Code: [Select]

(vl-load-com)
(defun gc:GetObjectIdString (obj)
  (or *util*
      (setq *util* (vla-get-Utility  (vla-get-ActiveDocument (vlax-get-acad-object)))))
  (if (vlax-method-applicable-p *util* 'GetObjectIdString)
    (vla-GetObjectIdString *util* obj :vlax-false)
    (itoa (vla-get-ObjectId obj))))
(defun c:test (/ ss i sselection vla-obj id pt)
  (if (setq ss (ssget "_:L" '((0 . "CIRCLE"))))
    (repeat
      (setq i (sslength ss))
       (setq sselection (ssname ss (setq i (1- i))))
       (setq vla-obj (vlax-ename->vla-object sselection))
       (setq pt (cdr (assoc 10 (entget sselection))))
       (vla-addMText (vla-get-ModelSpace (vla-get-ActiveDocument (vlax-get-acad-object)))
         (vlax-3d-point pt)
         2.
         (strcat ("%<\\AcObjProp Object(%<\\_ObjId"
                   (gc:GetObjectIdString vla-obj)
                   ">%).Area \\f \"%lu2\">%"
                 ))))
    (princ))
  (princ))


[Lee Mac]

Maybe something like this:

Code: [Select]

(vl-load-com)

(defun gc:GetObjectIdString ( obj )
  (or *util* (setq *util* (vla-get-Utility  (vla-get-ActiveDocument (vlax-get-acad-object)))))
  (if (vlax-method-applicable-p *util* 'GetObjectIdString)
    (vla-GetObjectIdString *util* obj :vlax-false)
    (itoa (vla-get-ObjectId obj))
  )
)

(defun c:test ( / spc ss i en )
  (setq spc (vla-get-modelspace (vla-get-ActiveDocument (vlax-get-acad-object))))
 
  (if (setq ss (ssget "_:L" '((0 . "CIRCLE"))))
    (repeat (setq i (sslength ss))
      (setq en (ssname ss (setq i (1- i))))
      (vla-addMText spc (vlax-3d-point (cdr (assoc 10 (entget en)))) 2.
        (strcat "%<\\AcObjProp Object(%<\\_ObjId " (gc:GetObjectIdString (vlax-ename->vla-object en)) ">%).Area \\f \"%lu2\">%")
      )
    )
  )
  (princ)
)
A few pointers:

• Don't use (vlax-get-acad-object) inside a loop, its slow and is bad practice.
• Your Field string was missing a space after the ObjId

[Coder]

Great . 

Thank you so much for your time Lee , and the others also as well .

Appreciated a lot.

Maybe something like this:

Code: [Select]

(vl-load-com)

(defun gc:GetObjectIdString ( obj )
  (or *util* (setq *util* (vla-get-Utility  (vla-get-ActiveDocument (vlax-get-acad-object)))))
  (if (vlax-method-applicable-p *util* 'GetObjectIdString)
    (vla-GetObjectIdString *util* obj :vlax-false)
    (itoa (vla-get-ObjectId obj))
  )
)

(defun c:test ( / spc ss i en )
  (setq spc (vla-get-modelspace (vla-get-ActiveDocument (vlax-get-acad-object))))
 
  (if (setq ss (ssget "_:L" '((0 . "CIRCLE"))))
    (repeat (setq i (sslength ss))
      (setq en (ssname ss (setq i (1- i))))
      (vla-addMText spc (vlax-3d-point (cdr (assoc 10 (entget en)))) 2.
        (strcat "%<\\AcObjProp Object(%<\\_ObjId " (gc:GetObjectIdString (vlax-ename->vla-object en)) ">%).Area \\f \"%lu2\">%")
      )
    )
  )
  (princ)
)
A few pointers:

• Don't use (vlax-get-acad-object) inside a loop, its slow and is bad practice.
• Your Field string was missing a space after the ObjId