Topic: Open excel file

[Atwist]

Hello,

How to open a excel file in AutoCad

[SOFITO_SOFT]

hello:
I use a DLL that is not divine, but it works very well with A2008, excel 2003 on XP 32.

Code for open the sheet "Ayuda_Sofito_Soft" of file "Sofito_Soft.xls" in folder "H:\\aa_sofito\\"

Code: [Select]

( setq arma_3d_path "H:\\aa_sofito\\")
( if ( not Excel_Release )
    ( command "netload"  (  strcat arma_3d_path  "ExcelLisp.dll" ) )
  )
( setq excel-libro (  strcat arma_3d_path  "Sofito_Soft.xls" ) )
( Excel_Conecta T  excel-libro  "Ayuda_Sofito_Soft")
Now you can read, write, make new sheets , change cell formats, save book, etc ...
Attacheds, the DLL and little help of use.

I hope you can use.

Greetings from Madrid

[gile]

Hi,

Look at this 'not so old' thread.

[Lee Mac]

This will 'open' any file, but if you actually meant to interface with the Excel file, refer to the link suggested by gile.

[HofCAD]

Hello,
How to open a excel file in AutoCad

See in http://www.theswamp.org/index.php?topic=38526.0 DDE-OpenAll.xls

Regards HofCAD CSI.

[Atwist]

Hello all

Thanks for your answer

@ Lee

I have use your lisp "open" and have dish chance but it don't works
Watt is wrong.

Code: [Select]

(defun LM:excel ( target / Shell result ) (vl-load-com)
(LM:excel "T:\\excel bestanden\\layerlijst.xls")

 
  (setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))

  (setq result
    (and (or (eq 'INT (type target)) (setq target (findfile target)))
      (not
        (vl-catch-all-error-p
          (vl-catch-all-apply 'vlax-invoke (list Shell 'Open target))
        )
      )
    )
  )
  (vlax-release-object Shell)
  result
)


[Lee Mac]

You are not calling the function correctly since you call the function within its own definition.

This is better:

Code: [Select]

;;------------------------=={ Open }==------------------------;;
;;                                                            ;;
;;  Uses the 'Open' method of the Shell Object to open the    ;;
;;  specified file or folder.                                 ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2010 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  target - filename, directory or                           ;;
;;           ShellSpecialFolderConstants Enumeration to open  ;;
;;------------------------------------------------------------;;
;;  Returns:  T if opened successfully, else nil              ;;
;;------------------------------------------------------------;;

(defun LM:Open ( target / Shell result ) (vl-load-com)
 
  (setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))
  (setq result
    (and (or (eq 'INT (type target)) (setq target (findfile target)))
      (not
        (vl-catch-all-error-p
          (vl-catch-all-apply 'vlax-invoke (list Shell 'Open target))
        )
      )
    )
  )
  (vlax-release-object Shell)
  result
)

(LM:Open "T:\\excel bestanden\\layerlijst.xls")


[Atwist]

Thanks Lee

It works

[SOFITO_SOFT]

Hello people swampy:
A question a little more difficult with Excel.
2 programs LSP want to use a spreadsheet. Each opens, write and close the spreadsheet.
Do any method for each program know if the sheet is already open and available to write?
Thus saving the time to open and close. The 2 programs could know if the other has opened the spreadsheet ?.
Thanks in advance.
Greetings

PS.:  I know I could use a flag switch (is open / is closed)
but look for something more sophisticated ...

[VVA]

Patrick_35 xopen functions

[johnson]

You are not calling the function correctly since you call the function within its own definition.

This is better:

Code: [Select]

;;------------------------=={ Open }==------------------------;;
;;                                                            ;;
;;  Uses the 'Open' method of the Shell Object to open the    ;;
;;  specified file or folder.                                 ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2010 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  target - filename, directory or                           ;;
;;           ShellSpecialFolderConstants Enumeration to open  ;;
;;------------------------------------------------------------;;
;;  Returns:  T if opened successfully, else nil              ;;
;;------------------------------------------------------------;;

(defun LM:Open ( target / Shell result ) (vl-load-com)
 
  (setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))
  (setq result
    (and (or (eq 'INT (type target)) (setq target (findfile target)))
      (not
        (vl-catch-all-error-p
          (vl-catch-all-apply 'vlax-invoke (list Shell 'Open target))
        )
      )
    )
  )
  (vlax-release-object Shell)
  result
)

(LM:Open "T:\\excel bestanden\\layerlijst.xls")


Lee after loading xls is opened.without comman.after command i want open that xls

[Lee Mac]

Lee after loading xls is opened.without comman.after command i want open that xls

Yes, because the function is called outside of any function definition and so is evaluated on loading:

Code: [Select]

(LM:Open "T:\\excel bestanden\\layerlijst.xls")
You can call it from inside a function definition instead:

Code: [Select]

(defun c:test ( / )
  (LM:Open "T:\\excel bestanden\\layerlijst.xls")
  (princ)
)

[johnson]

Error is coming

Command: ; error: no function definition: LM:OPEN

[Lee Mac]

Error is coming

Command: ; error: no function definition: LM:OPEN

You will need to have the LM:Open function definition loaded in order to call it.

[cadman6735]

Hi Lee

I just found this post and love this macro.  I am studying your code but have some questions if you don't mind.

Code: [Select]

(setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))Is "Shell.Application" sort of a catch all?

I am finding I can open all the files I have tried so far but if I follow the example for (vla-getIntrfaceObject) and put in for example instead of "Shell.Application" I use "Excel.Application" I get "error problem in loading application"  I am guessing this is because your code is using "target" as a check to see what the file type is to be fed to the shell for loading?

I have a couple of more questions to follow but will pause here

Thanks lee