Topic: Maximize Text Window with Lisp

[Harrie]

Hello,

Is it possible to Maximize AutoCAD Text Window with Lisp?

Regards.

[Lee Mac]

Code: [Select]

(textscr)

[Harrie]

Code: [Select]

(textscr)

Lee,

The function (textscr) and (textpage) gives only the text window, but gives not a Maximize text window!

Regards.

[highflyingbird]

Maybe like this:

Code: [Select]


(defun c:test(/ wsh title)
  (textscr)
  (setq title "AutoCAD 文本窗口 - Drawing1.dwg")    ;->this is  the title of  your Textscreen
  (setq wsh (vlax-create-object "Wscript.Shell"))
  ;;(vlax-invoke wsh 'AppActivate title)
  ;;(command "delay" 100)
  (vlax-invoke wsh 'Sendkeys "% x")  ;x Maximize;n Minimize
  (vlax-release-object wsh)
  (princ)
)


[Lee Mac]

Nice idea highflybird 

Using your idea,

Code: [Select]

(defun TextWin ( flag / wsh )
  (cond
    ( flag
      (textscr)
      (setq wsh (vlax-create-object "WScript.Shell"))
      (vlax-invoke wsh 'SendKeys "% x")
      (vlax-release-object wsh)
    )
    ( (graphscr) )
  )
  (princ)
)

Code: [Select]

(TextWin   T) ;; Maximise
(TextWin nil) ;; Minimise

[Harrie]

Nice idea highflybird  

Using your idea,

Code: [Select]

(defun TextWin ( flag / wsh )
  (cond
    ( flag
      (textscr)
      (setq wsh (vlax-create-object "WScript.Shell"))
      (vlax-invoke wsh 'SendKeys "% x")
      (vlax-release-object wsh)
    )
    ( (graphscr) )
  )
  (princ)
)

Code: [Select]

(TextWin   T) ;; Maximise
(TextWin nil) ;; Minimise

Thanks Lee and Highflybird,

I have some questions:
1) In the program Test from Highflybird, I see no change in the Title of the TextScreen
2) In the program TextWin from Lee Mac, is it not better to change the string "% x"
in "% M".

Code: [Select]

(defun TextWin2 ( flag / wsh )
(if (> (atoi (substr (getvar "ACADVER") 1 2)) 14)
(progn
  (vl-load-com)
  (cond
    ( flag
      (textscr)
      (setq wsh (vlax-create-object "WScript.Shell"))
      (vlax-invoke wsh 'SendKeys "% M"); "% M" Maximize and "% N" Minimize All
      (vlax-release-object wsh)
    )
    ( (graphscr) )
  )
)
(if flag (textscr)(graphscr))
)
)
or

Code: [Select]

(defun TextWin3 (flag / wsh str)
(if flag (setq str "% M")(setq str "% N"))
(if (> (atoi (substr (getvar "ACADVER") 1 2)) 14)
(progn
(vl-load-com)
(if flag (textscr))
(setq wsh (vlax-create-object "WScript.Shell"))
(vlax-invoke wsh 'SendKeys str)
(vlax-release-object wsh)
))
(if flag (textscr)(graphscr))
(princ)
)


Code: [Select]

(TextWin3 T); Maximize Textscreen
(TextWin3 nil); Minimize All

Regards, Harrie.

[Lee Mac]

I thought the mnemonic was 'x' for Maximise in the menu that appears when pressing Alt+Space

[highflyingbird]

I have some questions:
1) In the program Test from Highflybird, I see no change in the Title of the TextScreen
Regards, Harrie.

At the first ,I wanted to use "AppActivate" method to active a window, its title should be "AutoCAD 文本窗口 - Drawing1.dwg",like this.
but later,I found it's not necessary, because (textscr) means you have activated text window.
so actually, (setq title "AutoCAD 文本窗口 - Drawing1.dwg") can be removed. as Lee Mac's.

this article will help you

[HofCAD]

Lee and Highflybird,

Is this the right way?

Code: [Select]

(defun TextWin4 (code / wsh str)
  (cond ((= code 0) (graphscr))
((= code 1) (setq str "% M"))
(T (setq str "% N"))
  )
  (if (> (atoi (substr (getvar "ACADVER") 1 2)) 14)
    (progn
      (if (/= code 0)
(progn
 (vl-load-com)
 (if (= code 1)
   (textscr)(graphscr)
 )
 (setq wsh (vlax-create-object "WScript.Shell"))
 (vlax-invoke wsh 'SendKeys str)
 (vlax-release-object wsh)
)
      )
    )
    (if (= code 1)
      (textscr)
      (graphscr)
    )
  )
  (princ)
)
(princ "\nTextWin4.lsp loaded.")
(defun C:Info ()
  (TextWin4 1)
  (mapcar
    '(lambda (x) (princ X))
    '(
      "\nType (TextWin4 0) for displaying the AutoCAD graphics screen."
      "\nType (TextWin4 1) for displaying the maximized AutoCAD text screen."
      "\nType (TextWin4 2), (TextWin4 nil) or (TextWin4 T) for minimized AutoCAD."
      "\n************************Type INFO for this screen************************"
     )
  )
  (princ)
)
(c:INFO)
(princ)

HofCAD

[highflyingbird]

Lee and Highflybird,

Is this the right way?

Code: [Select]

(defun TextWin4 (code / wsh str)
  (cond ((= code 0) (graphscr))
((= code 1) (setq str "% M"))
(T (setq str "% N"))
  )
  (if (> (atoi (substr (getvar "ACADVER") 1 2)) 14)
    (progn
      (if (/= code 0)
(progn
  (vl-load-com)
  (if (= code 1)
    (textscr)(graphscr)
  )
  (setq wsh (vlax-create-object "WScript.Shell"))
  (vlax-invoke wsh 'SendKeys str)
  (vlax-release-object wsh)
)
      )
    )
    (if (= code 1)
      (textscr)
      (graphscr)
    )
  )
  (princ)
)
(princ "\nTextWin4.lsp loaded.")
(defun C:Info ()
  (TextWin4 1)
  (mapcar
    '(lambda (x) (princ X))
    '(
      "\nType (TextWin4 0) for displaying the AutoCAD graphics screen."
      "\nType (TextWin4 1) for displaying the maximized AutoCAD text screen."
      "\nType (TextWin4 2), (TextWin4 nil) or (TextWin4 T) for minimized AutoCAD."
      "\n************************Type INFO for this screen************************"
     )
  )
  (princ)
)
(c:INFO)
(princ)

HofCAD

Good job!
by the way,  if you want maximize Application window or VBIDE window or  Document window,
just change the property of  windowState , like that :

Code: [Select]

(setq app (vlax-get-acad-object))
(vla-put-windowstate app 3)

[Lee Mac]

Lee and Highflybird,

Is this the right way?

I didn't think it needed to be that complicated (as per my earlier example), but since you asked, I would write your code in the following way:

Code: [Select]

(defun TextWin ( code / wsh )
  (if (> (atoi (getvar 'ACADVER)) 14)
    (cond
      ( (= code 0) (graphscr) )
      ( (= code 1)
        (textscr)
        (setq wsh (vlax-create-object "WScript.Shell"))
        (vlax-invoke wsh 'SendKeys "% x")
        (vlax-release-object wsh)
      )
      (t(graphscr)
        (setq wsh (vlax-create-object "WScript.Shell"))
        (vlax-invoke wsh 'SendKeys "% n")
        (vlax-release-object wsh)
      )
    )
    (if (= 1 code) (textscr) (graphscr))
  )
  (princ)
)

(princ "\nTextWin.lsp loaded.")
(defun c:Info nil
  (mapcar 'princ
   '("\nType (TextWin 0) for displaying the AutoCAD graphics screen."
     "\nType (TextWin 1) for displaying the maximized AutoCAD text screen."
     "\nType (TextWin 2) for minimized AutoCAD."
     "\n-------------------- Type INFO for this screen -------------------- "
    )
  )
  (TextWin 1) (princ)
)
(c:INFO) (princ)

[HofCAD]

Thanks Lee and Highflybird,

I made a small change.

Regards.

[Harrie]

Thanks Lee, Highflybird and HofCAD.

[laidbacklarry]

I almost always want the Acad text window maximized so I mapped a revised version of Lee Mac's first code to the F2 key and life is good. Thanks Lee and others...