Topic: What would you want in a set of Xref tools?

[barc]

I'm in no big hurry for it, and if I get time to wade through the code posted here I just might learn something.  Thanks for the fishin' lesson.

[T.Willey]

Try this.

Code: [Select]

(defun c:PrintXrefInfo ( / GetXrefs XrList Opened Data Path )
   
    (defun GetXrefs (/ tempData tempEnt XrefList)
       
        (while (setq tempData (tblnext "block" (not tempData)))
            (if (equal (logand (cdr (assoc 70 tempData)) 4) 4)
                (progn
                    (setq tempEnt (tblobjname "block" (cdr (assoc 2 tempData))))
                    (setq tempData (entget (cdr (assoc 330 (entget tempEnt)))))
                    (setq XrefList
                        (cons
                            (cons
                                tempEnt
                                (
                                    (lambda ( x / InsList NestList )
                                        (foreach i x
                                            (cond
                                                ((equal (car i) 331)
                                                    (setq InsList (cons (cdr i) InsList))
                                                )
                                                ((equal (car i) 332)
                                                    (setq NestList (cons (cdr i) NestList))
                                                )
                                            )
                                        )
                                        (list InsList NestList)
                                    )
                                    (member '(102 . "{BLKREFS") tempData)
                                )
                            )
                            XrefList
                        )
                    )
                )
            )
        )
        XrefList
    )
    ;-----------------------------------------------------
    (if (setq XrList (GetXrefs))
        (progn
            (setq Opened (open (setq Path (strcat (getvar 'DwgPrefix) (vl-filename-base (getvar 'DwgName)) "_Xref.log")) "w"))
            (foreach i XrList
                (setq Data (entget (car i)))
                (write-line (strcat "Xref name: " (cdr (assoc 2 Data))) Opened)
                (write-line (strcat "\tSaved path: " (cdr (assoc 1 Data))) Opened)
                (write-line (strcat "\tFound at path: " (findfile (cdr (assoc 1 Data)))) Opened)
                (write-line "\tInserted at:" Opened)
                (foreach j (cadr i)
                    (setq Data (entget j))
                    (write-line (strcat "\t\tLayout: " (cdr (assoc 410 Data))) Opened)
                    (write-line (strcat "\t\tInsertion point: " (vl-princ-to-string (cdr (assoc 10 Data)))) Opened)
                    (write-line (strcat "\t\tScale[X Y Z]: " (rtos (cdr (assoc 41 Data))) " " (rtos (cdr (assoc 42 Data))) " " (rtos (cdr (assoc 43 Data)))) Opened)
                    (write-line (strcat "\t\tRotation: " (rtos (cdr (assoc 50 Data)))) Opened)
                    (write-line (strcat "\t\tLayer: " (cdr (assoc 8 Data))) Opened)
                )
                (write-line "\tNested xrefs:" Opened)
                (foreach j (caddr i)
                    (write-line (strcat "\t\t" (cdr (assoc 2 (entget j)))) Opened)
                )
            )
            (close Opened)
            (prompt (strcat "\n Log at: " Path))
        )
        (prompt "\n No xrefs within drawing.")
    )
    (princ)
)


[Krushert]

Try this.

Code: [Select]

  Snipped 

Very interesting tool.  I have no need for it but a very interesting tool none the less. 

[barc]

Thanks Tim, cool tool.  That's very close to what I need.  I'm going to look at it tonight to see if I can "tweak" the output a bit.

Really appreciate the help, this will make the next lunacy from the front office a lot easier to accomplish.

[alanjt]

I completely forgot to post this, but I put together a quick cursor list prompt (using DosLib) the other day...

Code: [Select]

(defun c:XRT (/ choice lst)
  (if (setq choice (dos_popupmenu
                     (setq lst
                            '("testxs - for xref states"
                              "testcoxl - for copy original xref layers properties ( color and linetype )"
                              "testcn - for copy nested entity, or nested layer"
                              "testxopen - for open xref, zoomed to same location"
                              "testexrs - for erase xref annotation scales not referenced"
                              "testrlo - for remove layer overrides ( color, linetype and lineweight )"
                              "testxrlc - for change all selected xref layer colors"
                              "EditLayerFromSelection - change properties of layers based on entity selected"
                             )
                     )
                   )
      )
    (command (strcat "_." (substr (setq choice (nth choice lst)) 1 (vl-string-search " - " choice)))
    )
  )
  (princ)
)

[T.Willey]

Thanks Tim, cool tool.  That's very close to what I need.  I'm going to look at it tonight to see if I can "tweak" the output a bit.

Really appreciate the help, this will make the next lunacy from the front office a lot easier to accomplish.

Good to hear.

Alan - Does that execute the command for you?  It seems like it, but I don't think I have doslib installed, and don't know if I should if the company didn't.  If so, nice tool.

[alanjt]

Thanks Tim, cool tool.  That's very close to what I need.  I'm going to look at it tonight to see if I can "tweak" the output a bit.

Really appreciate the help, this will make the next lunacy from the front office a lot easier to accomplish.

Good to hear.

Alan - Does that execute the command for you?  It seems like it, but I don't think I have doslib installed, and don't know if I should if the company didn't.  If so, nice tool.

Yeah, it's a simple loading list. DosLib has some really useful tools, especially some for quick coding and since it's just an arx that can be easily loaded from the acaddoc.lsp, I don't see a problem using it and/or putting it on the network and having everyone load it.

It's a simple thing, but I found it useful with running your commands in a beta state.

[T.Willey]

Cool idea.  Maybe I'll see about it then.

[alanjt]

Cool idea.  Maybe I'll see about it then.

[hudster]

I'd like the ability to change all lines so that I can change their layer, but they retain their original layer linetype.

[T.Willey]

I'd like the ability to change all lines so that I can change their layer, but they retain their original layer linetype.

To have this done, one would have to setup a reactor base application, as the items would need to be changed after each time the xref is reloaded.  What purpose would this serve?  Is this something so you wouldn't have to change the original xref file?

[hudster]

I work for a building services consultancy, we typically clean xrefs removing the crud we don't need, then we move the remaining info to our standard xref layers, so for exapmle we are producing a ceiling layout, we can freeze the furniture and sanitary ware off, to make the drawing cleaner.

But mostly when we clean up the drawings, things with hidden or centre linetypes become solid and can be misinterpreted as walls.

[Rabbit]

I completely forgot to post this, but I put together a quick cursor list prompt (using DosLib) the other day...

Here's my version of this.  It doesn't require DosLib:

Code: [Select]

;;;Written by Jamie Myers
;;;Loose extrapilation from Tony Tanzillo's XGETSTRING sub-routine
(defun xgetkword (msg StringInput / s)
   (setq s
  (getkword
    (strcat "\n" msg
    (cond (StringInput (strcat " <" StringInput ">: "))
  (t ": ")))))
   (cond ((eq s nil) StringInput) (t s))
)

;;;------------------------------------------------------------------------------------------------
(setq choice "testxs")
(initget "testxs testcoxl testcn testxopen testexrs testrlo testxrlc EditLayerFromSelection")
(setq choice (xgetkword "[testxs/testcoxl/testcn/testxopen/testexrs/testrlo/testxrlc/EditLayerFromSelection] " choice))


[alanjt]

I completely forgot to post this, but I put together a quick cursor list prompt (using DosLib) the other day...

Here's my version of this.  It doesn't require DosLib:

Code: [Select]

;;;Written by Jamie Myers
;;;Loose extrapilation from Tony Tanzillo's XGETSTRING sub-routine
(defun xgetkword (msg StringInput / s)
   (setq s
  (getkword
    (strcat "\n" msg
    (cond (StringInput (strcat " <" StringInput ">: "))
  (t ": ")))))
   (cond ((eq s nil) StringInput) (t s))
)

;;;------------------------------------------------------------------------------------------------
(setq choice "testxs")
(initget "testxs testcoxl testcn testxopen testexrs testrlo testxrlc EditLayerFromSelection")
(setq choice (xgetkword "[testxs/testcoxl/testcn/testxopen/testexrs/testrlo/testxrlc/EditLayerFromSelection] " choice))


Seems like a bit of extra typing just to avoid loading a very useful addon like DosLib.

[Lee Mac]

modify to suit (add/change properties, export result to file ...)

                                    ...Values greater than 1 suggest you may
    ;;      have a CADD Bozo who inadvertantly copied an XREF during
    ;;      a copy sequence, whereas a instance count of 0 suggests
    ;;      said quack deleted the xref during an erase sequence.