Topic: ssget "_w" with filter

[cadman6735]

I am practicing, this code is for nothing other than my education.

I am not sure what I am doing wrong.  I think my (setq sset (ssget...  Is not selecting anything. and gets stuck on (repeat (sslength sset)...

I have found two opions for the sset:

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "TEXT") (cons 0 "MTEXT"))))
(setq sset (ssget "_W" pt1 pt2 '((0 . TEXT) (0 . MTEXT))))
The first line gets stuck on (repeat
The second line gets stuck on its own line "invalid list"

If someone can educate me this would be great
Thanks

(defun c:test ( / )

  (setq pt1 (getpoint "\nPick First Point"))
  (setq pt2 (getcorner pt1 "\nPick Second Point"))
  (setq sset (ssget "W" pt1 pt2 (list (cons 0 "TEXT") (cons 0 "MTEXT"))))
 

  (setq item 0)

  (repeat (sslength sset)

    (setq
      ent   (ssname sset item)
      entData   (entget ent)
      entString   (cdr (assoc 1 (entget ent)))
      entType   (cdr (assoc 0 (entget ent)))
      newString (strcase entString)
      entString (subst (cons 1 newString) (assoc 1 entData) entData)
    )

    (entmod entString)

    (setq item (1+ item))
  )

(princ)
)




;(setq sset (ssget "_W" pt1 pt2 '((0 . TEXT) (0 . MTEXT))))

[ronjonp]

First off .. change your selection filter to this:

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "*TEXT"))))

This will not work:
(setq sset (ssget "W" pt1 pt2 (list (cons 0 "TEXT") (cons 0 "MTEXT"))))

You should check that you have all the appropriate input before you try to repeat:
...and locali(z)(s)e your variables  

Code: [Select]

(defun c:test (/ ent entdata entstring enttype item newstring pt1 pt2 sset)
  (if (and (setq pt1 (getpoint "\nPick First Point"))
  (setq pt2 (getcorner pt1 "\nPick Second Point"))
  (setq sset (ssget "W" pt1 pt2 (list (cons 0 "*TEXT"))))
  (setq item 0)
      )
    (repeat (sslength sset)
      (setq ent      (ssname sset item)
   entdata   (entget ent)
   entstring (cdr (assoc 1 (entget ent)))
   enttype   (cdr (assoc 0 (entget ent)))
   newstring (strcase entstring)
   entstring (subst (cons 1 newstring) (assoc 1 entdata) entdata)
      )
      (entmod entstring)
      (setq item (1+ item))
    )
  )
  (princ)
)
Try pasting this into the command line (sslength nil) ... you need to see what functions will chuck wobblies with invalid data.

[Lee Mac]

When you say, 'gets stuck' I'm assuming you mean it errors, as a repeat expression cannot enter an infinite loop by its definition.

The error would most likely be caused by a null SelectionSet since your filter list will filter out all entities.

By default, the filter list will match all entries using an AND operation, i.e. all conditions in the filter list must be met.

To filter for more than one object we require an OR operation, which can be achieved in one of two ways:

Using the wcmatch OR:

Code: [Select]

(ssget '((0 . "TEXT,MTEXT")))
Using the -4 filter OR:

Code: [Select]

(ssget '((-4 . "<OR") (0 . "TEXT") (0 . "MTEXT") (-4 . "OR>")))
I would use the first one.

Lee

EDIT: When working with SelectionSets, be sure to test for a valid SelectionSet before proceeding to use ssname/sslength/ssmemb/ssdel etc. As SelectionSet functions will error if passed nil for the SelectionSet argument.

i.e.

Code: [Select]

(if (setq ss (ssget ... ))
  -- Your Code Here  --
)

[CAB]

Careful with this as it will get Rtext too.

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "*TEXT"))))
I prefer

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "TEXT,MTEXT"))))

[ronjonp]

Careful with this as it will get Rtext too.

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "*TEXT"))))
I prefer

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "TEXT,MTEXT"))))

I prefer:
(setq sset (ssget "_W" pt1 pt2 '((0 . "TEXT,MTEXT"))))
 

[alanjt]

Careful with this as it will get Rtext too.

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "*TEXT"))))
I prefer

Code: [Select]

(setq sset (ssget "W" pt1 pt2 (list (cons 0 "TEXT,MTEXT"))))

I prefer:
(setq sset (ssget "_W" pt1 pt2 '((0 . "TEXT,MTEXT"))))
 

Well, I prefer

Code: [Select]

(setq sset (ssget "_W" pt1 pt2 '((0 . "MTEXT,TEXT")))) because I like to alphabetize.

[ronjonp]

 

[cadman6735]

Thanks all...

[cadman6735]

Which sel-method allows me to pick individual elements or crossing window.  Same as in the move command or copy command.

or is this a routine all to itself?

[ronjonp]

Which sel-method allows me to pick individual elements or crossing window.  Same as in the move command or copy command.

or is this a routine all to itself?

(SSGET) Gives you a window(s) selection. No need to supply points.

[cadman6735]

um...  I would like to be able to select one item with a pick box, like you see when you first start the move command or select a window of items as if I click off to the side (not hitting an element) it jumps right into a window selection, for multiple items.

[ronjonp]

(ssget) has that exact behavior on my computer    You may want to look into (entsel) for single selection.

[cadman6735]

I'm sorry ronjonp

I didn't remove the getpoint function...

you even told me to do so too...  I must have a hearing problem or something... 

Thanks for your help

[cadman6735]

This is so cool, it is like a new toy or something

Thanks again