Topic: Synchronizing two instances of AutoCADs display window

[chierchio]

I was curious if anyone has written something that will syncronize 2 instances of AutoCAD's display window. I am moving around a lot in a source drawing to paste into others and a LISP that would do this would be sooo nice.

[Andrea]

Hi Chierchio...

first...I can't beleive that your post have been seen by many...and no one reply with any welcome on theswamp.. :pissed:

so...
Welcome aboard  ! 

second...may I ask you why you need to synchronise 2 instance of CAD ?

[mjfarrell]

I was curious if anyone has written something that will syncronize 2 instances of AutoCAD's display window. I am moving around a lot in a source drawing to paste into others and a LISP that would do this would be sooo nice.

does Right-Click paste to original coordinates not do this?

[Kerry]

What do you mean (exactly) by

syncronize 2 instances of AutoCAD's display window.

[xiaxiang]

Maybe two Viewports in one drawing?

[chierchio]

Thanks for your response and your welcome to the swamp.

The reason it would be nice to have the windows synchronize is that I am working on a job that covers a varied area in all directions. I am putting together some construction sequencing and on one monitor I have a instance of AutoCAD with source drawing that shows all the facilities and infrastructure and on the other monitor, another instance of AutoCAD that has drawings that show construction progress month by month. I am looking at a plan on my desk and on  on moving to the location in the source where I need to copy from, then go to the stepped drawing to drop it in. Of course there is a little more to it than that. Copy to original coordinates is fine, but there is a lot of information to do with and going around and searching for this is a bit painful.
I was just curious if anyone knew of a lisp that would help. I can try and write it myself, but why reinvent the wheel.

I was thinking either
a) an invisible attributed block that gets written and read, deleted then purged
or
b) registry write and read

I kind of think b is the better way to go. I believe there is a simple V-LAX procedure to do it. I wrote one 6-7 years ago, but I'd have to go through the procedure again.

Thoughts ?


Thanks,

Chris

[T.Willey]

If you want it to function in two different sessions of Acad, then you will have to write to an external source from one, and read from the other.  I would just write to a temp file, as I don't like messing with the registry if I don't have to, and with writing to a temp file, you can format it any way you want to.

[mjfarrell]

I'm thinking that simply XREFerencing the two drawings together and using COPY NESTED would achieve the desired results and not need two instances of cad or any code to accomplish.

[cmwade77]

I'm thinking that simply XREFerencing the two drawings together and using COPY NESTED would achieve the desired results and not need two instances of cad or any code to accomplish.

I agree completely, but there may be other things that we are not aware of going on here....or a lot of stuff that needs to be copied.

I would also suggest copy with base point.

But if you do want to do this, I strongly recommend a temp file, do not edit the registry (the fewer registry edits the better, otherwise you risk registry fragmentation).

[T.Willey]

Was bored, so thought about this a little, and come up with this.  It is a reactor that will update a text file with the coordinates of the zoom window when you make that drawing not active.

Code: [Select]

(defun DeactiveDoc ( react lst / VpCords )

    (defun VPCords ( )
        ; by MP @ theswamp.org
        (   (lambda (offset)
                (   (lambda (viewctr)
                        (list
                            (mapcar '- viewctr offset)
                            (mapcar '+ viewctr offset)
                        )
                    )
                    (getvar "viewctr")
                )
            )
            (   (lambda (halfHeight aspectRatio)
                    (list
                        (* halfHeight aspectRatio)
                        halfHeight
                    )
                )
                (* 0.5 (getvar "viewsize"))
                (apply '/ (getvar "screensize"))
            )
        )
    )
    ;------------------------------------------------
    (   
        (lambda ( x )
            (foreach i (VpCords)
                (print i x)
            )
            (close x)
        )
        (open "c:/temp/log.log" "w")
    )
)

(if (not GlbReactorDocumentDeactive)
    (setq GlbReactorDocumentDeactive (vlr-docmanager-reactor "tmw:DocumentDeactive" '((:vlr-documentToBeDeactivated . DeactiveDoc))))
)

This next code will zoom the current drawing to the other drawings same coordinates, but you will have to run it when you go to the drawing.

Code: [Select]

(defun c:ZoomTo ( / LogPath Opened ll ur )
    (setq LogPath "c:/temp/log.log")
    (if (findfile LogPath)
        (progn
            (setq Opened (open LogPath "r"))
            (read-line Opened)
            (setq ll (append (read (read-line Opened)) '(0.0)))
            (setq ur (append (read (read-line Opened)) '(0.0)))
            (close Opened)
            (vlax-invoke (vlax-get-Acad-Object) 'ZoomWindow ll ur)
        )
        (prompt "\n No file found.")
    )
    (princ)
)