Topic: layer color

[Andrea]

Hi all...

I need to get the color of a specific layer in LISP...

any idea how ??

thanks.

[daron]

Yeah, ask it in the proper forum. Nevermind, I'll move you to it. Hmm. How do you intend to get the info out of the layer? I believe the activex route makes it easier, but I can't look, don't have cad here. I'm sure dxf will give it to you if it's not bylayer. I believe the dxf value you would look for is 62. Someone correct me if I'm wrong.

[Kerry]

This should give you the idea :

Code: [Select]


;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;; return the item if existing, or nil
;;; kwb 20050104

(defun kbpf:safeitem (collection item / returnvalue)
  (if (not (vl-catch-all-error-p
             (setq returnvalue
                    (vl-catch-all-apply 'vla-item (list collection item)))
           )
      )
    returnvalue
  )
)

;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;; return the color of the named layer, or nil
;;; Does not allow explicitly for TrueColor RGB colors.
;;; kwb 20050104

(defun get_LayerColor (sLayerName / oLayer oColor)
  (if (setq oLayer (kbpf:safeitem
                     (vla-get-layers
                       (vla-get-activedocument (vlax-get-acad-object))
                     )
                     sLayerName
                   )
      )
    (setq oColor (vla-get-color oLayer))
  )
  oColor
)

;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;; kwb 20050104

(defun c:test (/ result)
  (foreach sLayerName '("0" "DoesNotExist")
    (if (setq result (get_LayerColor sLayerName))
      (alert (strcat "Color for Layer '" slayerName "' : " (itoa result)))
      (alert (strcat "Color for Layer '" slayerName "' : undetermined "))
    )
  )
)

[Andrea]

thanks. Kerry,

I've modified the routine for my use and it work well.