Topic: document manager

[Amsterdammed]

Hello there!

I ask just to prevent inventing the wheel again.
I always work with two screens and lovepaperless working, since I travel a lot with my work. SO i always have acad running on one screen and the information i need to design on the other screen, mostly pdf. So everytime i start working i need to open all the documents related to that deg I'm working on. I thought about storing the paths of the document in the deg and open them with a lisp.

I assume others have the same demand for a thing like that and therefore the code might be written already.

Thanks in advance

Bernd

[Lee Mac]

A nice idea - if one did not exist, I'd be willing to spend some time putting one together perhaps 

[HasanCAD]

A nice idea, I am facing the same problem.

[huiz]

You can add hyperlinks to objects. Just put some objects (ie texts describing the needed documents) somewhere outside the drawing, add a hyperlink to those objects and CTRL+click - voila!

[JohnK]

You can add hyperlinks to objects. Just put some objects (ie texts describing the needed documents) somewhere outside the drawing, add a hyperlink to those objects and CTRL+click - voila!

second that.

[Amsterdammed]

I though more about to open the files the first time with getfiled and store the location in non graphic data and then have a command to reopen them the next time, so no big thing at all.

[JohnK]

Okay, quick questions:
Would this progy automatically open the files (all, some, or last)? ...what happens if the file doesnt exist? What happens if the files are not needed any longer (5 yrs down the road)--a persistent reactor (if you decide to go that route) would be a real pain.

[Amsterdammed]

no reactor. Dictionary and you open it on command., so no reactor needed You can show them in a list first and you select what you want to open, and of course you look if the are still there

[JohnK]

like a simple list box? ...cool.

[deegeecees]

Like a command to store open files, then write those paths to xdata. Then a command to pull that info into a listbox for retrieval. Sounds like a good idea.

[Amsterdammed]

a command to open the files in the first place wit getfiled, so you already have the path. then sore it  and get it back with a listbox to select

[Lee Mac]

Quickly scribbled together:

Code: [Select]

(defun c:docset ( / file lst )
  (vl-load-com)
  ;; © Lee Mac 2010

  (if
    (while (setq file (getfiled "Select File to Add to Drawing" (cond ( file (vl-filename-directory file) ) ( "" )) "" 16))
      (setq lst (cons file lst))
    )
    (vlax-ldata-put "DocManagerDocs" "docs" (acad_strlsort lst))
  )

  (princ)
)

(defun c:docget ( / _OpenFiles data )
  (vl-load-com)
  ;; © Lee Mac 2010

  (defun _OpenFiles ( files / Shell )
    (setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))

    (mapcar
      (function
        (lambda ( file )
          (if
            (vl-catch-all-error-p
              (vl-catch-all-apply
                (function vlax-invoke) (list Shell 'Open file)
              )
            )
            (princ (strcat "** Error Opening: " file " **"))
          )
        )
      )
      files
    )

    (vlax-release-object Shell)
  )

  (if (setq data (vlax-ldata-get "DocManagerDocs" "docs"))
    (_OpenFiles
      (vlax-ldata-put "DocManagerDocs" "docs"
        (vl-remove-if-not 'findfile data)
      )
    )   
  )

  (princ)
)

DocSet, stores filename data in drawing dictionary, continuous file selection prompts until user hits cancel.

DocGet, opens stored files.

I'm sure it could be improved upon,

Lee

[stevesfr]

Lee, it boms here thus:

Command: appload
docset.lsp successfully loaded.


Command: ; error: bad argument type: numberp: nil

Steve

[Lee Mac]

I can't seem to reproduce that Steve, furthermore, the code doesn't use any functions which are supplied predominantly with numbers, so I'm a little perplexed at that 

[Amsterdammed]

It works with no problem here....
thanks!!