Topic: Which is more beautiful . . .

[jbuzbee]

I've seen a number of challenges and "why I wrote this" type threads so I thought I try one out:

What initially drew me to AutoLISP was the ability to write quick and dirty routines, on the fly when needed, to cut drafting times in half!  Of course as I learned more my routines became more robust and thus much more complicated.  Did I get caught up in the "figuring out" of a complex process? (remember, I'm an architect, my knowledge of all things digital is very limited!) 

So my question is: Which one of the following routines is more beautiful to you?  Don't make the decision too complicated by arguing function, use, etc.  Just which one are you first drawn too?

A

Code: [Select]

(defun c:MyLine( / )
  (command "line" pause pause "")
  (princ)
  )
B

Code: [Select]

(defun c:MyLine (/ *Error* doc act space p1 p2 pt1 pt2)
  (defun *Error* (Msg)
    (cond ((or (not Msg)
       (member Msg '("console break" "Function cancelled" "quit / exit abort"))
       )
   )
  ((princ (strcat "\nError: " Msg)))
  )
    (princ)
    )
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-StartUndoMark doc)
  (setq act (vlax-get doc 'activespace))
  (cond ((= act 1)
(setq space (vlax-get doc 'modelspace))
)
((= act 0)
(setq space (vlax-get doc 'paperspace))
)
)
  (setq p1 (getpoint "\nSelect start point: "))
  (if p1
    (setq p2 (getpoint p1 "\nSelect end point: "))
    )
  (if (and p1 p2)
    (progn
    (setq pt1 (vlax-3d-point p1)
  pt2 (vlax-3d-point p2)
  )
    (vla-addline space pt1 pt2)
    )
    )
  (vla-EndUndoMark doc)
  (princ)
  )

[T.Willey]

B

[JohnK]

In this case/application/need: A

[pkohut]

A

[Hangman]

... the ability to write quick and dirty routines, on the fly when needed, to cut drafting times in half!

As Se7en mentioned, case/application/need:  I also say  A

... Did I get caught up in the "figuring out" of a complex process?

For this type of function, Yes.  Especially when your initial focus is "... quick and dirty routines, on the fly when needed, to cut drafting times in half!"

However, ... It's sooo much fun to create, build, modify, and watch your creation function and florish and improve your mundane drafting experience.  So, B.    

[LE3]

A

[ronjonp]

C 

Code: [Select]

(defun addline (/ e p1 p2)
  (and (setq p1 (getpoint "\nSpecify first point:"))
       (setq p2 (getpoint p1 "\nSpecify next point:"))
       (setq e (entmakex (list '(0 . "LINE") (cons 10 p1) (cons 11 p2))))
  )
  e
)
(addline)

[pkohut]

C is so much better than the others. A, makes me cringe, and B provided a WTHIT moment.

[Aerdvark]

C for shure.

[dgorsman]

For the intention, A.  I would say B, but 1) no code comments 2) no prefix comments explaining what it does and what its for, and 3) OVERKILL is a command, not a way of life.   

[Chris]

for Simplicity A
overall C

[alanjt]

C, but if I were to use A, I'd take the following route:

Code: [Select]

(defun c:A2 (/ p1 p2)
  (if (and (setq p1 (getpoint "\nSpecify first point: "))
           (setq p2 (getpoint p1 "\nSpecify next point: "))
      )
    (command "_.line" "_non" p1 "_non" p2 "")
  )
  (princ)
)

[MP]

If I had to go the (B) ActiveX route ...

Code: [Select]

(defun c:Quick_And_Dirty_Alternative_D ( / p1 p2 doc )

    [color=green];;  For this exercise a non wcs is not corrected for
    ;;  and thus will produce shit results just like the
    ;;  other examples. No hate, just sayin'.[/color]

    (if
        (and
            (setq p1 (getpoint "\nSelect start point: "))
            (setq p2 (getpoint p1 "\nSelect end point: "))
        )
        (progn
            (vla-StartUndoMark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
            (vla-addline
                (vlax-get doc
                    (if (eq 1 (getvar "cvport"))
                        'PaperSpace
                        'ModelSpace
                    )
                )
                (vlax-3d-point p1)
                (vlax-3d-point p2)
            )
            (vla-EndUndoMark doc)
        )
    )

    (princ)

)

[alanjt]

Code: [Select]

   [color=green];;  For this exercise a non wcs is not corrected for
    ;;  and thus will produce shit results just like the
    ;;  other examples. No hate, just sayin'.[/color]

Minus the command one.

[MP]

true / sorry / that's what I get for posting quick and dirty