Topic: Issue with ' vlax-curve-getClosestPointTo '

[T.Willey]

With the sample code and drawing you can see that on the candy cane looking object that ' vlax-curve-getClosestPointTo ' does not return the closest point along the object.  I was wondering if anyone else has seen this, and if there is a way to fix it?

The two yellow lines represent the start point of the curve to the cursor location, then cursor location to where ' vlax-curve-getClosestPointTo ' is selecting the point.
The red line is just start point of the curve to the point returned by ' vlax-curve-getClosestPointTo '.

You will notice that on the other objects in the drawing, besides the solid, the lines are shown correctly.  If you change the UCS to world, and the run the program, then it will show correctly on the candy cane, but not the other two.  So now I'm back to the original section in the post.  I have tried ' trans 'ing the points different ways, but nothing I have thought of has worked.

Thanks.

Code: [Select]

(defun c:Test ( / Sel Ent Norm StPt Ext GrList tempPt Pt )
   
    (setq Sel (entsel "\n Select candy cane looking object: "))
    (setq Ent (car Sel))
    (setq StPt (vlax-curve-getPointAtParam Ent (vlax-curve-getStartParam Ent)))
    (setq Norm (cdr (assoc 210 (entget Ent))))
    (while (and (not Ext) (setq GrList (grread T 13 1)))
        (cond
            ((equal (car GrList) 5)
                (setq tempPt (vlax-curve-getClosestPointTo Ent (trans (cadr GrList) 1 0) nil))
                (redraw)
                (grvecs
                    (list
                        1
                        (trans StPt 0 1)
                        (trans tempPt 0 1)
                        2
                        (trans StPt 0 1)
                        (cadr GrList)
                        2
                        (cadr GrList)
                        (trans tempPt 0 1)
                    )
                )
            )
            ((equal (car GrList) 3)
                (setq Pt (vlax-curve-getClosestPointTo Ent (trans (cadr GrList) 1 0) nil))
            )
            (
                (and
                    (equal (car GrList) 2)
                    (member (cadr GrList) '(13))
                )
                (setq Ext T)
            )
            ((member (car GrList) '(11 25))
                (setq Ext T)
            )
        )
    )
    (redraw)
    (princ)
)


[MP]

Don't have time to test your code Tim but I've had vlax-curve-getClosestPointTo problems with large drawings (with respect to coordinate extremes) to the extent I had to write my own version of said function because I could not rely on the native one. The problems I had were not related to non WCS scenarios. Hope you find a suitable solution quickly.

[T.Willey]

Thanks for the heads up Michael.  I'm studying vectors and stuff right now, so maybe I'll see if I can roll my own, if that is the only way.

[LE3]

Hola Tim,

I recall doing more transformations for the getClosestPointTo(); in arx for a custom getCurveSnapAngle() function based on selected point on a curve object.... let me see if I can port the steps back to autocad lisp... as soon I get a chance (guess spent more time typing this )

[T.Willey]

Thanks Luis.

[LE3]

Thanks Luis.

OK.... I see there are not the same arguments in ARX ... hmmm...

Did a quick try with a change on this line:
(setq tempPt (vlax-curve-getClosestPointTo Ent (cadr GrList) nil))

Can you tested?

[T.Willey]

That didn't work either Luis.

No problem.  I can do some more research into math ( have to re/learn things ), and see if I can roll my own, as I think that is going to be the only way.

[LE3]

That didn't work either Luis.

No problem.  I can do some more research into math ( have to re/learn things ), and see if I can roll my own, as I think that is going to be the only way.

it is obvious that I do not know what you are trying to do, have a look at the image: (if I get a chance will try to play more later today...)

(will post another image this one looks weird....) - uploaded (as zips sorry non displayed right here) two look into any of both... is that the right output?

[T.Willey]

I'm trying to track the cursor movement along the selected curve in any UCS.

[MP]

Thanks for the heads up Michael.  I'm studying vectors and stuff right now, so maybe I'll see if I can roll my own, if that is the only way.

You're welcome Tim, I have every confidence you'll pen an elegant solution and will enjoy the process.

[T.Willey]

Thanks for the vote of confidence Michael.  Will post what I have, when I have it.

Luis,

Yours seems not to be working at all correctly.  I don't have a screen capture program that will output gif files, so I can't show you have it works on my screen, but it is better than that.  I will see what I can come up with.  Thanks for testing it.

[LE3]

I see, sorry about that... the more older I get, the more I forget, or need more detailed explanations, to understand......... 

Luis,

Yours seems not to be working at all correctly.  I don't have a screen capture program that will output gif files, so I can't show you have it works on my screen, but it is better than that.  I will see what I can come up with.  Thanks for testing it.

[gile]

Hi Tim,

Maybe I misundertood the question (one more time) but...

I did some test with your code and IMO all is working as expected.
The point returned by (cadr grList) owns to the current UCS plane, if the curve construction plane is different than this one, the line between the cursor point and the closest point on curve neithe owns the curve plane nor to the current UCS one so it doesn't diplays perpendicular to the curve.

Try adding:
(entmake (list '(0 . "LINE") (cons 10 tempPt) (cons 11 (trans (cadr grList) 1 0))))
in the ((equal (car GrList) 3) ...) expression, pick some points then use rotate3d to see these lines against the curve.

[CAB]

Great explanation gile.
I spent several hours trying to figure this out and had a general idea what was wrong but you have confirmed it.

[T.Willey]

I did some test with your code and IMO all is working as expected.
The point returned by (cadr grList) owns to the current UCS plane, if the curve construction plane is different than this one, the line between the cursor point and the closest point on curve neithe owns the curve plane nor to the current UCS one so it doesn't diplays perpendicular to the curve.

I think you understand correctly, but I was trying to find a way to translate the point returned by grread, so that it would show up on the entity.  So I know that grread returns the point in the current UCS, which doesn't necessarily mean that is the CS of the view or the OCS of the object, so I was trying to find a way that I could translate the point shown, be the closest to the entity.  I hope that makes sense.  If not let me know and I will try and explain it a little better.

So I think my basic problem is trying to translate the point the cursor is at on the screen, to relate more to the entity correctly.

[CAB]

I suspect you will need to change the UCS to match that of the object in order to relate the cursor to it.
Just guessing on my end.

[gile]

If I keep on understanding, the easiest way should be, as CAB said, to change the current UCS :
(command "_.ucs" "_object" ent)

An other way is to project the point returned by (cadr grList) on the entity plane about the current view direction.
Here's an example:

Code: [Select]

(defun c:Test (/ Sel Ent Norm vDir StPt Ext GrList tempPt projPt)

  (setq Sel (entsel "\n Select candy cane looking object: "))
  (setq Ent (car Sel))
  (setq    StPt (vlax-curve-getPointAtParam
           Ent
           (vlax-curve-getStartParam Ent)
         )
  )
  (setq    Norm (cdr (assoc 210 (entget Ent)))
    vDir (trans '(0. 0. 1.) 2 0 T)
  )
  (while (and (not Ext) (setq GrList (grread T 13 1)))
    (cond
      ((equal (car GrList) 5)
       (setq projPt (ProjectPointOnPlane
              (trans (cadr grList) 1 0)
              vDir
              stPt
              norm
            )
         tempPt (vlax-curve-getClosestPointTo
              Ent
              projPt
              nil
            )
       )
       (redraw)
       (grvecs
     (list
       1
       (trans StPt 0 1)
       (trans tempPt 0 1)
       2
       (trans StPt 0 1)
       (trans projPt 0 1)
       2
       (trans projPt 0 1)
       (trans tempPt 0 1)
     )
       )
      )
      ((equal (car GrList) 3)
       (entmake
     (list '(0 . "LINE") (cons 10 tempPt) (cons 11 projPt))
       )
      )
      (
       (and
     (equal (car GrList) 2)
     (member (cadr GrList) '(13))
       )
       (setq Ext T)
      )
      ((member (car GrList) '(11 25))
       (setq Ext T)
      )
    )
  )
  (redraw)
  (princ)
)

;; ProjectPointOnPlane (gile)
;; Returns the projected point on the specified plane
;;
;; Arguments
;; pt: the point to be projected
;; dir: the projection direction vector
;; org: a point on the projection plane
;; nor: the projection plane normal vector

(defun ProjectPointOnPlane (pt dir org nor / scl)
  (if (and
(/= 0 (setq scl (DotProduct nor dir)))
(setq scl (/ (DotProduct nor (mapcar '- pt org)) scl))
      )
    (mapcar '+ pt (mapcar '(lambda (x) (* x (- scl))) dir))
  )
)

;; DotProduct (gile)
;; Returns the dot product (scalar product) of two vectors
;;
;; Arguments : two vectors

(defun DotProduct (v1 v2) (apply '+ (mapcar '* v1 v2)))

[LE3]

I still don't know what it is the idea  but, end up doing what I mentioned about arx [ if (pCurve->getClosestPointTo(pickPoint, vDisplay, pClosest) != Acad::eOk) return; ]
Have a look at the image, if that is not what you are trying to do well...

[gile]

Corrected a mistake in the ProjectPointOnPlane function.

It seems to work as expected (as Luis's) now.

[LE3]

I think, I was able to figure out the name in lisp from the arx function, and did the corrections (and no need of arx usage or c# that i did):

Code: [Select]

(defun c:Tester2 ( / Sel Ent Norm StPt Ext GrList tempPt Pt )
   
    (setq Sel (entsel "\n Select candy cane looking object: "))
    (setq Ent (car Sel))
    (setq StPt (vlax-curve-getPointAtParam Ent (vlax-curve-getStartParam Ent)))
    (setq Norm (cdr (assoc 210 (entget Ent))))

  (setq wcs 0)
  (setq ucs 1)
  (setq dcs 2)

;;;  (trans pt ucs wcs 0)

(setq vecDCSNormal (list 0 0 1))
  ;(trans vecDCSNormal dcs wcs 1)

    (while (and (not Ext) (setq GrList (grread T 13 1)))
        (cond
            ((equal (car GrList) 5)
                (setq tempPt (vlax-curve-getClosestPointToProjection Ent (trans (cadr GrList) 1 0 0) (trans vecDCSNormal dcs wcs 1)))
                (redraw)
                (grvecs
                    (list
                        1
                        (trans StPt 0 1)
                        (trans tempPt 0 1)
                        2
                        (trans StPt 0 1)
                        (cadr GrList)
                        2
                        (cadr GrList)
                        (trans tempPt 0 1)
                    )
                )
            )
            ((equal (car GrList) 3)
                (setq Pt (vlax-curve-getClosestPointToProjection Ent (trans (cadr GrList) 1 0 0) (trans vecDCSNormal dcs wcs 1)))
            )
            (
                (and
                    (equal (car GrList) 2)
                    (member (cadr GrList) '(13))
                )
                (setq Ext T)
            )
            ((member (car GrList) '(11 25))
                (setq Ext T)
            )
        )
    )
    (redraw)
    (princ)
) [code][/code]

[CAB]

Worked like a charm gile.


Close Luis but still will not track around the entire object.

[LE3]

Close Luis but still will not track around the entire object.

Thank you Alan, I tested both routines on the same drawing(Tim's) and did not noticed any difference - but must be me

[T.Willey]

Thanks you both, Gile and Luis.  They both seems to work as advertised.  Now I just need to study the code, and see how you guys were able to do it.

[CAB]

Close Luis but still will not track around the entire object.

Thank you Alan, I tested both routines on the same drawing(Tim's) and did not noticed any difference - but must be me

Just tried again and no joy. Must be my version of ACAD2000.

[LE3]

Never use that version, could be.

Just tried again and no joy. Must be my version of ACAD2000.

[T.Willey]

It must be Alan, because from looking at the codes, they are both doing the same thing, except Gile is doing the translation himself, while Luis is letting Acad's built in functions handle the translation.  If that is the case, then maybe I'll use Gile's solution, since it works better with older versions of Acad.

Side note:  I was trying to use the view direction system variable ' ViewDir '.  Never thought to translate the normal view direction like both Gile and Luis did.  Very smart.  Now off to study the method behind projecting a point onto a plane.

Thanks again guys!

[LE3]

I'm glad you have your problem solved Tim.

I tried to stay within the built-in functions, but as you if you are going to support previous versions, then Gile's it is a better approach.

Side note:  I was trying to use the view direction system variable ' ViewDir '.  Never thought to translate the normal view direction like both Gile and Luis did.  Very smart.  Now off to study the method behind projecting a point onto a plane.

[gile]

from looking at the codes, they are both doing the same thing

I don't think so.
Luis uses the vlax-curve-getClosestPointToProjection function which project the curve to the view plane, then, calculates the closest point from the cursor (UCS plane) to the projected curve and project this point back to the curve.

The way I use is to project the cursor point on the curve plane along the view direction (which may be a non orthogonal projection) and returns the closest point from this point. It works the same as if the current UCS plane was the same as the the curve plane.

In this little video I first run my 'test' command which draws a red line between the projected point and the returned point. Then I run Luis's 'tester2' in which I add an expression to draw a green line between the cursor point and the returnd point.

Code: [Select]

[...]
((equal (car GrList) 3)
       (setq Pt (vlax-curve-getClosestPointToProjection
  Ent
  (trans (cadr GrList) 1 0 0)
  (trans vecDCSNormal dcs wcs 1)
)
       )
       [color=red](entmake
(list '(0 . "LINE") (cons 10 Pt) (cons 11 (trans (cadr GrList) 1 0)))
       )[/color]
      )
[...]

[LE3]

Nice demo - gile.

Thanks!

edit: added the note below:
When I grow up, I want to be like you [intelligent] (I know it will take me quite some years)

[T.Willey]

Nice explanation Gile.

[T.Willey]

Okay Gile.  I think I understand your code now.  Here it goes.

The dot product will give you angle and magnitude, but since you are using it on two unit vectors, all you get is the angle ( or cosine of the angle ) between the view direction and the normal of the plane.

Code: [Select]

(setq scl (DotProduct nor dir))
Then you make sure that it isn't perpendicular.

Code: [Select]

(not (equal 0. (setq scl (DotProduct nor dir))))
Then you get the dot product of the ' normal of the plane ' and the vector ' from a point on the plane to the point selected '.  This time one is not a unit vectors, so you get the magnitude of the vector also.

Code: [Select]

(DotProduct nor (mapcar (function -) pt org))
Then you divide the previous step, by the first step, so that you get the magnitude ( distance in this case ) from the plane to the point selected.  I had a question here though.  Does the new scalar include an angle also?  or is only the magnitude left?  I would think a partial angle would still be represented in the scalar, unless the angles are equal ( angle between view direction and normal of plane, and angle of normal of plane and angle from point on plane to selected point ).

Code: [Select]

(setq scl (/ (DotProduct nor (mapcar (function -) pt org)) scl))
Since you have a vector ' dir ' and a magnitude ' sc1 ', you multiple them, so that you can get the vector that represents the projection of the selected point to the plane.  But you need the magnitude to go in the opposite direction, so you need a negative magnitude first.

Code: [Select]

(mapcar (function (lambda (x) (* x (- scl)))) dir)
Now that we have a vector that represents the path the point will take to project itself onto the plane, all that is left to do is add the point and the vector.

Code: [Select]

(mapcar (function +) pt (mapcar (function (lambda (x) (* x (- scl)))) dir))
I hope I understood correctly.  Thanks again Gile.  This was a good learning exercise for me.  Not sure if I would have gotten it as quickly as I did without your code to show it.

[gile]

As far as I can read English, you seem to have a good understanding of the method.

It works even the vectors aren't unit vectors.

It's the way used to calculate the intersection between a line (unbounded) and a plane (from here):

Code: [Select]

;;; VXV Returns the dot product of two vectors

(defun vxv (v1 v2)
  (apply '+ (mapcar '* v1 v2))
)

;;================================================================;;

;; ILP (gile)
;; Returns the intersection point between the line defined by two points
;; and the plane defined by a point and a normal vector
;;
;; Arguments
;; p1 et p2 : 3d points which defines the line
;; org : any point of the plane
;; nor : the normal vector of the plane

(defun ilp (p1 p2 org nor / scl)
  (if (and
(/= 0 (setq scl (vxv nor (mapcar '- p2 p1))))
(setq scl (/ (vxv nor (mapcar '- p1 org)) scl))
      )
    (mapcar (function (lambda (x1 x2) (+ (* scl (- x1 x2)) x1)))
    p1
    p2
    )
  )
)

[T.Willey]

Thanks again Gile.  Now I'll see if I understand that code better now.   

[ScottBolton]

Luis / Gile,

  What software are you using to create your gif?

S

[gile]

Luis / Gile,

  What software are you using to create your gif?

S

Camtasia studio

[T.Willey]

Here is the link to the final code that this post relates to.
Copy along curve [ http://www.theswamp.org/index.php?topic=35097.0 ]