Topic: GET COORDINATES FROM SAFEARRY

[psuchewinner]

Ive searched for this and I cant find what Im looking for.  How can I get the coordinates from this:
(setq TextInsertionPoint (vla-get-insertionpoint TextObject))?

I know it is simple but I really dont understand variants and safearrays.

[Gliderider]

Code: [Select]

(setq TextInsertionPoint (vlax-get TextObject 'InsertionPoint ))

that really didn't answer your question did it? Try this

Code: [Select]

(setq coords (vlax-safearray->list (vlax-variant-value TextInsertionPoint)))


[gile]

Hi,

Look at the safearray->list function.

Another way is to use vlax-get instead of a vla-* function which returns a variant:
(vlax-get TextObject 'Insertionpoint) returns a standard LISP list.

You can also use this sub which convert any variant or safearray into LISP data type

Code: [Select]

;; gc:VariantToLispData
;; Converts a variant or a safearray into LISP data (list)
;;
;; Argument: var variant or safearray

(defun gc:VariantToLispData (var)
  (cond
    ((= (type var) 'variant)
     (gc:VariantToLispData (vlax-variant-value var)))
    ((= (type var) 'safearray)
     (mapcar 'gc:VariantToLispData (vlax-safearray->list var))
    )
    (T var)
  )
)
Look at this thread

[psuchewinner]

Awesome, thanks guys.

Does the VLAX work woth all properties?

I will read up on this stuff when I am not quite so busy.

[Kerry]

Here's the one I use for generic conversion ...

Code: [Select]


;;=====================================================
(defun lisp-value (v)
  ;; the Holy Grail of vla->lisp conversion? ;-)
  ;; Copyright 2002 Vladimir Nesterovsky.
  ;; Free for use by any commercial entity with
  ;; less then $100 million annual revenue.
  (cond ((= (type v) 'variant) (lisp-value (variant-value v)))
        ((= (type v) 'safearray) (mapcar 'lisp-value (safearray-value v)))
        (t v)
  )
)
;;
;;=====================================================