Topic: List Printer

[Lee Mac]

I needed something similar to MP's Elist function, but for general lists, so I came up with this:

Code: [Select]

(defun prt ( lst / subprt )
  ;; © Lee Mac 2010
  (vl-load-com)

  (defun subprt ( lst ind / pritem )

    (defun pritem ( item ind )
      (repeat ind (princ "   "))
      (if (member item '("(" ")"))
        (princ item)
        (prin1 item)
      )
      (terpri)
    )

    (if lst
      (if (vl-some 'vl-consp lst)
        (progn
          (pritem "(" ind)
          (foreach x lst
            (if (vl-consp x)
              (if (vl-list-length x)
                (subprt x (1+ ind))
                (pritem x (1+ ind))
              )
              (pritem x (1+ ind))
            )
          )
          (pritem ")" ind)
        )
        (pritem lst ind)
      )     
    )
  )

  (cond (  (not lst) (princ "nil"))

        (  (eq 'ENAME (type lst))

           (subprt (entget lst) 0)
        )
        (  (subprt lst 0))
  )
  (princ)
)

I hope it will help someone, and of course suggestions for improvement are welcome. 

[JohnK]

Whats the Elist function?

(Looking at code now)

[JohnK]

hey?! My list was reformatted?! ...what did you do that for? I'm guessing that youre just reporting something back to the user right 'cause i dont really see a need for reformatting a list other then for aesthetics. Right?

[Lee Mac]

Yeah, its just for reformatting for clarity - I would use it if I am debugging code with a big list structure... else the list is printed in one long line... 

Example:

Code: [Select]

(1 2 (3 5) (1 . 2) 1 2 (1 (2 (3 4) 2)) 1)

becomes:

Code: [Select]

(
   1
   2
   (3 5)
   (1 . 2)
   1
   2
   (
      1
      (
         2
         (3 4)
         2
      )
   )
   1
)


[Lee Mac]

Whats the Elist function?

(Looking at code now)

I'm sure its on here somewhere elist.lsp - prints the list in almost the same format as mine, but is used for 'entget' returns...

[JohnK]

Ah, well, good job. Carry on.

[Lee Mac]

 

[VovKa]

Code: [Select]

(defun pprint (lst ind)
  (strcat ind
 "(\n"
 (apply 'strcat
(mapcar (function (lambda (e)
    (if (and e (listp e) (vl-list-length e) (vl-some 'listp e))
      (pprint e (strcat ind " "))
      (strcat ind " " (vl-prin1-to-string e) "\n")
    )
  )
)
lst
)
 )
 ind
 ")\n"
  )
)
(princ (pprint '(1 2 (3 5) (1 . 2) 1 2 (1 (2 (3 4) 2)) 1) ""))
i use something of this kind to write formatted xml files