Topic: cui-profiles-workspaces

[POCKETS]

Is there a way to save my cui files, workspaces and profiles to a thumbdrive?
I know that profiles can be exported but I can't seem to import them.
Thanking you for all your help.
Pockets

[Krushert]

First, workspaces are a "In-My-Whack-Out-Opinion-of-Describing-It" a child of divorce parents; meaning it belongs to the arg profile and cui, as in the workspace lives in both houses.  So therefore I periodically save my workspace (which reminds me - BRB) and then I export my arg profile to two backup locations one of which is a external hard drive.  My CUIs are monitored for changes by Allway Sync and that is sync to the two locations.  One of the options is to sync when removable device is connected.  This software is really set it up and forget it.

Select condition(s) for starting synchronization automatically.
When removable device is connected  
 
Use this option when one or more of the sync folders in this job are on a removable USB device (USB drive, digital camera, MP3 player, flash card reader, etc.). Synchronization is performed automatically - just insert the device into a USB port. No other interaction is required! Note: this option does not detect when network drives are connected.

My question is why can you import your ARG profiles?  I do my through the Options > Profile tab  Maybe I am missing something from your post.

[alanjt]

I actually did this quickie today:

Code: [Select]

(defun c:BackUP (/ str)
  (vl-load-com)
  (vl-mkdir "c:\\BackUP")
  (setq str "")
  (foreach file '("acad" "civil" "custom" "land")
    (foreach ext '(".cui" ".cuix" ".mnl" ".mns" ".mnu" ".pgp")
      (and (findfile (strcat file ext))
           (setq str (strcat str file ext "\n"))
           (vl-file-copy (findfile (strcat file ext)) (strcat "c:\\BackUP\\" file ext))
      )
    )
  )
  (or (eq str "") (alert (strcat "File(s) backed up to c:\BackUP\n\n" str)))
  (princ)
)
It should take care of everything except Profiles.

[Krushert]

And take a look at this from Se7en for profiles:  http://www.theswamp.org/index.php?topic=14917.0

[Krushert]

I actually did this quickie today:

Code: [Select]

(defun c:BackUP (/ str)
  (vl-load-com)
  (vl-mkdir "c:\\BackUP")
  (setq str "")
  (foreach file '("acad" "civil" "land")
    (foreach ext '(".cui" ".cuix" ".mnu" ".pgp")
      (and (findfile (strcat file ext))
           (setq str (strcat str file ext "\n"))
           (vl-file-copy (findfile (strcat file ext)) (strcat "c:\\BackUP\\" file ext))
      )
    )
  )
  (or (eq str "") (alert (strcat "File(s) backed up to c:\BackUP\n\n" str)))
  (princ)
)
It should take care of everything except Profiles.

Sweeeeeeettt.   :kewl: Very nice.  

Code: [Select]

(foreach file '("acad" "civil" "land" "custom")I would add "custom" to cover any users cui.s

[alanjt]

Sweeeeeeettt.   :kewl: Very nice.  

Thanks.

Code: [Select]

(foreach file '("acad" "civil" "land" "custom")I would add "custom" to cover any users cui.s

Completely forgot about Custom. Updated above and added mns and mnl.

Actually, this might be more versatile. It will just copy everything that matches CUI, MNU, MNL, MNS, CUIX, PGP. Will also ignore any of the 'bak' menu files.

Code: [Select]

(defun c:BackUp (/ str)
  ;; Alan J. Thompson, 04.28.10
  (vl-mkdir "c:\\BackUp")
  (setq str "")
  (foreach file (vl-directory-files (vl-filename-directory (findfile "acad.pgp")))
    (and (wcmatch (strcase file) "*.CUI*,*.MNU,*.MNL,*.MNS,*.PGP")
         (not (wcmatch (strcase file) "*BAK*"))
         (setq str (strcat str file "\n"))
         (vl-file-copy (findfile file) (strcat "c:\\BackUp\\" file))
    )
  )
  (or (eq "" str) (alert (strcat "Files backed up to c:\\BackUp\n\n" str)))
  (princ)
)

[alanjt]

I suppose I could have just used roamablerootprefix and strcat'ed "\\Support" on the end instead of (vl-filename-directory (findfile "acad.pgp"))).
Oh well, 6 in one, half a dozen in the other.

[POCKETS]

Thank you, Alan
Pockets

[alanjt]

Thank you, Alan
Pockets

You're welcome.