Topic: Question about SSDel

[alanjt]

If I define a selection set to a variable, then copy that variable (assign it to another), and the ssdel an ename out of the variable, why does it remove it from the first variable selection set?

eg.

Code: [Select]

Command: (sslength (setq s1 (ssget)))

Select objects: Specify opposite corner: 8 found

Select objects:
8

Command: (setq s2 s1)
<Selection set: ffea>

Command: (sslength (ssdel (ssname s2 0) s2))
7

Command: (sslength s1)
7

[MP]

for performance and economy reasons selection sets are "special" (not like se7en) in that they behave more like pointers, thus when you set one selection set to another they both actually point to the same object

[Jeff_M]

Short answer...... Because both variable are referencing the same SelectionSet - <Selection set: ffea>

Longer answer, someone should be along with one Crud, Trauma happens quick!

[alanjt]

OK, that make sense. I guess I was thinking about it like a list. Thanks guys.

[alanjt]

I was trying to accomplish this:

Code: [Select]

(defun test (ss)
  (while (setq e (ssname ss 0))
    (cons e (test (ssdel e ss)))
  ) ;_ while
) ;_ defun

[color=red]OR[/color]

(defun test (ss / s2)
  (while (setq e (ssname (setq s2 ss) 0))
    (cons e (test (ssdel e s2)))
  ) ;_ while
) ;_ defun

But, I'll just use this:

Code: [Select]

(defun AT:SS->List (SS VLA / l)
  ((lambda (i)
     (if VLA
       (while (setq e (ssname SS (setq i (1+ i)))) (setq l (cons (vlax-ename->vla-object e) l)))
       (while (setq e (ssname SS (setq i (1+ i)))) (setq l (cons e l)))
     ) ;_ if
   ) ;_ lambda
    -1
  )
) ;_ defun

[LE3]

to play with a little with lisp again, that you have to do something in the ugly lines below:

Code: [Select]

(setq s2 (ssadd))
(setq i 0)
(repeat (sslength s1)
  (ssadd (ssname s1 i) s2)
  (setq i (1+ i)))
 then you will have another selection...

[alanjt]

to play with a little with lisp again, that you have to do something in the ugly lines below:

Code: [Select]

(setq s2 (ssadd))
(setq i 0)
(repeat (sslength s1)
  (ssadd (ssname s1 i) s2)
  (setq i (1+ i)))
 then you will have another selection...

Ahh, thanks Luis.

[alanjt]

or this...

Code: [Select]

(defun AT:SS->List (SS VLA / l)
  ((lambda (i)
     (if VLA
       (repeat (sslength SS)
         (setq l (cons (vlax-ename->vla-object (ssname SS (setq i (1+ i)))) l))
       ) ;_ repeat
       (repeat (sslength SS) (setq l (cons (ssname SS (setq i (1+ i))) l)))
     ) ;_ if
   ) ;_ lambda
    -1
  )
) ;_ defun

[MP]

I won't bother showing how to copy a selection set since LE3 anted up, so here's a different offering for one of your "alt" approaches ...

Code: [Select]

(defun _PicksetToEnames ( ss )
    (if (eq 'pickset (type ss))
        (mapcar
           '(lambda ( x ) (cadr x))
            (vl-remove-if '(lambda ( x ) (minusp (car x))) (ssnamex ss))
        )
    )
)

[alanjt]

I won't bother showing how to copy a selection set since LE3 anted up, so here's a different offering for one of your "alt" approaches ...

Code: [Select]

(defun _PicksetToEnames ( ss )
    (if (eq 'pickset (type ss))
        (mapcar
           '(lambda ( x ) (cadr x))
            (vl-remove-if '(lambda ( x ) (minusp (car x))) (ssnamex ss))
        )
    )
)

I used something very similar (used vl-remove-if 'listp), but wanted to replace it with something a bit faster (slow day and wanted to do a little optimizing).

Code: [Select]

Command: (benchmark '( (_picksettoenames s) (at:ss->list s nil) ))
Elapsed milliseconds / relative speed for 32768 iteration(s):

    (AT:SS->LIST S nil)......1890 / 3.71 <fastest>
    (_PICKSETTOENAMES S).....7016 / 1 <slowest>
Using my While one.



I hope you don't think I'm trying to tell you anything. I've learned so much just from looking at your posted examples.

[alanjt]

I completely forgot about checking if the variable was valid. Thank you.
I think I'll go with this...

Code: [Select]

(defun AT:SS->List (SS VLA / l)
  (if (eq 'PICKSET (type SS))
    ((lambda (i)
       (while (setq e (ssname SS (setq i (1+ i))))
         (if VLA
           (setq l (cons (vlax-ename->vla-object e) l))
           (setq l (cons e l))
         ) ;_ if
       ) ;_ while
     ) ;_ lambda
      -1
    )
  ) ;_ if
) ;_ defun

[MP]

Code: [Select]

   (AT:SS->LIST S nil)......1890 / 3.71 <fastest>
    (_PICKSETTOENAMES S).....7016 / 1 <slowest>

cool, on quick glance I wouldn't have guessed that significant a performance difference.

I hope you don't think I'm trying to tell you anything.

The minute a man thinks he knows it all he becomes a fool, subtitle: bring it on brother, it's all good, and thanks for the edumacation.

I've learned so much just from looking at your posted examples.

Thanks for the acknowledgment Alan, nice of you to say and it takes the edge off the smashing headache I'm sporting today.

[alanjt]

Code: [Select]

    (AT:SS->LIST S nil)......1890 / 3.71 <fastest>
    (_PICKSETTOENAMES S).....7016 / 1 <slowest>

cool, on quick glance I wouldn't have guessed that significant a performance difference.

I hope you don't think I'm trying to tell you anything.

The minute a man thinks he knows it all he becomes a fool, subtitle: bring it on brother, it's all good, and thanks for the edumacation.

I've learned so much just from looking at your posted examples.

Thanks for the acknowledgment Alan, nice of you to say and it takes the edge off the smashing headache I'm sporting today.

I was pretty surprised too.
Thanks for understanding.

[CAB]

Give this a test drive

Code: [Select]

;;  http://www.theswamp.org/index.php?topic=14184.msg171131#msg171131
(defun ss->lst (ss / i ename result)
  (and (eq 'pickset (type ss))
       (setq i -1)
       (while (setq ename (ssname ss (setq i (1+ i))))
         (setq result (cons ename result))
       )
  )
  result
)

[MP]

Give this a test drive

Code: [Select]

;;  http://www.theswamp.org/index.php?topic=14184.msg171131#msg171131
(defun ss->lst (ss / i ename result)
  (and (eq 'pickset (type ss))
       (setq i -1)
       (while (setq ename (ssname ss (setq i (1+ i))))
         (setq result (cons ename result))
       )
  )
  result
)

yep

[LE3]

by looking into the last two post... it took me way back to the x-arch or reni urban place, because of the code style - ish

when I was like 4 or 7 years   

[MP]

Ah yes, the good old daze when Tony would publicly, and gratuitously insult Reini, calling him a fool etc. I also remember coming to your defense several times when you were in his sights. Of course, Tony and I got along famously, almost as well as I got on with Frank Oquendo.  :whistle:

[LE3]

Ah yes, the good old daze when Tony would publicly, and gratuitously insult Reini, calling him a fool etc. I also remember coming to your defense several times when you were in his sights. Of course, Tony and I got along famously, almost as well as I got on with Frank Oquendo.  :whistle:

any idea of what happen to Frank Oquendo?


and yes the friendly days....

[MP]

Don't have a clue, I always assumed he legally changed his name because he appeared to vanish. Maybe Bobby Jones (who occasionally hangs here) knows, they were once business partners of sorts.

[MP]

Spider senses are tingling, here comes Bobby now!

[Bobby C. Jones]

Don't have a clue, I always assumed he legally changed his name because he appeared to vanish. Maybe Bobby Jones (who occasionally hangs here) knows, they were once business partners of sorts.

I hang when possible, I lurk even more, and I try to refrain from trolling as much as possible.

I haven't heard from Frank in a long while.  I miss those good 'ol days too

[LE3]

Spider senses are tingling, here comes Bobby now!

Also, about Robert Bell.... or maybe he is in the ng's still - but I do not frequent there as I use to....

[Bobby C. Jones]

Spider senses are tingling, here comes Bobby now!

That's amazing

[Bobby C. Jones]

Spider senses are tingling, here comes Bobby now!

Also, about Robert Bell.... or maybe he is in the ng's still - but I do not frequent there as I use to....

Bob hangs a lot in the AUGI groups.  I would visit there more often, but I don't like the UI as much as the swamp.

[MP]

I hang when possible, I lurk even more, and I try to refrain from trolling as much as possible.

I haven't heard from Frank in a long while.  I miss those good 'ol days too

evidently

Also, about Robert Bell.... or maybe he is in the ng's still - but I do not frequent there as I use to....

once I found the swamp I basically dropped the audesk ngs

That's amazing

the powers come and go, if only I could harness them on demand

Also, about Robert Bell.... or maybe he is in the ng's still - but I do not frequent there as I use to....

augi sucks on so many levels :ugly:

[Lee Mac]

If you really wanted to use recursion, perhaps

Code: [Select]

(defun ss->lst (ss / f)

  (defun f (i / e)
    (if (<= 0 i)
      (cons (ssname ss i) (f (1- i)))))

  (f (1- (sslength ss))))

But its not really worth it imo, considering the unpredictable sizes of SelSets coupled with the performance deficits of recursive iteration.

[alanjt]

If you really wanted to use recursion, perhaps

Code: [Select]

(defun ss->lst (ss / f)

  (defun f (i / e)
    (if (<= 0 i)
      (cons (ssname ss i) (f (1- i)))))

  (f (1- (sslength ss))))

But its not really worth it imo, considering the unpredictable sizes of SelSets coupled with the performance deficits of recursive iteration.

Nice.

You're probably right. I was more curious than anything.

[alanjt]

Counterpart:

Code: [Select]

;;; Convert list of ename objects to 1 selection set
;;; L - list of enames
;;; Alan J. Thompson, 04.01.10
(defun AT:List->SS (L)
  (if (cdr L)
    (ssadd (car L) (AT:List->SS (cdr L)))
    (ssadd (car L))
  ) ;_ if
) ;_ defun