Topic: -={ Challenge }=- Subst at n

[Lee Mac]

The Challenge: to substitute an item in a list at a specified position.

Example:

Code: [Select]

(subst_at_n 2 '(0 1 2 3 4 5) 4)

=>  (0 1 2 3 2 5)


I figure there are quite a few ways to do this, so the challenge might be interesting.

I apologise in advance if this has been addressed in the past - I did do a search, but was perhaps not thorough enough.

My entry:

Code: [Select]

 (defun Subst_at_n (item lst n)
    (if lst
      (cons (if (zerop n) item (car lst))
            (Subst_at_n item (cdr lst) (1- n)))
      (car lst)))


[alanjt]

I wrote this back in June...

Code: [Select]

;;; Replace nth item in list
;;; #Nth - nth number in list to replace
;;; #New - replacement item
;;; #List - list to process
;;; Alan J. Thompson, 06.16.09
(defun AT:NthReplace (#Nth #New #List / #Count)
  (setq #Count -1)
  (mapcar '(lambda (x)
             (if (eq #Nth (setq #Count (1+ #Count)))
               #New
               x
             ) ;_ if
           ) ;_ lambda
          #List
  ) ;_ mapcar
) ;_ defun
This would be better...

Code: [Select]

(defun AT:NthReplace (#Nth #New #List / #Count)
  (if (zerop #Nth)
    (cons #New (cdr #List))
    (progn (setq #Count -1)
           (mapcar (function (lambda (x)
                               (if (eq #Nth (setq #Count (1+ #Count)))
                                 #New
                                 x
                               ) ;_ if
                             ) ;_ lambda
                   ) ;_ function
                   #List
           ) ;_ mapcar
    ) ;_ progn
  ) ;_ if
) ;_ defun


[alanjt]

BTW Lee...

Code: [Select]

([color=red]Mac-[/color]Subst_at_n item (cdr lst) (1- n)))

[Lee Mac]

Wowza... I made that change in the post box, something I'm never going to do again... Thanks alan

[alanjt]

Wowza... I made that change in the post box, something I'm never going to do again... Thanks alan

I've done the exact same thing.

[CAB]

Code: [Select]

;; variation by CAB
(defun replace_CAB (lst i itm)
  (setq i (1+ i))
  (mapcar '(lambda (x) (if (zerop (setq i (1- i))) itm x)) lst)
)

[CAB]

http://www.theswamp.org/index.php?topic=14170.0

[MP]

Quick & dirty & just for fun ...

Code: [Select]

(defun _ReplaceNth ( n item lst / f )

    (defun f ()
        (if (zerop n)
            (progn (defun f () x) item)
            (progn (setq n (1- n)) x)
        )    
    )            
        
    (mapcar (function (lambda (x) (f))) lst)
        
)

[MP]

and for even more fun ...

Code: [Select]

(defun _ReplaceNth ( n item lst )
    (   (lambda (f) (mapcar (function (lambda (x) (f))) lst))
        (lambda ( )
            (if (zerop n)
                (progn (defun f () x) item)
                (progn (setq n (1- n)) x)
            )    
        )            
    )
)
 

[It's Alive!]

Code: [Select]

#include "stdafx.h"
#include <array>
#include <iostream>

using namespace std;
using namespace std::tr1;

int _tmain(int argc, _TCHAR* argv[])
{
  array<int,9> ints = {1,2,3,4,5,6,7,8,9};
  ints[2] = 9;
  for_each(ints.begin(), ints.end(), [](int n) { cout << n << " "; });
  cout << endl;
  system("pause");
  return 0;
}


[LE3]

Be careful don't end like me and be tagged for ever and be part of a real facts...      

Here is something from my very old lisp coding school.-

Code: [Select]

(defun substAtPosition  (newItem position oldList / cont lth lst)
  (setq cont 0
lth  (length oldList))
  (while (/= cont position)
    (setq lst (append lst (list (nth cont oldList)))
 cont (1+ cont)))
  (setq lst (append lst (list newItem))
cont (1+ cont))
  (while (< cont lth)
    (setq lst (append lst (list (nth cont oldList)))
 cont (1+ cont)))
  lst)
 

(substAtPosition 2 4 '(0 1 2 3 4 5))
(0 1 2 3 2 5)

Wowza... I made that change in the post box, something I'm never going to do again... Thanks alan

[Kerry]

int _tmain(int argc, _TCHAR* argv[])

sick puppy 

[It's Alive!]

I thought you might like the lambda expression, I can format it like lisp 

Code: [Select]

for_each(
 ints.begin(),
    ints.end(),
        [](int n) { cout << n << " "; });


[Lee Mac]

Nice one Michael - I love that 'double-defun' trick 

[Lee Mac]

http://www.theswamp.org/index.php?topic=14170.0

I knew there would be another one, there was no way this operation was untouched