Topic: Strip block of Dynamic Properties

[Shade]

Does any one have a lisp that will strip the dynamic properties from dynamic blocks?

I have an extensive DB library which I use quite heavily throughout my drawings, some payed for, others spent serious time on developing.
I starting freelance drafting about a year ago and would like to protect my investment in the DB's, both in money as well as time and effort.
My DB collection helps me produce drawings quicker and more accurately then the clients can in house.  Which is why my clients come to me with the work.
I have released the dwg files with the DB's, in them to the clients and have notice they are starting to use them in their offices.
One client has drop my services altogether because he is able to work cheaper in house with my DB collection then before.
I would like to strip any DB from my drawings to prevent other's from following suit.
The only way I figure to protect my db now is to explode all blocks before transferring to the clients.
If anyone has a better way of protecting my investment, please feel free to express it.

Any help would be greatly appreciated.....

Thanks
Shade 




 

[MP]

What version of AutoCAD? What happens if you do a "Save As" to the lowest version available, does that "lobotomize" the dynamic blocks?

edit: DOH, just saw your sig. Last question stands.

[MP]

Okay, that doesn't work. I have 2008. Saved to r14 and re-opened -- the dynamic data round tripped ok.

Some lisp should be able to lobotomize it no prob tho.

[alanjt]

Just an example:

Code: [Select]

(vla-ConvertToStaticBlock (vlax-ename->vla-object (car (entsel))) "NewName")

[MP]

yep

[alanjt]

Granted, if you select multiples of the same Dynamic block, it will error. However, you just convert the first one, then rename the remaining accordingly.

Code: [Select]

(vla-put-name x "NewName")

[MP]

Be careful, that strategy will introduce errors unless all instances of a given block share the same state.

[Lee Mac]

Just an example:

Code: [Select]

(vla-ConvertToStaticBlock (vlax-ename->vla-object (car (entsel))) "NewName")

That's a new one for me thanks Alan 

[alanjt]

Be careful, that strategy will introduce errors unless all instances of a given block share the same state.

Oh yeah, I wasn't thinking about that.

Just an example:

Code: [Select]

(vla-ConvertToStaticBlock (vlax-ename->vla-object (car (entsel))) "NewName")

That's a new one for me thanks Alan 

  I remembered seeing it a while back when I wrote the routine that allows one to change the visibility states for multiple Dynamic blocks at once.

[MP]

Friday quick & dirty freebie ... not the most efficient but free ...

Code: [Select]

(defun c:UnDynamic

    (   /
        _get_item
        _right
        _make_key
        _dynamic->static_block
        _get_locked
        _get_dynamic_inserts
        _main
    )

    (defun _get_item ( collection key / item )
        (vl-catch-all-apply
           '(lambda ( ) (setq item (vla-item collection key)))
        )
        item
    )

    (defun _right ( str n / len )
        (if (< n (setq len (strlen str)))
            (substr str (1+ (- len n)))
            str
        )
    )

    (defun _make_key ( collection prefix len / key )
        (   (lambda ( i pad )
                (while
                    (_get_item collection
                        (setq key
                            (strcat prefix
                                (_right
                                    (strcat pad (itoa (setq i (1+ i))))
                                    len
                                )
                            )
                        )
                    )
                )
                key
            )
            0
            (   (lambda ( pad )
                    (while (< (strlen pad) len)
                        (setq pad (strcat "0" pad))
                    )
                    pad
                )
                ""
            )
        )
    )

    (defun _dynamic->static_block ( blocks insert len )
        (vla-ConvertToStaticBlock
            insert
            (_make_key blocks "STATIC_" len)
        )
    )

    (defun _get_locked ( layers / locked )
        (vlax-for layer layers
            (if (eq :vlax-true (vla-get-lock layer))
                (setq locked (cons layer locked))
            )
        )
        locked
    )

    (defun _get_dynamic_inserts ( blocks / inserts )
        (vlax-for block blocks
            (vlax-for object block
                (if (eq "AcDbBlockReference" (vla-get-objectname object))
                    (if (eq :vlax-true (vla-get-isdynamicblock object))
                        (setq inserts (cons object inserts))
                    )
                )
            )
        )
        inserts
    )

    (defun _main ( document / blocks inserts locked len )
        (if
            (setq inserts
                (_get_dynamic_inserts
                    (setq blocks (vla-get-blocks document))
                )
            )
            (progn
                (foreach layer (setq locked (_get_locked (vla-get-layers document)))
                    (vla-put-lock layer :vlax-false)
                )
                (setq len (strlen (itoa (length inserts))))
                (foreach insert inserts
                    (_dynamic->static_block blocks insert len)
                )
                (foreach layer locked
                    (vla-put-lock layer :vlax-true)
                )
            )
        )
        (princ)
    )

    (_main (vla-get-activedocument (vlax-get-acad-object)))

)

[alanjt]

Friday quick & dirty freebie ... not the most efficient but free ...

Alan is right, you really are an artist. Nice work.

[Lee Mac]

Friday quick & dirty freebie ... not the most efficient but free ...

Alan is right, you really are an artist. Nice work.

x2   

[MP]

Tall praise given the source(s). Someday I will be worthy. Thanks guys.

[trogg]

In my CAD customization class, we were warned that after we saved our drawings with dynamic blocks, if we save them as a .dxf we would lose the dynamic block functions and any hyper-links.
just a thought from a newbie.
Although - I really like the code though too

[cmwade77]

The .dxf method would work, but may introduce more errors too.....the code looks good too though.

[mexxx_]

Hello,

I have now found that all lines in the block included. Characterized the block unnecessarily large and blows to the drawing.

[mexxx_]

Hello,

I delete the invisible Objects with this Code. Can you integrate this Code in your Code please?

Code: [Select]

(defun c:delinvb (/ acdoc ss i sset nme Blockdefinition)
  (vl-load-com)
  (setq acdoc (vla-get-activedocument
                (vlax-get-acad-object)
              )
  )
  (if (setq ss (ssget "_:L" '((0 . "INSERT"))))
    (repeat
      (setq i (sslength ss))
      (setq sset (ssname ss (setq i (1- i))))
      (setq nme (cdr (assoc 2 (entget sset))))
      (setq Blockdefinition (vla-item (vla-get-blocks acdoc) nme))
      (if
        (and
          (eq :vlax-false (vla-get-isxref Blockdefinition))
          (eq :vlax-false (vla-get-islayout Blockdefinition))
        )
          (vlax-for x Blockdefinition
       (if(=(vla-get-Visible  x) :vlax-false)
        (vla-delete x)
    )
)
      )
    )
    (princ)
  )
  (vla-regen acdoc acAllViewports)
  (princ)
)
Thanks 

[cadpoobah]

Friday quick & dirty freebie ... not the most efficient but free ...

That's a Fenomonal Friday Freebie, MP!

I made a couple mods.

Mod 1 - I wanted to preserve the original block name and just add the numeric suffix to it, rather than renaming them to the generic "STATIC_#".
In the "_dynamic->static_block" function, I changed:

Code: [Select]

(_make_key blocks "STATIC_" len)was changed to

Code: [Select]

(_make_key blocks (strcat (vla-get-EffectiveName insert) "_") len)
Mod 2 - The function was bombing if the block it found was nested within an Xref.

Code: [Select]

(foreach insert inserts
  (_dynamic->static_block blocks insert len)
)was changed to

Code: [Select]

(foreach insert inserts
  (if (null (wcmatch (vla-get-name insert) "*|*"))
    (_dynamic->static_block blocks insert len)
    )
)
Works great otherwise! Thanks!

[bluepencil]

Hi!I was also looking for a way protect my "investment" in creating dynamic blocks... and I want to also find a way to strip the dynamic properties of the blocks when i pass the drawings to client and other people.  Then i stumbled upon this post...

I tried to make the code into an AUTOLISP and loaded it to my AutoCAD and it gave me this error:

Command: UNDYNAMIC
; error: no function definition: VLAX-GET-ACAD-OBJECT

I am using AutoCAD 2016 (Beta for Mac)... and i am not code-savvy... please can you help me what does it mean?  Or this error happened because I am using AutoCAD for Mac?

Thanks a lot!

[Lee Mac]

The error occurs because you have not issued the (vl-load-com) expression to define the set of ActiveX(COM) functions before attempting to evaluate such functions; however, since you are using AutoCAD for Mac, the ActiveX extensions will be unavailable in any case.

[bluepencil]

Hi Lee Mac,

Are there any workaround for this in the MAC platform?

Thanks!

[Lee Mac]

Are there any workaround for this in the MAC platform?

No, ActiveX(COM) is a proprietary MS technology and so not available on a Mac platform; there are the new setpropertyvalue / getpropertyvalue / dumpallproperties functions, which are an attempt by Autodesk to bridge this shortfall, but these will not help in this particular case.

[bluepencil]

Thanks again!

I guess this means exploding or ref-edit-in-place of dynamic blocks will be part of my workflow... haha.

Thanks!

[Lee Mac]

Or switch to Windows 

[Richardb1208]

Hi All

These lisps are brilliant!! Has anyone created / found a lisp that will take the UNDYNAMIC in a slightly different direction?

I have 400 drawings that contain Dynamic blocks that use the visibility method. I need to lobotomize the blocks at a global level but ensure that the end product is the block renamed to include the visibility state convention. i.e. BlockName_VisibilityState.

Can anyone help?

[ronjonp]

Hi All

These lisps are brilliant!! Has anyone created / found a lisp that will take the UNDYNAMIC in a slightly different direction?

I have 400 drawings that contain Dynamic blocks that use the visibility method. I need to lobotomize the blocks at a global level but ensure that the end product is the block renamed to include the visibility state convention. i.e. BlockName_VisibilityState.

Can anyone help?

Here you go .. welcome to TheSwamp   . be aware that the code does not checked for locked layers.

Code - Auto/Visual Lisp: [Select]

1. (defun c:staticblocks (/ name)
2.   (vl-load-com)
3.   (vlax-for b (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
4.     (vlax-for b2 b
5.       (if (and (vlax-property-available-p b2 'isdynamicblock)
6.           (minusp (vlax-get b2 'isdynamicblock))
7.           (setq name (vl-some '(lambda (prop)
8.                   (if (= "Visibility" (vla-get-propertyname prop))
9.                (vlax-get prop 'value)
10.                   )
11.                 )
12.                (vlax-invoke b2 'getdynamicblockproperties)
13.            )
14.           )
15.      )
16.    (if (tblobjname "block" (setq name (strcat (vla-get-effectivename b2) "_" name)))
17.      (vla-put-name b2 name)
18.      (vla-converttostaticblock b2 name)
19.    )
20.       )
21.     )
22.   )
23.   (princ)
24. )
25.  

*Also if your dynamic blocks have other properties that can change under the visibility state, the renamed block will take on the properties of the first found.

[Lee Mac]

Nice one Ron - though, unfortunately I don't believe that you can rely on the Property Name of the Visibility State parameter being named "Visibility", since any dynamic block parameter may be arbitrarily named.

Therefore, as an extension of your code, I would propose:

Code - Auto/Visual Lisp: [Select]

1. (defun c:staticblocks ( / bln lst vis )
2.     (vlax-for blk (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
3.         (vlax-for obj blk
4.             (if (and (= "AcDbBlockReference" (vla-get-objectname obj))
5.                      (vlax-property-available-p obj 'isdynamicblock)
6.                      (= :vlax-true (vla-get-isdynamicblock obj))
7.                      (or (setq bln (vla-get-effectivename  obj)
8.                                vis (cdr (assoc bln lst))
9.                          )
10.                          (and (setq vis (LM:getvisibilityparametername obj))
11.                               (setq lst (cons (cons bln vis) lst))
12.                          )
13.                      )
14.                      (setq vis (LM:getdynpropvalue obj vis))
15.                 )
16.                 (if (tblsearch "block" (setq bln (strcat bln "_" vis)))
17.                     (vla-put-name obj bln)
18.                     (vla-converttostaticblock obj bln)
19.                 )
20.             )
21.         )
22.     )
23.     (princ)
24. )
25.  
26. ;; Get Dynamic Block Property Value  -  Lee Mac
27. ;; Returns the value of a Dynamic Block property (if present)
28. ;; blk - [vla] VLA Dynamic Block Reference object
29. ;; prp - [str] Dynamic Block property name (case-insensitive)
30.  
31. (defun LM:getdynpropvalue ( blk prp )
32.     (setq prp (strcase prp))
33.     (vl-some '(lambda ( x ) (if (= prp (strcase (vla-get-propertyname x))) (vlax-get x 'value)))
34.         (vlax-invoke blk 'getdynamicblockproperties)
35.     )
36. )
37.  
38. ;; Get Visibility Parameter Name  -  Lee Mac
39. ;; Returns the name of the Visibility Parameter of a Dynamic Block (if present)
40. ;; blk - [vla] VLA Dynamic Block Reference object
41. ;; Returns: [str] Name of Visibility Parameter, else nil
42.  
43. (defun LM:getvisibilityparametername ( blk / vis )  
44.     (if
45.         (and
46.             (vlax-property-available-p blk 'effectivename)
47.             (setq blk
48.                 (vla-item
49.                     (vla-get-blocks (vla-get-document blk))
50.                     (vla-get-effectivename blk)
51.                 )
52.             )
53.             (= :vlax-true (vla-get-isdynamicblock blk))
54.             (= :vlax-true (vla-get-hasextensiondictionary blk))
55.             (setq vis
56.                 (vl-some
57.                    '(lambda ( pair )
58.                         (if
59.                             (and
60.                                 (= 360 (car pair))
61.                                 (= "BLOCKVISIBILITYPARAMETER" (cdr (assoc 0 (entget (cdr pair)))))
62.                             )
63.                             (cdr pair)
64.                         )
65.                     )
66.                     (dictsearch
67.                         (vlax-vla-object->ename (vla-getextensiondictionary blk))
68.                         "ACAD_ENHANCEDBLOCK"
69.                     )
70.                 )
71.             )
72.         )
73.         (cdr (assoc 301 (entget vis)))
74.     )
75. )
76.  
77. (vl-load-com) (princ)

Dynamic Block functions from here.

[Lee Mac]

Maybe the following to account for other dynamic block parameters and for locked layers?

Code - Auto/Visual Lisp: [Select]

1. (defun c:staticblocks ( / doc eff lck lst nbn new obn vis vpl )
2.     (setq doc (vla-get-activedocument (vlax-get-acad-object))
3.           new
4.         (lambda ( old vis / cnt rtn )
5.             (setq cnt 0)
6.             (if (tblsearch "block" (setq rtn (strcat old "_" vis)))
7.                 (while (tblsearch "block" (setq rtn (strcat old "_" vis "_" (itoa (setq cnt (1+ cnt)))))))
8.             )
9.             rtn
10.         )
11.     )
12.     (vlax-for lay (vla-get-layers doc)
13.         (if (= :vlax-true (vla-get-lock lay))
14.             (progn
15.                 (setq lck (cons lay lck))
16.                 (vla-put-lock lay :vlax-false)
17.             )
18.         )
19.     )
20.     (vlax-for blk (vla-get-blocks doc)
21.         (vlax-for obj blk
22.             (cond
23.                 (   (not
24.                         (and
25.                             (= "AcDbBlockReference" (vla-get-objectname obj))
26.                             (vlax-property-available-p obj 'isdynamicblock)
27.                             (= :vlax-true (vla-get-isdynamicblock obj))
28.                         )
29.                     )
30.                 )
31.                 (   (setq obn (vla-get-name obj)
32.                           nbn (cdr (assoc obn lst))
33.                     )
34.                     (vla-put-name obj nbn)                        
35.                 )
36.                 (   (and
37.                         (or (setq eff (vla-get-effectivename obj)
38.                                   vis (cdr (assoc eff vpl))
39.                             )
40.                             (and (setq vis (LM:getvisibilityparametername obj))
41.                                  (setq vpl (cons (cons eff vis) vpl))
42.                             )
43.                         )
44.                         (setq vis (LM:getdynpropvalue obj vis))
45.                         (setq nbn (new eff vis))
46.                     )
47.                     (vla-converttostaticblock obj nbn)
48.                     (setq lst (cons (cons obn nbn) lst))
49.                 )
50.             )
51.         )
52.     )
53.     (foreach lay lck (vla-put-lock lay :vlax-true))
54.     (princ)
55. )
56.  
57. ;; Get Dynamic Block Property Value  -  Lee Mac
58. ;; Returns the value of a Dynamic Block property (if present)
59. ;; blk - [vla] VLA Dynamic Block Reference object
60. ;; prp - [str] Dynamic Block property name (case-insensitive)
61.  
62. (defun LM:getdynpropvalue ( blk prp )
63.     (setq prp (strcase prp))
64.     (vl-some '(lambda ( x ) (if (= prp (strcase (vla-get-propertyname x))) (vlax-get x 'value)))
65.         (vlax-invoke blk 'getdynamicblockproperties)
66.     )
67. )
68.  
69. ;; Get Visibility Parameter Name  -  Lee Mac
70. ;; Returns the name of the Visibility Parameter of a Dynamic Block (if present)
71. ;; blk - [vla] VLA Dynamic Block Reference object
72. ;; Returns: [str] Name of Visibility Parameter, else nil
73.  
74. (defun LM:getvisibilityparametername ( blk / vis )  
75.     (if
76.         (and
77.             (vlax-property-available-p blk 'effectivename)
78.             (setq blk
79.                 (vla-item
80.                     (vla-get-blocks (vla-get-document blk))
81.                     (vla-get-effectivename blk)
82.                 )
83.             )
84.             (= :vlax-true (vla-get-isdynamicblock blk))
85.             (= :vlax-true (vla-get-hasextensiondictionary blk))
86.             (setq vis
87.                 (vl-some
88.                    '(lambda ( pair )
89.                         (if
90.                             (and
91.                                 (= 360 (car pair))
92.                                 (= "BLOCKVISIBILITYPARAMETER" (cdr (assoc 0 (entget (cdr pair)))))
93.                             )
94.                             (cdr pair)
95.                         )
96.                     )
97.                     (dictsearch
98.                         (vlax-vla-object->ename (vla-getextensiondictionary blk))
99.                         "ACAD_ENHANCEDBLOCK"
100.                     )
101.                 )
102.             )
103.         )
104.         (cdr (assoc 301 (entget vis)))
105.     )
106. )
107.  
108. (vl-load-com) (princ)

[ronjonp]

Nice one Ron - though, unfortunately I don't believe that you can rely on the Property Name of the Visibility State parameter being named "Visibility", since any dynamic block parameter may be arbitrarily named.

Dynamic Block functions from here.

Ah yes .. silly me 

[rkmcswain]

Friday quick & dirty freebie ... not the most efficient but free ...

...and then 6 years later, stolen and presented without credit. 

https://lispbox.wordpress.com/2016/02/29/undinamic-all-blocks-in-one-click/

[MP]

Happens tons (here and out there), one of many reasons why I basically stopped posting code.

[rkmcswain]

Happens tons (here and out there), one of many reasons why I basically stopped posting code.

Some of the blog posts at that particular site refer to another URL**, but many are flat out stealing since they are posted under the guise of being original.

** Re-posting code can be excused in special cases, but most of the time a person should just link to the original source.
The owner of this particular "blog" is doing nothing more than copying and pasting work from others.

[MP]

The shameless repackaging that frequently goes on at the swamp is far more bothersome than the activities of those "out there". That said, the author of that site is a complete <pick derogatory word>.

[rkmcswain]

That said, the author of that site is a complete <pick derogatory word>.

I should state that we are both using the word "author" loosely.

Oh, and he is a member here at the Swamp too.

[mjfarrell]

Friday quick & dirty freebie ... not the most efficient but free ...

...and then 6 years later, stolen and presented without credit. 

https://lispbox.wordpress.com/2016/02/29/undinamic-all-blocks-in-one-click/

have dynamic blocks really been around 6 years?  (where does time go?)

[rkmcswain]

have dynamic blocks really been around 6 years?

Almost 11 years actually.

http://lynn.blogs.com/lynn_allens_blog/files/autocad_2006_tips_and_tricks_booklet.pdf

[AIberto]

Friday quick & dirty freebie ... not the most efficient but free ...

Code: [Select]

(defun c:UnDynamic

)

Dear MP

It will change all dynamic blocks to normal blocks. I only need change selected blocks(not all)  to normal blocks . Where need modify ?

Thanks a lot.

[MP]

Please see post #4.

[FrankenClyde]

ACK!

Dynamic Blocks are one of my favorite things, since I got a legitimate copy of v2006.
I use them extensively, but this morning I was told to cease, under threat of dismissal (out of the blue). Seems Production does not like them (Architectural Millwork, with CNC routers).
So, I found this site, via a web search, and direction from Cad-Notes
http://www.cad-notes.com/how-to-convert-dynamic-block-to-regular-block/

I copied the code in post #9, to great success, in a test drawing. I copied several (20+) visibility, rotation, flip, etc. versions of one block out to a blank drawing, and the code ran instantaneously, naming the new ones STATIC_01, STATIC_02, etc..
Then I copied 5-6 more into the new file, and tried it again. Not so good - the program hung for several minutes, until I hit esc. A few of the new ones had been converted, as STATIC_1, STATIC_2, etc. (without the "0#). I gather this is a once-and-only-once thing to do.

Then I signed up for The Swamp as a newb. That's when I saw there were a full three pages of posts, and several more versions of code for this converting DB's to regular blocks, including some renaming enhancements.

My main exposure to .lsp is using the defun:c in my extensive acaddoc.lsp file, with souped-up .pgp combined commands, like "n" for "move" "previous" ("mp" is for match properties). I know nothing of all the other functions of lisp or v-lisp.

My reason for posting is that I am confused with the subsequent posts, and which one to go with. I like the bit from post #17, then there's #25-27, with different code altogether.

Which should I use??

[iku]

Hello.

During my search on the web I found the nice script that was posted here (reply #9) and I gave it a shot. It works just fine for my needs except that my blocks have annotative scales and that information gets lost. I'm not very fluent with lisp but am I correct assuming that there aren't any parameters one can pass to ConvertToStaticBlock method except new block name? I couldn't find confirmation, but static blocks don't support anno scales? So I need a new approach altogether instead of ConvertToStaticBlock?

Could someone help me with this please?