Topic: Search for mleaderstyle

[psuchewinner]

I need some help in searching for a mleaderstyle to test if it exists.  I hafve not had luck with "tblsearch".

[ronjonp]

Try something like this:

Code: [Select]

(vla-item (vla-get-dictionaries
       (vla-get-activedocument (vlax-get-acad-object))
     )
     "ACAD_MLEADERSTYLE"
   )

[psuchewinner]

i need to test to see if it is in "ACAD_MLEADERSTYLE".  If I do a (VAL-GETOBJECT "MLDRDICT" "LEADERSTYLE"), i get an invalid key error.  Im looking for a T or F, arent I?

[ronjonp]

Perhaps something more like this:

Code: [Select]

(defun mleaderstyle-p (name / dic)
  (and (not (vl-catch-all-error-p
      (setq
dic (vl-catch-all-apply
      'vla-item
      (list
(vla-get-dictionaries (vla-get-activedocument (vlax-get-acad-object)))
"ACAD_MLEADERSTYLE"
      )
    )
      )
    )
       )
       (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-item (list dic name))))
  )
)

[Joe Burke]

Does this help?

Command: (dictsearch (namedobjdict) "acad_mleaderstyle")
((-1 . <Entity name: 7efdb648>) (0 . "DICTIONARY") (5 . "9DC9") (102 .
"{ACAD_REACTORS") (330 . <Entity name: 7efc6c40>) (102 . "}") (330 . <Entity
name: 7efc6c40>) (100 . "AcDbDictionary") (280 . 0) (281 . 1) (3 . "Copy of
Standard") (350 . <Entity name: 7eb97610>) (3 . "Standard") (350 . <Entity
name: 7efdb650>))

Check the DXF 3 codes

[ronjonp]

Good call Joe 

Code: [Select]

(defun mleaderstyle-p (name)
  (vl-position
    name
    (mapcar 'cdr
    (vl-remove-if-not
      '(lambda (x) (= (car x) 3))
      (dictsearch (namedobjdict) "acad_mleaderstyle")
    )
    )
  )
)

[psuchewinner]

perfect! Thanks!

[Joe Burke]

You're welcome and thanks to ronjonp for adding the final touches.