Topic: (Challange) Edit part of text string.

[JohnK]

This challenge will be broken down into two parts. One part being this part and the next part will be being the ...next part. (*blink*)

I want to be able to edit just part of a text string. (Okay, i can hear what your saying; -"Duh!? ...he be stupid!" but bear with me.)

If i have a text string like so: "Jack and Jill ran up the hill" And most of this text will NEVER change except for one part; "Jack" (I guess Jill gets arround *LoL*. ...*sigh* ok, I'm sorry for that. that was just bad!?) So wouldnt it be nice to lock up that text so when you go to edit that string only a little piece of text is editable?!

How about we do this: We have a set start point and a end point marker. Lets use brackets. '<' & '>' So our string would/should look like this: "<Jack> and Jill ran up the hill." And when we go to edit the string, all we give to the user is "Jack".

How about that. ...Okay that isnt very hard at all but the next part might be.

So your challenge is to build me a procedure that will prompt me only text between the brackets.  Here is your string: "<Jack> and Jill ran up the hill."

TIP: Those of you new to lisp, should get in on this one as well, this will not be a hard procedure at all.  In fact, I will help you out a bit. Look into the AutoLisp function: "subst" and see if you can think of a way to test the overall string for those brackets.  The main workhorse of this challange will be a procedure that will acccept as an argument a string, string position, and length. ...trust me. If you get stuck, just sit back and see if you were on the right track. but try to get something down on paper before looking at other peoples code.

[Mark]

so the it might look something like ........
(defun func (str-edit str)
  ( ........
   ......... )
  )

[Jeff_M]

Well, here's how I'd do it.....allowing only one  string to be selected at a time:

<snip> of partial code.....

next time I'll read the whole post before submitting.......

[JohnK]

Nope,

(defun procedure (string)
  (....)
)

>: "Jack"

I dont want to select anything, this challenge is a workhorse. Just a procedure to "parse a string" so to speak.

[JohnK]

No thats cool. Save that, cause we might need that later. This is actualy turning out to be a cool idea.  (I'm doing some brain storming now.)

[Jeff_M]

OK, better?

Code: [Select]


(defun ed_str (str / p1 p2)
  (if (and (setq p1 (vl-string-position (ascii "<") str))
  (setq p2 (vl-string-position (ascii ">") str))
  )
    (substr str (+ 2 p1) (1- p2))
    )
  )


[CAB]

Do it with lists

Code: [Select]

(defun ed_str (str / slst target)
  (and
    (setq slst (vl-string->list str))
    (setq target (cdr(member 60 slst)))
    (setq target (cdr(member 62 (reverse target))))
    (setq target (vl-list->string (reverse target)))
  )
  Target
)

[JohnK]

Cool.   ...remeber to comment your code for the newbies too.

(Challenge: II) Parse a given string.

Ok, this challenge is kinda turning out to be a good idea so, I'm gonna extend this into a few more parts.

Your challenge is to make a procedure that will return several things.
1.) The string parsed of brackets.
2.) The position where the first braket was. (zero bassed)
3.) The length of chars inside the brackets.

Given the string: "<Jack> and Jill went up the hill."

Your procedure should return: "Jack and Jill went up the hill." 0 4

[whdjr]

Can the string within the brackets contain more than one word:

"<Jack Brown> and Jill went up the hill."

"<Lumber Jack> and Jill went up the hill."

"<Statue of Liberty> and Jill went up the hill."

or should the string within the brackets be constrained to one word only:

Just a thought.

[JohnK]

Multiple words are A-ok.  (spaces are char's too!?)

[JohnK]

Oh, and "Jack and <Jill> went up the hill." is cool too.

[CAB]

Code: [Select]

;;  returns list (string  target [start pos] length)
(defun ed_str (str / slst pre tar suf)
  (setq slst (vl-string->list str)
        pre  '() ; empty list
        tar  '()
        suf  '()
  )
  (while (and (> (length slst) 0) ; get the prefix
              (/= (car slst) 60)
         )
    (setq pre  (cons (car slst) pre)
          slst (cdr slst)
    )
  )
  (setq slst (cdr slst)) ; remove <
  (while (and (> (length slst) 0) ; get the target
              (/= (car slst) 62)
         )
    (setq tar  (cons (car slst) tar)
          slst (cdr slst)
    )
  )
  (setq slst (cdr slst)) ; remove >
  (while (> (length slst) 0) ; get the suffix
    (setq suf  (cons (car slst) suf)
          slst (cdr slst)
    )
  )
  (setq start (length pre))
  (setq len (length tar))
  (setq str (vl-list->string (append (reverse pre) (reverse tar) (reverse suf))))
  (setq tar (vl-list->string (reverse tar)))
  (list str tar start len)
)

[daron]

Okay, I'm still on part one, but here's my take on it, minus the brackets thing. I'm not sure I understand the reason for them. Here:

Code: [Select]

(stringsearch
     "john"
     "john get's a dear john from jenny"
     "Se7en"
)
(defun stringsearch (lookup string sub)
     (while
 (vl-string-search lookup string)
     (setq string
(vl-string-subst
    sub
    lookup
    string
)
     )
     )
)

That little ditty will continue to look for the word john, replacing it with Se7en until it reaches the end of the string or whatever you supply as your arguments.

Am I close to what you're asking for Se7en?