Topic: Point Manager

[Lee Mac]

unfortunately not
http://www.keycivil.com/products/land.shtml
Its more of a ground modelling package.

I thought as much - it would take an extremely generous person to give that much away 

[Lee Mac]

Thanks to a bug report from one of the members over at CADTutor, I have updated the first post to Version 2.0

If anyone finds any other bugs - please let me know! 

[Lee Mac]

Updated to Version 2.2, includes an Object Options Dialog 

[XXL66]

Nice work so far Lee.

Try to add lines connected with codes like Pad says.
I have done a similar function (but this works besides coordinates also on raw field data).
After connecting lines, you can add construction codes, then there is no limit 

Attached you can see a sample. Every object is created using pointcodes. Construction codes include perpendicular lines on the buildings and their housenumbers f.e. Lengthen/shorten lines, create a perpendicular corner to the next point. Extend to sideshot line, define arcs, create parallel lines (distance but also measured true point), text remarks, point labels, blocks, you name it.

I use a DWT file where blocks, layers etc are used as reference. Every DWT has a codetable (same name difference extension), this is where fieldcodes are linked to objects like points, lines, blocks. Editing the codes is done in the DWT. It's possible to define default lengths for the perpedicular lines, distance aligned texts etc... and of course all entity properties. Even default excentric offset for each individual featurecode is possible (f.e. measuring a corner of a building with a robotic total station, the operator just has to enter code +x or -x for the default distance).

I'm currently porting everything to BricsCAD.

[Lee Mac]

Updated to Version 2.4 - bug fixes as reported from CADTutor 

[mdbdesign]

Lee, there is question form one user:
When output type is a block, is there possibilities to rotate it perpendicular to polyline?

[Lee Mac]

Lee, there is question form one user:
When output type is a block, is there possibilities to rotate it perpendicular to polyline?

I'm afraid this is not possible with the current program.

[alanjt]

Lee, there is question form one user:
When output type is a block, is there possibilities to rotate it perpendicular to polyline?

I wrote this a while back. It would have to be used after importing the blocks with Lee's code, but it'd be a solution to aligning the blocks to your polyline.

Code: [Select]

(defun c:RAC (/ ss ent)
  ;; Rotate blocks Along Curve
  ;; Required subroutines: AT:GetSel, AT:AngleAtPoint
  ;; Alan J. Thompson, 12.20.10

  (vl-load-com)

  (if (and (setq ss (ssget "_:L" '((0 . "INSERT"))))
           (setq ent
                  (car
                    (AT:GetSel
                      entsel
                      "\nSelect curve to rotate objects along: "
                      (lambda (x)
                        (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-curve-getEndParam (list (car x))))
                        )
                      )
                    )
                  )
           )
      )
    (progn
      (vlax-for x (setq ss (vla-get-activeselectionset
                             (cond (*AcadDoc*)
                                   ((setq *AcadDoc* (vla-get-activedocument
                                                      (vlax-get-acad-object)
                                                    )
                                    )
                                   )
                             )
                           )
                  )
        (vl-catch-all-apply
          (function
            (lambda (/)
              (vla-put-rotation
                x
                (AT:AngleAtPoint
                  ent
                  (vlax-curve-getClosestPointToProjection ent (vlax-get x 'InsertionPoint) '(0 0 1))
                )
              )
            )
          )
        )
      )
      (vla-delete ss)
    )
  )
  (princ)
)





(defun AT:GetSel (meth msg fnc / ent)
  ;; meth - selection method (entsel, nentsel, nentselp)
  ;; msg - message to display (nil for default)
  ;; fnc - optional function to apply to selected object
  ;; Ex: (AT:GetSel entsel "\nSelect arc: " (lambda (x) (eq (cdr (assoc 0 (entget (car x)))) "ARC")))
  ;; Alan J. Thompson, 05.25.10
  (setvar 'ERRNO 0)
  (while
    (progn (setq ent (meth (cond (msg)
                                 ("\nSelect object: ")
                           )
                     )
           )
           (cond ((eq (getvar 'ERRNO) 7) (princ "\nMissed, try again."))
                 ((eq (type (car ent)) 'ENAME)
                  (if (and fnc (not (fnc ent)))
                    (princ "\nInvalid object!")
                  )
                 )
           )
    )
  )
  ent
)





(defun AT:AngleAtPoint (e p)
  ;; Return angle along curve, at specified point (on curve)
  ;; e - valid curve (ENAME or VLA-OBJECT)
  ;; p - point on curve
  ;; Alan J. Thompson, 11.04.10
  (angle '(0. 0. 0.) (vlax-curve-getFirstDeriv e (vlax-curve-getParamAtPoint e p)))
)

[mdbdesign]

Will try it.
Thank you.