Topic: Middle Center justify text in rectangle?

[CAB]

Don't quite understand what you are asking.

[Lee Mac]

So that the MTEXT window is at each corner of the cell ... not easy 

[CAB]

What condition would this help?

Set width to zero.

[Dommy2Hotty]

What condition would this help?

Set width to zero.

I was thinking if the width was too narrow or too wide, text might pop out top and bottom or left and right of cell.  If it was 0 width, line breaks may not be present.

Might be overthinking...

[CAB]

With Plain Text you can adjust the with factor if there is over flow.

[CAB]

Updating my version to include Mtext.

Code: [Select]

;;  Example by CAB
;;  Moves Text or Mtext to center while justifying Middle Center
;;  Changes Mtest to Width Zero
(defun c:CenterText (/ ss i elast obj bent ipt prop)
  (defun getmid (ent)
    (setq lst (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= 10 (car x))) (entget ent))))
    (if (= (length lst) 4)
      (mapcar '(lambda (a b) (/ (+ a b) 2.)) (car lst) (caddr lst))
    )
  )

  (command "_undo" "begin")
  (prompt "\Select text within the table.")
  (if (setq ss (ssget "_:L" '((0 . "TEXT,MTEXT"))))
    (progn
      (setq i -1)
      (while (setq ename (ssname ss (setq i (1+ i))))
        (setq obj (vlax-ename->vla-object ename))
        (if (eq "AcDbText" (vla-get-ObjectName obj))
          (setq prop 'TextAlignmentPoint)
          (setq prop 'insertionpoint)
        )
        (setq elast (entlast))
        (setq ipt (vlax-get obj 'insertionpoint))
        (if (vl-catch-all-error-p
              (vl-catch-all-apply
                '(lambda ()
                   (vl-cmdf "_.-boundary" "_a" "_i" "_n" "" "" ipt "")
                   (while (> (getvar "CMDACTIVE") 0) (command ""))
                 )))
          (princ "\nText boundry not found.")
          (progn ;  got a boundry
            (if (and (not (eq elast (setq bent (entlast))))
                     (setq midpt (getmid bent))
                )
              (if (eq "AcDbText" (vla-get-ObjectName obj))
                (progn
                  (vla-put-Alignment obj acAlignmentMiddleCenter)
                  (vla-put-TextAlignmentPoint Obj (vlax-3D-point MidPT))
                )
                (progn
                  (vla-put-Width obj 0.0)
                  (vla-put-AttachmentPoint obj acAttachmentPointMiddleCenter)
                  (vla-put-insertionpoint Obj (vlax-3D-point MidPT))
                )
              )
            )
            (and (eq bent (entlast)) (entdel bent))
          )
        )
      )
    )
  )
  (command "_undo" "end")

  (princ)
)

[Dommy2Hotty]

Updating my version to include Mtext.

NICE CAB!