Topic: line with attribute tool

[dubb]

im looking for a tool that will draw a line on layer S-BEAM between two points and offset each end point -3". and then inserts a text attribute on layer S-TEXT  at the middle of the line. so in the end the attribute and the line are not related.

this will be used to draw a beam between two points and have attribute (text) in the middle top of the beam.  I dont know if there is something out there like this but if there is a similar post please link me.



the whole end product will look like this only the end points of this beam is offset by 3" from each end
|   ____BM-1______    |

[CADaver]

Go ahead and make the attempt tp write the pseudo-code for what you're trying to do.  I am sure one of the great-guru-code-gods here will help you flesh it out as you go.

[dubb]

ok. since im a totall NeWB to lisp....ill be referring to the afra lisp guide so ill be back in a while with my first crack at this routine...are there certain codes or variables to take into consideration?

[daron]

First thing to do is spell out how you would do this by hand. That's how we start pseudo-code.

[CAB]

dubb
Daron gives good advice.
You may think its too simple a problem to write the steps down but it's the best place to
start. I may not write the code down but I do it in my head for simple problems.

Here I'll get you started.

1 Change layer to S-BEAM, assume it exist for the time being
2 ask user to pick end point of line
3 as user to pick other end of line

You take it from here. How would you actually draw this?

[dubb]

How would you actually draw this?

its relatively simple. i draw a line from one end point to another end point then i stretch each end 3" less than. and then i insert and attributed that is centered on top of the line. thats it. i can write the code for picking the line points and inserting the attribute. but i dont think i can get the lines to stretch 3" less on each side.


so far i started writing this but i havent finished yet. i guess im stuck and im looking for more code content to use.

Code: [Select]


(defun c:beam ()


(setq pt1 (getpoint "\nPick First Beam Point:"))
;comment here

(setq pt2 (getpoint "\nPick Second Beam Point:"))
;comment here
(command "LINE" pt1 pt2 "")
;draw the line

(princ)
;clean running
) ;end defun

(princ)
;clean loading


[Jeff_M]

Try this in your code (remove the (command "line") part of yours first.

Code: [Select]


(setq newpt1 (polar pt1 (angle pt1 pt2) 3))
(setq newpt2 (polar pt2 (angle pt2 pt1) 3))
(entmake (list '(0 . "LINE")
      (cons 10 newpt1)
      (cons 11 newpt2)
      )
)


[CAB]

Here are some tools for you.
(setq ang  (angle pt1 pt2))
(setq newpt1 (polar pt1 ang 3))

[dubb]

thanks it now draws the line for me. how come i cant see the line as i use the routine. i see the line after the routine is done.

what does

ang

do?

what does

Code: [Select]

(setq ang (angle pt1 pt2)) do?

[CAB]

ang is the variable that holds the angle pt1 pt2 and (angle pt1 pt2) if the function
that returns that angle. So to take it a step further you can use:
(setq ang1 (angle pt1 pt2)) ; angle of line FROM pt1 to pt2
(setq ang2 (angle pt2 pt1)) ; angle of line FROM pt2 to pt1

Now you know the angle from the picked points toward the new points you want to draw the
line from. You can use the POLAR function to get the new points. In your case 3 units
distance from the picked points. Polar works like this:
(setq newpt1 (polar pt1 ang1 3)) ; newpt1 is 3 units from pt1 toward pt2
you don't need pt1 any more so you could reuse the variable like this:
(setq pt1 (polar pt1 ang1 3)) ; pt1 assigned a new location

By doing the same thing with pt2 you can draw your line.
(setq pt2 (polar pt1 ang1 3)) ; pt2 assigned a new location
(command ".line" pt1 pt2 "")

Or you can use the results of (polar pt1 ang1 3) directly without
reassigning pt1. Like this:
(command ".line" (polar pt1 ang1 3) (polar pt1 ang1 3) "")

As Jeff pointed out you can use ENTMAKE to create the line as well as the command I used.

[daron]

thanks it now draws the line for me. how come i cant see the line as i use the routine. i see the line after the routine is done.

(defun c:beam ()

Code: [Select]


(setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint "\nPick Second Beam Point:"))


^your code cleaned up a bit^^^
vYour code with one additionvvv

Code: [Select]


(setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint pt1 "\nPick Second Beam Point:"))


Note the placement of pt1 just after getpoint in the second variable.
This will draw a rubberbanding line. Also, look into initget for error control and grdraw for line drawing.

[dubb]

ang is the variable that holds the angle pt1 pt2 and (angle pt1 pt2) if the function
that returns that angle. So to take it a step further you can use:
(setq ang1 (angle pt1 pt2)) ; angle of line FROM pt1 to pt2
(setq ang2 (angle pt2 pt1)) ; angle of line FROM pt2 to pt1

Now you know the angle from the picked points toward the new points you want to draw the
line from. You can use the POLAR function to get the new points. In your case 3 units
distance from the picked points. Polar works like this:
(setq newpt1 (polar pt1 ang1 3)) ; newpt1 is 3 units from pt1 toward pt2
you don't need pt1 any more so you could reuse the variable like this:
(setq pt1 (polar pt1 ang1 3)) ; pt1 assigned a new location

By doing the same thing with pt2 you can draw your line.
(setq pt2 (polar pt1 ang1 3)) ; pt2 assigned a new location
(command ".line" pt1 pt2 "")

thanks, it now seems clear for me. i have to go back and rework the routine.

Code:

(setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint pt1 "\nPick Second Beam Point:"))
 


Note the placement of pt1 just after getpoint in the second variable.
This will draw a rubberbanding line. Also, look into initget for error control and grdraw for line drawing.

wow that simple change makes a difference

ok...if there are any more advice, keep them coming if you liked to post. ill be working on this routine ill be back on this topic after ive developed the routine. thanks guys

[dubb]

OK, im back on this thread again. sorry it took so long. ive made a few changes to the code i previously had.

Code: [Select]


(defun c:bm ()
(setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint pt1 "\nPick Second Beam Point:"))
;comment here
(command "clayer" "s-beam")
(setq newpt1 (polar pt1 (angle pt1 pt2) 3))
(setq newpt2 (polar pt2 (angle pt2 pt1) 3))
(setq pt3 (polar pt1 (angle pt1 pt2) 5))
(entmake (list '(0 . "LINE")
          (cons 10 newpt1)
          (cons 11 newpt2)
 
          )
    )
(command "clayer" "s-bm-text")
(COMMAND "-insert" "BM-TEXT" pt3 "" "" "")

(princ)
) ;end defun



the problem with this one is i cant specify "PT3" to be the midpoint of pt1 and pt2 at the angle of pt1 and pt2. and i cant get  s-bm-text layer in the drawing without having it created first.

[whdjr]

dubb,

First things first.  All the variables you have established (ie. pt1, pt2, ang, etc.) need to be localized so as not to interfere with other programs.  Here is some info to get you started on figuring out how to localize them.

The following example shows the use of local variables in a user-defined function (be certain there is at least one space between the slash and the local variables).

_$  (defun LOCAL ( / aaa bbb)
(_> (setq aaa "A" bbb "B")
(_> (princ (strcat "\naaa has the value " aaa ))
(_> (princ (strcat "\nbbb has the value " bbb))
(_> (princ) )

LOCAL

Before you test the new function, assign variables aaa and bbb to values other than those used in the LOCAL function.

_$  (setq aaa 1 bbb 2)

2

You can verify that the variables aaa and bbb are actually set to those values.  

_$  aaa
1
_$  bbb

2

Now test the LOCAL function.

_$  (local)
aaa has the value A

bbb has the value B

You will notice the function used the values for aaa and bbb that are local to the function. You can verify that the current values for aaa and bbb are still set to their nonlocal values.

_$  aaa
1
_$  bbb

2

In addition to ensuring that variables are local to a particular function, this technique also ensures the memory used for those variables is available for other functions.

Please ask more questions if this doesn't make sense.

[dubb]

huh?....it kinda blew right past me. you mean to say that the way i arranged my code is improper? pt1 and pt2 dont interfere with other routines that i have loaded is there a way to determine it absolutely will interfere?

[Keith™]

dubb, it is good coding practice to localize vars that don't need to be global in context.

[dubb]

so my defun should look like this right?

Code: [Select]


(defun c:bm (/ pt1 pt2 pt3 newpt1 newpt2)


[Keith™]

yeppers

[dubb]

yayy!!

so what about setting pt3 as the midpoint of pt1 and pt2?

[Keith™]

Do you not have PT# already set, or is set incorrectly

[dubb]

i beleive its set incorrectly

Code: [Select]


(setq pt3 (polar pt1 (angle pt1 pt2) 5))


i know this is not the way, theres gotta be some other function

[Keith™]

Ok, to get the midpoint of PT1 and PT2, you can use the polar command and the distance command to get the value such as:

Code: [Select]


(setq pt3 (polar pt1 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))


Or you can use the algebraic formula

Code: [Select]


(setq pt3 (list (/(+ (car pt1)(car pt2))2)(/(+(cadr pt1)(cadr pt2))2)))


[CAB]

dubb
So this line (setq pt3 (polar pt1 (angle pt1 pt2) 5))
Becomes this (setq pt3 (polar pt1 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))
And reads like this: pt3 equals a point starting from pt1 at an angle of (angle pt1 pt2)
for a distance of half the distance of pt1 lt2  (/ (distance pt1 pt2) 2)))

Clayer is also a system variable and can be set with the setvar function like this
(setvar "clayer" "s-beam")

I noticed you did not set the angle in the insert command. To make it the same angle
as the line use (angle pt1 pt2)

So the changes look like this, so far

Code: [Select]

(defun c:bm (/ pt1 pt2 pt3 newpt1 newpt2)
(setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint pt1 "\nPick Second Beam Point:"))
   ;comment here
(setvar "clayer" "s-beam")
(setq newpt1 (polar pt1 (angle pt1 pt2) 3))
(setq newpt2 (polar pt2 (angle pt2 pt1) 3))
(setq pt3 (polar pt1 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))
(entmake (list '(0 . "LINE")
          (cons 10 newpt1)
          (cons 11 newpt2)
 
          )
    )
(setvar "clayer" "s-bm-text")
(COMMAND "-insert" "BM-TEXT" pt3 "" "" (angle pt1 pt2))
(princ)
)   ;end defun

Now using -layer with the M option how would you deal with the layers you have chosen?

[CADaver]

nevermind, my bad.

[whdjr]

Here's a little thought:

Instead of using

Code: [Select]

(setvar "clayer" "s-beam")
why not just add this

Code: [Select]

'(2 . "s-beam") to the entmake command.

However; regardless of which way you choose you should definitely check to see if the layer is already there.  I'm sure this process will get to error checking eventually.

Good Luck and Happy Coding.

[Fuccaro]

However; regardless of which way you choose you should definitely check to see if the layer is already there.

ENTMAKE will create a new layer if it doesn't exists. So if you use the '(8 . "s-beam") expression as Whdjr suggested the line will be placed on the layer s-beam. If that layer doesn't exists, it will be firstly created.

[dubb]

thank you very much for the code suggestions.

i have tried to use

Code: [Select]


(command "layer" "make" "S-BEAM" "color" 5 "" "")^c
(command "clayer" "s-beam")


to add my layer if it wasnt there but

Code: [Select]


'(8 . "s-beam")

 is wayt much simpler. what does the

8

represent?

[whdjr]

It is the DXF reference tag for Layer Name.

Look up DXF Reference in the autolisp help file.

[Mark]

The '8' represents the DXF code for the layer of all entites. Take a look around here for one of the layer app's, you'll see how it was used.

[Mark]

dang!! beat by one minute.

[CAB]

Do the procedure at command line then repeat each entry.

Code: [Select]

Command: -layer

Current layer:  "S4"
Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/PStyle/Freeze/Thaw/LOck/Unlock]:
 m

Enter name for new layer (becomes the current layer) <S4>: S-BEAM
Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/PStyle/Freeze/Thaw/LOck/Unlock]:
 c

Enter color name or number (1-255): 5

Enter name list of layer(s) for color 5 (blue) <S-BEAM>:
Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/PStyle/Freeze/Thaw/LOck/Unlock]:

Code: [Select]

(command "-layer" "m" "S-BEAM" "c" "5" "" "")
Where did the ^c come from? Don't use it.
When you use the MAKE option it sets that layer current so you don't need clayer.

To make a layer if it doesn't exist or set current use this code

Code: [Select]

(setq lyr "S-BEAM")
(if (not (tblsearch "layer" lyr))
 (command "._layer" "m" lyr "c" "5" "" "")
 (command "._Layer" "_Thaw" lyr "_On" lyr "_UnLock" lyr "_Set" lyr "")
)

[whdjr]

dang!! beat by one minute.

     

[dubb]

cab, that is a gr8 way to learn. my other question is

Code: [Select]

(command "-layer" "m" "S-BEAM" "c" "5" "" "")

what are the following quotes used for? is there a rule for using the quotes?
what im talking about is the

(.....""  "")

after the

"5"

[/quote]

[CADaver]

cab, that is a gr8 way to learn. my other question is

Code: [Select]

(command "-layer" "m" "S-BEAM" "c" "5" "" "")

what are the following quotes used for? is there a rule for using the quotes?
what im talking about is the

(.....""  "")

after the

"5"

They execute "ENTER" after the layer color command to accept the default layer name for color 5, then exit the layer loop.

[dubb]

im back again....here is another version of my beam command. except i stilll cant get that block on the midpoint (pt3) and also when i insert the block it doesnt align with the direction i place "pt1 and pt2" unless it wasnt at an angle, any suggestions?

Code: [Select]


(defun c:bm (/ pt1 pt2 pt3 newpt1 newpt2)
(setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint pt1 "\nPick Second Beam Point:"))
   ;comment here
(command "layer" "make" "S-BEAM" "color" 5 "" "")
(command "clayer" "s-beam")
(setq newpt1 (polar pt1 (angle pt1 pt2) 3))
(setq newpt2 (polar pt2 (angle pt2 pt1) 3))
(setq pt3 (polar pt2 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))
(entmake (list '(0 . "LINE")
          (cons 10 newpt1)
          (cons 11 newpt2)
 
          )
    )
(command "layer" "make" "S-BM-TEXT" "color" 1 "" "")
(command "clayer" "S-BM-TEXT")
(COMMAND "-insert" "BM-TEXT" pt3 "" "" (angle pt1 pt2))

(princ)
)   ;end defun


[CADaver]

If you're puling the angle between PT1 and PT2 start your (POLAR from PT1.  YOu could also use:

Code: [Select]

(cal "(pt1+pt2) /2")
The angle requested after the insert command is in degrees (angle PT1 PT2) returns radians, you need to convert.

[CAB]

Read each line of code....

Code: [Select]

(defun c:bm (/ pt1 pt2 pt3)
  (setq pt1 (getpoint "\nPick First Beam Point:")
        pt2 (getpoint pt1 "\nPick Second Beam Point:")
  )
  (command "layer" "make" "S-BEAM" "color" 5 "" "")
  ;;(command "clayer" "s-beam") NOT needed because the 'layer' 'make'
  ;;  sets the layer current
  (entmake (list '(0 . "LINE")
                 (cons 10 (polar pt1 (angle pt1 pt2) 3))
                 (cons 11 (polar pt2 (angle pt2 pt1) 3))

           )
  )
  (command "layer" "make" "S-BM-TEXT" "color" 1 "" "")
  ;;(command "clayer" "S-BM-TEXT") NOT needed because the 'layer' 'make'
  ;;  sets the layer current
  ;; correction of error in next line, thanks CADaver!!
  ;;(setq pt3 (polar pt2 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))
  (setq pt3 (polar pt1 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))
  (setq useros (getvar "osmode"))
  (setvar "osmode" 0)
  (command "-insert" "BM-TEXT" pt3 "" ""(* 180.0 (/ (angle pt1 pt2) pi)))
  (setvar "osmode" useros)
  (princ)
) ;end defun  

[CADaver]

Code: [Select]

(setq pt3 (polar pt2 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))

Correct me if I'm wrong here, but if you start the polar function from PT2 and pull the angle between PT1 and PT2, you're not going to be at the midpt between PT1 and PT2, but rather that far OFF the end pf PT2.  Right???

Shouldn't it be:

Code: [Select]

(setq pt3 (polar pt1 (angle pt1 pt2) (/ (distance pt1 pt2) 2)))

or:

Code: [Select]

(setq pt3 (polar pt2 (angle pt2 pt1) (/ (distance pt1 pt2) 2)))

Be nice, remember I'm a lisp hack.

[CAB]

You are absolutely right.
Typo on my part & I never ran the code.
See those old eyes are still sharp.

[CADaver]

Well you told me read each line...

whew, I was scared there for a minute, I'm at that age where "old-timer's" disease is a real worry.    :horror:  

[CAB]

If you try to keep up with ACAD you won't have to worry about exercising those
brain cells. Seems like just that is a full time job. I always feel that way
when I get overrun with work. Oh well working through the weekend again. At least
I'm not alone, right t-bear.

Have a good weekend.

[CADaver]

If you try to keep up with ACAD you won't have to worry about exercising those brain cells.

had I known I was gonna need 'em this long, I'd have been kinder to 'em in my youth.

Oh well working through the weekend again. At least I'm not alone, right t-bear.

I'll be here, too.

[dubb]

finally i got it works perfect. thank you fellaz for all your help. thank you thank you.