Topic: Stringless Rounds?

[David Bethel]

Taking Michael's approach and appling to my code, you get:

Code: [Select]

;;;ROUND BY
;;;ARG -> REAL to round, REAL to round by
;;;RET -> REAL
(defun rndby (r b / tmp)
  (setq tmp (rem r b))
  (cond ((>= tmp (* 0.5 b))  (+ r (- b tmp)))
        (T                   (- r tmp))))


A fairly clean piece of code.  -David

[CAB]

Got my last routine to work with neg number as well as positive ones.

Code: [Select]

; positive or negative numbers with variable break point
(defun rndup (num Brk)
  (float (fix (+ num (* (/ num (abs num))(- 1 brk))))))


(defun c:test()
  (print (rndup 2.2 0.2))
  (print (rndup 2.3 0.3))
  (print (rndup -2.5 0.3))
  (print (rndup -2.2 0.3))
  (princ)
)

[daron]

David, that's exactly what I tried. Maybe I need to exactly try it again. I'm sure I didn't do it right.

[David Bethel]

Daron, Mark

You could also make it an (if) statement in lieu of (cond)

Code: [Select]

(defun rndby (r b / tmp)
  (setq tmp (rem r b))
  (if (>= tmp (* 0.5 b))
      (+ r (- b tmp))
      (- r tmp)))


-David

[ImaJayhawk]

Can you use vla-eval to call the VBA Round function?



--ImaJayhawk

[daron]

Wouldn't know, but I believe there have been a number of ways to skin this cat as I've asked.

[Kerry]

Speaking of skinning cats ;

Code: [Select]


(defun our:RoundTo (value to-prec)
  (setq to-prec (abs to-prec))
  (* to-prec
     (fix (/ ((if (minusp value) - + )
               value
               (* to-prec 0.5)
             )
             to-prec
          )
     )
  )
)

It makes me a little self-conscious to admit how old this is.