Topic: Subst in an only element.

[velasquez]

I have a list in the format -> (0 (B " C ") 0 123 0) 
I need to substitute (nth 2) of this list for 5. 
The new list should be -> (0 ("A" "B " C ") 5 123 0) 
How can I make this work?

[Andrea]

try this..

Code: [Select]

(defun listsubst (xlist xitem xsubst / val xlist2)
  (setq val 0)
  (setq xlist2 (mapcar '(lambda (x) (cons (setq val (1+ val)) x)) xlist))
  (setq xlist2 (subst (cons xitem xsubst) (assoc xitem xlist2) xlist2))
  (setq xlist2 (mapcar '(lambda (x) (cdr x))
                       (subst (cons xitem xsubst) (assoc xitem xlist2) xlist2)
               )
  )
)


;;test
(listsubst '(0 (B " C ") 0 123 0) 3 5)


[VovKa]

Code: [Select]

(defun SubstNth
   (NewItem Position InList /)
  (if InList
    (if (zerop Position)
      (cons NewItem (cdr InList))
      (cons (car InList) (SubstNth NewItem (1- Position) (cdr InList)))
    )
  )
)


[velasquez]

Thank you very much the functions work perfectly.

[CAB]

More offerings:

http://www.theswamp.org/index.php?topic=14170.0