Topic: Do I really need error checking

[jlogan02]

This routine doesn't have any user actions to it except selecting a button that launches the routine. Is there really any reason for error checking for routines that don't have user action required within the code?

Code - Auto/Visual Lisp: [Select]

1. (defun c:ST01ToBy (/ *error* msg col )
2.  
3.   (defun *error* (msg)
4.    
5.     (if (not (member msg '("Function cancelled" "quit / exit abort")))
6.       (princ (strcat "\nError: " msg))
7.     )
8.     (princ)
9.   )
10.  
11.   (setvar 'cmdecho 0)
12.      
13.   (if
14.     (setq col (ssget "X" '((0 . "*Dimension,MultiLeader,Hatch,*Line,*Text,Arc,Circle") (62 . 1))))
15.     (foreach x (mapcar 'cadr (ssnamex col))
16.         (entmod (append (entget x) '((62 . 256)))))
17.   )
18.  
19.    (command "_layer" "Make" "LINE1" "color" "yellow" "LINE1" "")
20.  
21.   (setvar 'cmdecho 1)
22.  
23.  (princ)
24. )

[mhupp]

Always a potential for an error. you can set variables back to what they were before the lisp was called, or undo changes. the code isn't run unless their is an error so whats the harm?

Code - Auto/Visual Lisp: [Select]

1. (defun c:ST01ToBy (/ *error* msg col)
2.   (defun *error* (msg)
3.     (if (not (member msg '( "Function cancelled" "quit / exit abort")))
4.       (princ (strcat "\nError: " msg))
5.     )
6.     (vla-endundomark Drawing)
7.     (command "_U") ;undo if error    
8.     (setvar 'cmdecho 1) ;set cmdecho back to one if their is an ERROR
9.     (princ)
10.   )
11.   (setq Drawing (vla-get-activedocument (vlax-get-acad-object)))
12.   (vla-startundomark Drawing)
13.   (setvar 'cmdecho 0)
14.   (if (setq col (ssget "X" '((0 . "*Dimension,MultiLeader,Hatch,*Line,*Text,Arc,Circle") (62 . 1))))
15.     (foreach x (mapcar 'cadr (ssnamex col))
16.       (entmod (append (entget x) '((62 . 256))))
17.     )
18.   )
19.   ;(command "_layer" "Make" "LINE1" "color" "yellow" "LINE1" "")
20.   (entmake '((0 . "LAYER") (100 . "AcDbSymbolTableRecord") (100 . "AcDbLayerTableRecord") (2 . "LINE1") (70 . 0) (62 . 2)))  
21.   (setvar 'cmdecho 1)
22.   (vla-endundomark Drawing)
23.   (princ)
24. )

[jlogan02]

Good point. It can' t hurt.

[kdub_nz]

Just be careful where you place the 'undo'.

Haven't tested, but I think the 'undo' in your handler will override the setvar ( a couple lines earlier )

[jlogan02]

Thanks. I'll double check.

[mhupp]

Thanks kdub code updated.

--Edit

Also ran into this the other day. In BricsCAD you can just run the ssget with out an if statement and it wouldn't error if nil. sent a lisp to someone running AutoCAD and it does error if nil.  It also had an error trap so nothing was coming up.
They kept typing the command a couple more times. until they asked me why it wasn't working.

so while not displaying the default error maybe display a coustom one like.

Code - Auto/Visual Lisp: [Select]

1. (defun *error* (msg)
2.   (if (not (member msg '( "Function cancelled" "quit / exit abort")))
3.     (princ (strcat "\nError: " msg))
4.     (princ "\nSomething Went Wrong Contact: Name Here")
5.   )
6.   (vla-endundomark Drawing)
7.   (command "_U")       ;undo if error
8.   (setvar 'cmdecho 1)  ;set cmdecho back to one if their is an ERROR
9.   (princ)
10. )