Topic: pagesetup lisp

[dubb]

i have copied somebody elses's stuff but i modified it. tell me what you think. im a total noOb, please bear with me. this a lisp routine that will import pagesetups from a file. if i new more i would make it so that it doesnt have to reference files and rather make pagesetups through variables. it works for me but is this common practice in lisp?

;loads pagesetups for 1"=1'-0"
(defun C:123624(/ Save_Expert)
  (setq Save_Expert (getvar "EXPERT"))
  (setvar "EXPERT" 2)
  (command "_.-PSETUPIN" "S:/WYNN-CAD/pagesetups/12_36x24.dwg" "*")
  (setvar "EXPERT" Save_Expert)
  (princ)
)

;loads pagesetups for 3/4"=1'-0"
(defun C:163624(/ Save_Expert)
  (setq Save_Expert (getvar "EXPERT"))
  (setvar "EXPERT" 2)
  (command "_.-PSETUPIN" "S:/WYNN-CAD/pagesetups/16_36x24.dwg" "*")
  (setvar "EXPERT" Save_Expert)
  (princ)
)

;loads pagesetups for 1/4"=1'-0"
(defun C:483624(/ Save_Expert)
  (setq Save_Expert (getvar "EXPERT"))
  (setvar "EXPERT" 2)
  (command "_.-PSETUPIN" "S:/WYNN-CAD/pagesetups/48_36x24.dwg" "*")
  (setvar "EXPERT" Save_Expert)
  (princ)
)

;loads pagesetups for 1/4"=1'-0"
(defun C:483624(/ Save_Expert)
  (setq Save_Expert (getvar "EXPERT"))
  (setvar "EXPERT" 2)
  (command "_.-PSETUPIN" "S:/WYNN-CAD/pagesetups/48_36x24.dwg" "*")
  (setvar "EXPERT" Save_Expert)
  (princ)
)

;loads pagesetups for paperspace 36x24
(defun C:ps3624(/ Save_Expert)
  (setq Save_Expert (getvar "EXPERT"))
  (setvar "EXPERT" 2)
  (command "_.-PSETUPIN" "S:/WYNN-CAD/pagesetups/PS_36x24.dwg" "*")
  (setvar "EXPERT" Save_Expert)
  (princ)
)

[ronjonp]

Why don't you save all pagesetups in one file so you don't have to have a lisp for each one? They are easily accessible in the pulldown.

Ron

[M-dub]

Why don't you save all pagesetups in one file so you don't have to have a lisp for each one? They are easily accessible in the pulldown.

Ron

I'll second that notion....That's what I use and it is SuWEEEET!

[CAB]

Then load them with the click of a button
^C^CDel_Pagesetups;^C^C.-PSETUPIN "PageSetups.dwg" "*"

[M-dub]

http://theswamp.org/phpBB2/viewtopic.php?t=1771&highlight=delpagesetups

[CAB]

This subject goes way back.
PageSetup

[M-dub]

...and still growing!  

[dubb]

THANK YOU GUYS....a menu bar would be nicer. the reason why i have it this because i want just the setups that i need for each drawing.

when i use

Code: [Select]


^C^CDel_Pagesetups;^C^C.-PSETUPIN "PageSetups.dwg" "*"


i get

Command: .-PSETUPIN Enter file name: "S:/WYNN-CAD/pagesetups/12_36x24.dwg"
Enter user defined page setup(s) to import or [?]: "*"
Page setup "11x17" already exists. Redefine it? [Yes/No] <N>: *Cancel*

Page setup "12_36x24" already exists. Redefine it? [Yes/No] <N>: *Cancel*

so i use hotkeys. and later i will make a pull down menu and a toolbar

[M-dub]

Did you load Del_Pagesetups first?

[M-dub]

Here's what I use in my button macro:

Code: [Select]

^C^C(load"O:/Drawings/Menus-Blocks/LISP/Del_Pagesetups.lsp") Del_Pagesetups;^C^C.-PSETUPIN "O:/Drawings/SupportforCAD/AutoCAD-2004-Support/PageSetups.dwg" "*" PLOT;

[CAB]

In cas you did not get the link by m-dub

Code: [Select]

;;  Function to delete all user plot set ups
(defun c:Del_Pagesetups (/ curdwg pslayout x)
  (vl-load-com)
  (setq
    curdwg   (vla-get-ActiveDocument (vlax-get-Acad-Object))
    pslayout (vla-get-Layout (vla-get-PaperSpace curdwg))
  ) ;_ end of setq
  ;; Call RefreshPlotDeviceInfo before GetPlotDeviceNames
  (vla-RefreshPlotDeviceInfo pslayout)
  (vlax-for x (vla-get-Plotconfigurations curdwg)
    (vla-delete x)
  ) ;_ end of vlax-for
)               ; End Plot_config_list



PS this thread doesn't belong in this forum.

[M-dub]

>PS this thread doesn't belong in this forum.
*Oh yeah, forgot to mention that...*

I should also stop being lazy and paste the code in here instead of posting the link instead.  
Thanks CAB

[hyposmurf]

Im trying to sort my page setups out.I have the following macro asociated with a menu button.

^C^CDel_Pagesetups;^C^C.-PSETUPIN "A0PSETUP.dwg" "A0"

This imports the A0 page setup but it wont set it as current.Is there a way to do this?

[CAB]

Code: [Select]

; Jason Piercey . May 16th, 2003
; assign a pagesetup to a layout
; [layout] - string, layout name
; [setup] - string, pagesetup to assign
; return: T or nil
(defun putPagesetup (layout setup / layouts plots)
 (defun item-p (collection item)
  (if
   (not
    (vl-catch-all-error-p
     (vl-catch-all-apply
      '(lambda () (setq item (vla-item collection item))))))
   item
   )
  )
 (and
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (or *doc* (setq *doc* (vla-get-activedocument *acad*)))
  (setq layouts (vla-get-layouts *doc*))
  (setq plots (vla-get-plotconfigurations *doc*))
  (setq layout (item-p layouts layout))
  (setq setup (item-p plots setup))
  (not (vla-copyfrom layout setup))
  )
 )

[daron]

...
PS this thread doesn't belong in this forum.

I was thinking the same thing.

[daron]

I moved it to the lisp forum, away from the show your stuff forum.

[hyposmurf]

Code: [Select]

; Jason Piercey . May 16th, 2003
; assign a pagesetup to a layout
; [layout] - string, layout name
; [setup] - string, pagesetup to assign
; return: T or nil
(defun putPagesetup (layout setup / layouts plots)
 (defun item-p (collection item)
  (if
   (not
    (vl-catch-all-error-p
     (vl-catch-all-apply
      '(lambda () (setq item (vla-item collection item))))))
   item
   )
  )
 (and
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (or *doc* (setq *doc* (vla-get-activedocument *acad*)))
  (setq layouts (vla-get-layouts *doc*))
  (setq plots (vla-get-plotconfigurations *doc*))
  (setq layout (item-p layouts layout))
  (setq setup (item-p plots setup))
  (not (vla-copyfrom layout setup))
  )
 )

Thanks for that CAB Ive got the lisp apploaded and cant seem to get it to run.What do I need to initiate it?
psetup
putPagesetup
item-p
Probably none of these and I need to assign the name of my page setup in there somewhere.

[daron]

putPagesetup requires two arguments: layout & setup. I would assume those to be your layout to set to and the setup name.

[hyposmurf]

Im still scratching my head over where to put in my Layout 1 & A0 (which is my pagesetup name).

This next bit your going to find a bit of a mess but it works!

^C^CDel_Pagesetups;^C^C.-PSETUPIN "A0PSETUP.dwg" "A0" ^C^C.-INSERT "A0SML.dwg" 0,0 1 1 0 ;;;;;;;;;;;;;;;;;;

Thats the macro to insert a A0 pagesetup and my A0 titleblock.Im hoping to have this set for each titleblock and accompanying page setup.Everything is fine(well not the cleanest macro),but Im still miffed over that lisp for setting the current page setup.

[daron]

(putPagesetup "Layout 1" "A0")

Try that.

[CAB]

To take it one step farther.

Code: [Select]

(defun c:DansHelper(/ lay)
  (foreach lay (layoutlist)
    (putPagesetup lay "A0")
  )
  (princ)
)

Dan,
Are you taking Stig's Lisp Course?
If so you will understand the 'foreach' function.
Look up the 'layoutlist' function.
I haven't been following the course but you probably have covered
passing variables between lisp routines. I am talking about
'lay' and '"A0"' here. Can you figure out what each of the four lines of
code is doing?

[hyposmurf]

Nice defun! As far as Stig,s lisp course has gone ...... .My workload has almost doubled at work now another employee has left and Im also trying to get myself prepared for a departure to, which leaves me hardly any spare time.I even stayed in the whole easter weekend .Sad git that I am  it will pay off eventually.Thanks for the lisp I'll go and have a go and come back with some feedback.The need for me to learn how to lisp is becoming more apparent everyday!

[hyposmurf]

To take it one step farther.

Code: [Select]

(defun c:DansHelper(/ lay)
  (foreach lay (layoutlist)
    (putPagesetup lay "A0")
  )
  (princ)
)

Dan,
Are you taking Stig's Lisp Course?

Just got back on this one and hoping to sort it before I start work tomorrow .I havent seen Stigs course since cant even find it on the swamp any more. Im going to take a guess at what each layer means.
(defun c:DansHelper(/ lay) Defines the function
  (foreach lay (layoutlist) Attains a list of layouts
    (putPagesetup lay "A0") Sets the current layout to A0
  )
  (princ)
)        Exits the lisp quietly


When I run the lisp I get:
Command: DansHelper
; error: no function definition: PUTPAGESETUP

So the last line of code needs to finished,a functioned defined?Is it not possible to add to the macro I already have to set it current that way the whole sequence of events can be set from one button?

[CAB]

Look here: http://www.theswamp.org/phpBB2/viewtopic.php?p=55224#55224

Load it with the other lisp or add it to it like

Code: [Select]

(defun c:DansHelper(/ lay)

<put it here>

  (foreach lay (layoutlist)
    (putPagesetup lay "A0")
  )
  (princ)
)

[hyposmurf]

Thanks.That is almost there it sets the pagesetup I want to be current,but I still have to reopen the page setup dialogue and hit enter before any changes to the setup in the drawing are set.