Topic: File on desktop

[rude dog]

How do you create a textfile on the desktop via autolisp

[Keith™]

try this ....

Code: [Select]


(if (setq FN (open "full_path_to_text_file_on_desktop" "w"))
(close FN)
(alert "File not created")
)


[rude dog]

Code: [Select]

Command: (setq FN (open "C:\Documents and Setttings\All Users\Desktop\Tnew.txt" "w"))

#<file "C:Documents and SetttingsAll UsersDesktopTnew.txt">

Command: (WRITE-LINE "HERE IT IS" FN)

"HERE IT IS"

Command: (CLOSE FN)
nil
hmm.. still not creating a new text file to the desktop..what am I doing wrong

[Mark]

Try this:

Code: [Select]


(setq FN (open "C:\\Documents and Setttings\\All Users\\Desktop\\Tnew.txt" "w"))


[Keith™]

Your path is invalid. You need to correct the spelling of "Settings" and you need to either change your slashes to doubles "\\" or make them forward slashes "/"

As such:

Code: [Select]

(setq FN (open "C:\\Documents and Settings\\All Users\\Desktop\\Tnew.txt" "w"))
(WRITE-LINE "HERE IT IS" FN)
(CLOSE FN)


[Keith™]

Dangit Mark, you beat me to it ...

[Mark]

Dangit Mark, you beat me to it ...

Yea but I missed the spellling error.  

[Keith™]

Oh well we can't catch everything everytime....

[rude dog]

Thank you  &  Thank you...Oh and Thank you

[Keith™]

Uh ... you are welcome .... I think ... glad I could help

[SMadsen]

How do you create a textfile on the desktop via autolisp

Alternatively .. or additionally:

Code: [Select]

(defun getDesktop (/ script spFolders desktop)
  (cond ((setq script (vlax-create-object "WScript.Shell"))
         (setq spFolders (vlax-get-property script "SpecialFolders")
               desktop   (vlax-invoke-method spFolders 'Item "Desktop")
         )
         (vlax-release-object spFolders)
         (vlax-release-object script)
        )
  )
  desktop
)

(defun makeDesktopFile (/ dsktopPath fn fName)
  (cond
    ((and (setq dsktopPath (getDesktop))
          (/= (setq fName (getstring "\nFilename: ")) "")
     )
     ;; assume a default of ".txt" if no extension was given
     (if (/= (substr fName (- (strlen fName) 3) 1) ".")
          (setq fName (strcat fName ".txt")))
     ;; go create file
     (cond ((setq fn
                   (open (setq fName (strcat dsktopPath "\\" fName)) "w"))
            (close fn)
            ;; and, if succesfull, open it in notepad
            (startapp "notepad.exe" fName)
           )
     )
    )
  )
  (princ)
)

[Mark]

Not as elegant as yours Stig but none the less.......

Code: [Select]


(defun make-file (/ getdesktop fn fp fo)

  ;; create a .txt file in 'C:\Documents and Settings\All Users\Desktop'
  ;; named by user, default extension is .txt

  (defun get-desktop (/ dir)
    (cond
      ((and
         (setq dir (strcat (getenv "ALLUSERSPROFILE") "\\Desktop\\"))
         (vl-file-directory-p dir))
       dir
       )
      )
    )

 (if (and
       (setq fn (getstring "\n(Default Ext = .txt) Filename: "))
       (/= fn ""); if the user hits <enter>
       )
   
   ; make user we *have* a desktop path
   (if (setq fp (get-desktop))

     (cond

       ; user supplied extension so we'll use it
       ((vl-filename-extension fn)
        (setq fo (open (strcat fp fn) "a"))
        )

       ; user did *not* supply extension so we'll
       ; add .txt to the file name
       ((not (vl-filename-extension fn))
        (setq fo (open (strcat fp fn ".txt") "a"))
        )
       )

     ; this probably isn't needed but what the heck!
     (alert "Path [ C:\Documents and Settings\All Users\Desktop ] not found")
     )
   )

 (if fo ; ok file name look good so we can proceed
   (progn
     (write-line "Hello from the Desktop" fo)
     (close fo)
     )
   )

 (princ)
 )


[daron]

While we're on the subject of read/writ(e) ing to files, will someone explain how to properly use xmlin/xmlout? I know how to import the tlb. I just don't know what to do after that. Thank you.

[Keith™]

Oh the prevalence of code boggles the mind ...

[SMadsen]

(setq dir (strcat (getenv "ALLUSERSPROFILE") "\\Desktop\\"))

Mark, that's all fine but "Desktop" is in my localized version of Win2000 called "Skrivebord"