Topic: exploding a ssget

[DEVITG]

I have this code parta to selecte all POINT on a drawing

Code: [Select]

(DEFUN SELECIONEPUNTOS ()

;;;  (SETQ PUNTOS-EJE-X (SSGET "X"

(setq PUNTOS-EJE-X (ssget "X" '((0 . "POINT"))) )
(SETQ CANT-PUNTOS (SSLENGTH PUNTOS-EJE-X))
 



So I have the selection set , and the number of point on that selection.

QUESTION

How do I get all the entitys names and the x,y,z coordinates of each poitn

Thanks

[Keith™]

You need to iterate through the selection set and get the insertion point from each one.

Code: [Select]


(setq index 0)
(repeat (sslength PUNTOS-EJE-X))
(setq DXF10 (cdr (assoc 10 (entget (ssname PUNTOS-EJE-X index)))))
;;;add your code here
(setq index (1+ index))
)


[David Bethel]

I take a litlle different approach;

Code: [Select]



(defun SELECTPOINTS (/ ss i en ed ip fl)

(and (setq ss (ssget "X" '((0 . "POINT"))))
     (setq i (sslength ss))
     (while (not (minusp (setq i (1- i))))
            (setq en (ssname ss i)
                  ed (entget en)
                  ip (cdr (assoc 10 ed))
                  fl (cons (cons en ip) fl))))
fl)



-David

[CAB]

And a little of both:

Code: [Select]

(defun selectpoints (/ ss en fl)
  (and (setq ss (ssget "X" '((0 . "POINT"))))
       (repeat (sslength ss)
         (setq fl (cons (cons (setq en (ssname ss 0))
                              (cdr (assoc 10 (entget en)))) fl))
         (ssdel en ss)))
  fl
)

[MP]

And yet another:

Code: [Select]

(defun SelectPoints ( / ss i ename result )
    (if (setq ss (ssget "x" '((0 . "point"))))
        (repeat (setq i (sslength ss))
            (setq result
                (cons
                    (cons
                        (setq ename (ssname ss (setq i (1- i))))
                        (cdr (assoc 10 (entget ename)))
                    )
                    result
                )
            )
        )
    )
    result
)

[daron]

So DevitG, How do you like your code served up: Sunnyside up, Over-easy or over-hard?