Topic: BCOUNT -ALPHABETICAL

[rkysela]

Hello, can anyone help me ? I use huge amount of different blocks in drawing and if I count them by BCOUNT the list displays at NON alphabetical order. Is there any way how to force AutoCad to display them at alphabetical order

[It's Alive!]

Welcome to TheSwamp 
I don’t know if you can change the behavior of the command, but this might be something that can be recreated in lisp

something like

Code: [Select]

(DEFUN C:MYBCOUNT ( / c i l p s sl v)
  (VL-LOAD-COM)
  (SETQ S (SSGET "X" '((0 . "INSERT")))
L '()
SL '()
P ""
  )
  (PRINC "\nBlock.........................Count")
  (PRINC "\n-----------------------------------")
 
  (IF S
    (PROGN
      (SETQ C 0)
     
      (WHILE (< C (SSLENGTH S))
(SETQ L (CONS (STRCASE(CDR (ASSOC 2 (ENTGET (SSNAME S C))))) L)
      C (1+ C)))
     
      (SETQ L (VL-SORT L '>))
     
      (FOREACH V L
(IF (NOT (VL-POSITION V SL))
  (SETQ SL (CONS (STRCASE V) SL))))
 
      (FOREACH V SL
(SETQ C 0)
(FOREACH I L
  (IF (= V I)
    (PROGN
      (SETQ C (1+ C)))))
     
(IF (> C 0)
  (PROGN
    (REPEAT (- 30 (STRLEN V))
      (SETQ P (STRCAT P ".")))
       (PRINC (STRCAT "\n" V P (ITOA C)))
                (SETQ P "")
   
  )
)
      )
    )
  )
  (PRINC)
)


[Mark]

May or may not help but, you could use dataextraction and get a table of block names in alphabetical order.

[ronjonp]

Here's what I use. Works with modified dynamic blocks too 

Code: [Select]

;;; AUTHOR
;;; Copyright© 2009 Ron Perez (ronperez  at  gmail  .  com)
;;;

(defun c:blockcount (/ blks lst maxstr names out ss str tmp total)
  (vl-load-com)
  (if (setq ss (ssget '((0 . "INSERT"))))
    (progn (setq ss    (mapcar 'vlax-ename->vla-object
                               (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
                       )
                 blks  (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
                 str   ""
                 total 0
           )
           (vlax-map-collection blks
                                '(lambda (x)
                                   (if (not (wcmatch (vla-get-name x) "`**,*|*"))
                                     (setq names (cons (vla-get-name x) names))
                                   )
                                 )
           )
           (setq maxstr (+ 3 (apply 'max (mapcar 'strlen names))))
           (foreach x (reverse (acad_strlsort names))
             (foreach y ss
               (if (= (vla-get-effectivename y) x)
                 (setq lst (cons y lst))
               )
             )
             (if lst
               (setq tmp   ""
                     str   (strcat "\n"
                                   x
                                   (repeat (- maxstr (strlen x)) (setq tmp (strcat "." tmp)))
                                   (itoa (length lst))
                           )
                     out   (cons str out)
                     total (+ (length lst) total)
                     lst   nil
                     tmp   ""
               )
             )
           )
           (princ "\n")
           (repeat (apply 'max (mapcar 'strlen out)) (princ "="))
           (princ (apply 'strcat out))
           (princ "\n")
           (repeat (apply 'max (mapcar 'strlen out)) (princ "="))
           (princ
             (strcat "\nTOTAL"
                     (repeat (- maxstr (strlen "TOTAL")) (setq tmp (strcat " " tmp)))
                     (itoa total)
             )
           )
    )
    (princ "\nNo blocks selected...")
  )
  (princ)
)
*bug fix: repeat in strcat returned nil when maxstrlen = blockname strlen

[It's Alive!]

Yeah, but My dots are prettier   

[ronjonp]

Very true 

*now I have to make my dots pretty

[It's Alive!]

Does mine not work with modified dynamic blocks? I don’t have any so I couldn’t test

[ronjonp]

Does mine not work with modified dynamic blocks? I don’t have any so I couldn’t test

Daniel,

It picks them up as anonymous blocks (this is all the same block):

*U23..........................1
*U24..........................2
*U25..........................1

[It's Alive!]

Oh ok, Thanks for the test! I better fix this 

[ronjonp]

Updated code above...prints prettier results 

[It's Alive!]

Nice! 

[ronjonp]

Nice! 

Thanks Daniel 

[stevesfr]

Updated code above...prints prettier results 

Works with vanilla blocks. Why it doesn't work with blocks having attributes?

steveo
ac2008 vanilla

[FengK]

Works with vanilla blocks. Why it doesn't work with blocks having attributes?

steveo
ac2008 vanilla

that's odd, since all the code is doing is looping through selected blocks and count them by different effective name. it should not have anything to do with having attributes or not. try again or maybe post a sample drawing?

[ronjonp]

Updated code above...prints prettier results 

Works with vanilla blocks. Why it doesn't work with blocks having attributes?

steveo
ac2008 vanilla

I just tested it and it worked for me??