Topic: How to get all parameters at the self intersection of a curve?

[highflyingbird]

If a curve intersect with itself,how to get the second parameter (or the third parameter ,or more....) ?
I mean: we can use (vlax-curve-getParamAtPoint  curve intersectPoint) to get the parameter that from start point to its first intersection,then go on,it will have a second  intersection at the same point,so question is ,vlax-curve-getParamAtPoint just returns a single value,we don't know other parameters at this point,how to get them?

[Spike Wilbury]

get the intersection of the same curve using:

vla-intersectwith

then, use those points to extract their params.

[highflyingbird]

get the intersection of the same curve using:

vla-intersectwith

then, use those points to extract their params.

I know how to use vla-intersectwith,but sometimes this kind of curve just has a point of intersection,I want to know every parameter at this point.
Luis,thanks.

[Spike Wilbury]

get the intersection of the same curve using:

vla-intersectwith

then, use those points to extract their params.

I know how to use vla-intersectwith,but sometimes this kind of curve just has a point of intersection,I want to know every parameter at this point.
Luis,thanks.

I see that I missunderstood your question, what's your idea?, do you want to recreate the curve? or split the curve? - that curve looks like a spline, I have done the convertion to polyline but it end up being by approximation, something by the way available now in A2010... is that what you are after? if it is you will need to use C++ and ARX for the task.

Or explain in more detail....

[highflyingbird]

Sometimes we want to get these parameters to get all the length of segements that divided at this point,sometimes to split this curve at this point,and so on.
I think this question maybe  hasn't a direct answer.We need to split or break it and get these parameters.
for a lwpolyline,this question has a direct answer.

[Spike Wilbury]

Sometimes we want to get these parameters to get all the length of segements that divided at this point,sometimes to split this curve at this point,and so on.
I think this question maybe  hasn't a direct answer.We need to split or break it and get these parameters.

I went to my library of functions.... and also did a quick test using a spline like the one you posted, now if you noticed, can you define and pick an intersection on that apparent intersection? (you can't no?)

[highflyingbird]

Yes,I can't. and sometimes I use vla-intersectwith, it doesn't work?
for example,in this file, I can't get the intersection.
Actually, I can't get a intersection with a command if it's a spline.

[Spike Wilbury]

Yes,I can't. and sometimes I use vla-intersectwith, it doesn't work?
for example,in this file, I can't get the intersection.
Actually, I can't get a intersection with a command if it's a spline.

Yes....

The only thing I can think of is to use bpoly and create an internal boundary (that will be a region and if it is exploded converted to a spline), but the two outside spline parts are left out.

Or...

To convert the spline to polyline and work from there.

[jxphklibin]

I wrote a routine, but only for LWPOLYLINE POLYLINE, does not apply for the SPLINE.

Aother problem, that is, if is a vertex and a self-intersection, then this point does not know how to do.

[cjw]

So, "To convert the spline to polyline ".

[chlh_jd]

by this method can get the second param, but don't sure the intersections is correct .

Code: [Select]

(defun c:test  (/ en ips)
  (setq en (ssname (ssget ":E:S" '((0 . "SPLINE"))) 0))
  (setq ips (get-spline-cross-param en 1e-8))
  (if ips
    (foreach ip ips
      (entmake (list (cons 0 "POINT")
     (cons 10 (car ip))
     (cons 8 "Temp")
     (cons 62 1)))
      (entmake (list (cons 0 "LINE")
     (cons 10 '(0 0 0))
     (cons 11 (vlax-curve-getpointatparam en (cadr ip)))
     (cons 8 "Temp")
     (cons 62 1)
     ))
      (entmake (list (cons 0 "LINE")
     (cons 10 '(0 0 0))
     (cons 11 (vlax-curve-getpointatparam en (caddr ip)))
     (cons 8 "Temp")
     (cons 62 2)
     ))
      (princ (strcat "\nFirst param = "
     (rtos (cadr ip) 2 6)
     " ; Second param = "
     (rtos (caddr ip) 2 6)
     " ;;")))
    )
  (princ)
  )
;;;
(defun get-spline-cross-param  (en eps / _oce l ips len en1 mid)
  ;;by GSLS(SS) 2012-8-17
  (setq _oce (getvar "CMDECHO"))
  (setvar "CMDECHO" 0)
  (if en
    (progn
      (setq l
     ((lambda (/ r )
(if
  (not
    (vl-catch-all-error-p
      (vl-catch-all-apply
(function vl-cmdf)
(list "_PEDIT"
      (vlax-vla-object->ename
(vla-copy (vlax-ename->vla-object en))
)
      ""
      99
      ""
      ))))
   (progn
     (setq
       l (ss-assoc 10 (entget (setq r (entlast)))))
     (if (vlax-curve-isClosed r)
       (setq l (append l (list (car l))))
       )
     (entdel r)
     )
   )
l
)))
      (setq ips
     ((lambda (l isclosed / firstp p p0 p1 p2 p3 l1 ips)
(setq firstp t)
(while l
  (cond ((not firstp)
(setq p0 p1
       p1 (car l)
       l  (cdr l))
)
((and firstp isclosed)
(setq p0     (last l)
       p1     (car l)
       l      (cdr l)
       firstp nil)
)
(firstp
(setq p0     (car l)
       p1     (cadr l)
       l      (cddr l)
       firstp nil)
)
)
  (setq l1 l)
  (while (cadr l1)
    (setq p2 (car l1)
  p3 (cadr l1)
  l1 (cdr l1))
    (if (setq p (inters p0 p1 p2 p3))
      (setq ips (cons p ips))))
  )
ips
)
       l
       (vlax-curve-isclosed en)))
      (if ips
(progn
  (setq len (vlax-curve-getdistatparam
      en
      (vlax-curve-getendparam en)))
  (if
    (not (vl-catch-all-error-p
   (vl-catch-all-apply
     (function vl-cmdf)
     (list
       "_REVERSE"
       (vlax-vla-object->ename
(vla-copy (vlax-ename->vla-object en))
)
       ))))
     (progn        
       (setq en1 (entlast))
       (setq ipl
      (if
   (not
     (minusp
       (vlax-safearray-get-u-bound
(vlax-variant-value
   (setq mid
  (vla-IntersectWith
    (vlax-ename->vla-object
      en)
    (vlax-ename->vla-object
      en1)
    0
    )
)
   )
1
)
       )
     )
    (list-comp (vlax-safearray->list
(vlax-variant-value mid))
       3
       )
    ))
       (setq ips (mapcar (function (lambda (x)
    (car (vl-sort ipl (function (lambda (p1 p2)
      (< (distance x p1) (distance x p2))))))
     )
   )
ips))
       (setq
ips (mapcar
       (function
(lambda (p / is ps paf pas)
    (setq paf (vlax-curve-getparamatpoint
en
p)
   pas (vlax-curve-getparamatpoint
en1
p)
   pas (vlax-curve-getparamatdist
en
(-
   len
   (vlax-curve-getdistatparam
     en1
     pas)))  
   )
   (setq is T)
   (while is
     (setq ps (vlax-curve-getpointatparam en pas))
     (if (equal p ps eps)
       (setq is nil)
       (setq pas (+ pas (* (- (vlax-curve-getparamatpoint en (vlax-curve-getclosestpointto en (midpt p ps))) pas) 2.)))
       )
     )      
   (list p paf pas)
   ) ;_lambda
) ;_function
       ips) ;_mapcar
) ;_setq
       (entdel en1)        
       ) ;_progn      
     ) ;_if en1
  ) ;_progn
) ;_if ips
      ) ;_progn
    ) ;_if en
  (setvar "CMDECHO" _oce)
  ips
  )
;;
(defun ss-assoc (a lst / b res)
  (while (setq b (assoc a lst))
    (setq lst  (cdr (member b lst))
  res (cons (cdr b) res)
    ))(reverse res))
(defun list-comp (a b / mid rslt)
    (repeat (/ (length a) b)
      (setq mid nil)
      (repeat b
(setq mid (cons (car a) mid)
      a   (cdr a)
)
      )
      (setq rslt (cons (reverse mid) rslt))
    )
  (if a (reverse (cons a rslt))
    (reverse rslt))
  )


[Faster]

Only for LWpolyline:

Code - Auto/Visual Lisp: [Select]

1. (defun getlwparamatpoint (LW PT / DATA DPA PA PARS EL V K NEWEL A)
2.   (setq data (entget lw) dpa 0)
3.   (while (setq pa (vlax-curve-getParamAtPoint lw pt))
4.     (setq pars (cons (setq dpa (+ dpa pa)) pars)
5.           dpa (+ 1 (fix dpa))
6.           el (entget lw)
7.           v (- (cdr (assoc 90 el)) (fix pa) 1)
8.           k -1
9.           newel nil
10.           )
11.     (while el
12.       (setq a (car el)
13.             el (cdr el)
14.             )
15.       (cond
16.         ((= 10 (car a))
17.          (if (< k (fix pa))
18.            (setq k (1+ k)
19.                  el (cdddr el)
20.                  )
21.            (setq newel (cons a newel))
22.            )
23.          )
24.         ((= 90 (car el))
25.          (setq newel (cons (cons 90 v) newel))
26.          )
27.         (t (setq newel (cons a newel)))
28.        
29.         )
30.       )
31.     (entmod (reverse newel))
32.     (entupd lw)
33.     )
34.   (entmod data)
35.   (reverse pars)
36.   )
37. (defun c:test (/ e p pars)
38.   (setq e (car (entsel "\nSelect a lwpolyline:"))
39.         p (getpoint "\nSelect Point : ")
40.         )
41.   (if (and e p)
42.     (progn
43.     (setq pars (getlwparamatpoint e p))
44.     (if pars
45.       (progn
46.         (princ "\n Params is : ")
47.         (foreach a pars (princ a) (princ "  "))
48.         )
49.       (princ "\nNull...")
50.       )
51.     )
52.     )
53.   (princ)
54.   )

[Lee Mac]

Nice idea Faster 

[Faster]

This is my solutions:

Code: [Select]

;;Get all parameters for lwpolyline.
(defun gxl-getlwparamatpoint (LW PT / DATA DPA PA PARS EL V K NEWEL A)
  (setq data (entget lw) dpa 0)
  (while (setq pa (vlax-curve-getParamAtPoint lw pt))
    (setq pars (cons (setq dpa (+ dpa pa)) pars)
  dpa (+ 1 (fix dpa))
  el (entget lw)
  v (- (cdr (assoc 90 el)) (fix pa) 1)
  k -1
  newel nil
  )
    (while el
      (setq a (car el)
    el (cdr el)
    )
      (cond
((= 10 (car a))
(if (< k (fix pa))
   (setq k (1+ k)
el (cdddr el)
)
   (setq newel (cons a newel))
   )
)
((= 90 (car el))
(setq newel (cons (cons 90 v) newel))
)
(t (setq newel (cons a newel)))

)
      )
    (entmod (reverse newel))
    (entupd lw)
    )
  (entmod data)
  (reverse pars)
  )
;;Get all parameters for spline.
(defun gxl-getsplparamatpoint (SPL PT     /      GETPARAM OBJSPL
   OBJCIRCLE      PL       PARS0
   PA     PARS     RESULT
  )
  (defun getparam (CURVE PA1 PA2 P / PA P0 P1 P2)
    (setq pa (* 0.5 (+ pa1 pa2))
  p0 (vlax-curve-getPointAtParam curve pa)
    )
    (cond
      ((equal (setq p1 (vlax-curve-getPointAtParam curve pa1))
      (setq p2 (vlax-curve-getPointAtParam curve pa2))
      1e-8
       )
       pa
      )
      ((< (distance p p1) (distance p p2))
       (getparam curve pa1 pa p)
      )
      ((< (distance p p2) (distance p p1))
       (getparam curve pa pa2 p)
      )
      (t nil)
    )
  )
  (if (vlax-curve-getParamAtPoint spl pt)
    (progn
      (setq objspl    (vlax-ename->vla-object spl)
    objcircle (vla-addcircle
(vlax-get-property
  (vla-get-ActiveDocument (vlax-get-acad-object))
  (if (= 1 (getvar 'CVPORT))
    'PaperSpace
    'ModelSpace
  )
)
(vlax-3d-point pt)
1e-3
      )
      )
      (setq
pl (vlax-invoke objspl 'IntersectWith objcircle acExtendNone)
      )
      (vla-delete objcircle)
      (while pl
(setq pars0 (cons (vlax-curve-getParamAtPoint
   spl
   (list (car pl) (cadr pl) (caddr pl))
)
pars0
   )
      pl   (cdddr pl)
)
      )
      (setq pars0 (vl-sort pars0 '<))
      (while pars0
(setq pa (car pars0)
      pars0 (cdr pars0)
      )
(if pars0
  (progn
    (if (< (distance (vlax-curve-getPointAtParam spl pa) (vlax-curve-getPointAtParam spl (car pars0))) 2.0001e-3)
      (setq pars (cons (list pa (car pars0)) pars)
    pars0 (cdr pars0)
    )
      (setq pars (cons (list (if (vlax-curve-getpointatParam spl (- pa 1e-3))  (- pa 1e-3) (vlax-curve-getstartParam spl))
   (if (vlax-curve-getpointatParam spl (+ pa 1e-3))  (+ pa 1e-3) (vlax-curve-getendParam spl))
   )
     pars
     )
  )
      )
    )
  (setq pars (cons (list (if (vlax-curve-getpointatParam spl (- pa 1e-3))  (- pa 1e-3) (vlax-curve-getstartParam spl))
   (if (vlax-curve-getpointatParam spl (+ pa 1e-3))  (+ pa 1e-3) (vlax-curve-getendParam spl))
   )
     pars
     )
  )
  )
)
      (foreach par (reverse pars)
(if (setq pa (getparam spl (car par) (cadr par) pt))
  (setq result (cons pa result))
)
      )
      (reverse result)

    ) ;_ progn
  )
)
;;Get all parameters for any curves.
(defun gxl-getparamatpoint (CURVE PT / CURVETYPE ENL DATA E EL PAR)
  (if (= 'VLA-OBJECT (type curve))
    (setq curve (vlax-vla-object->ename curve))
  )
  (cond
    ((= "SPLINE" (setq curvetype (cdr (assoc 0 (entget curve)))))
     (gxl-getsplparamatpoint curve pt)
    )
    ((= "LWPOLYLINE" curvetype)
     (GXL-GETLWPARAMATPOINT curve pt)
    )
    ((= "POLYLINE" curvetype)
     (setq enl (entget curve)
   data
(list
  '(0 . "LWPOLYLINE")
  '(100 . "AcDbEntity")
  (assoc 8 enl)
  '(100 . "AcDbPolyline")
  (cons 90 (fix (vlax-curve-getendparam curve)))
  (cons 70
(if (vlax-curve-isClosed curve)
  1
  0
)
  )
)
   e curve
     )
     (while (and
      (setq e (entnext e))
      (/= (cdr (assoc 0 (entget e))) "SEQEND")
    )
       (setq el (entget e))
       (setq
data (append data
      (list (reverse (cdr (reverse (assoc 10 el))))
    (assoc 40 el)
    (assoc 41 el)
    (assoc 42 el)
      )
      )
       )

     )
     (entmake data)
     (setq curve (entlast))
     (setq par (GXL-GETLWPARAMATPOINT curve pt))
     (entdel curve)
     par
    )
    (t
     (if (setq par (vlax-curve-getParamAtPoint curve pt))
       (list par)
     )
    )
  )
)
(defun c:test (/ e p pars)
  (setq e (car (entsel "\nSelect a curve:"))
p (getpoint "\nSelect Point : ")
)
  (if (and e p)
    (progn
    (setq pars (gxl-getparamatpoint e p))
    (if pars
      (progn
(princ "\n Params is : ")
(foreach a pars (princ a) (princ "  "))
)
      (princ "\nNull...")
      )
    )
    )
  (princ)
  )


[chlh_jd]

This is my solutions:

Code: [Select]

;;Get all parameters for lwpolyline.
(defun gxl-getlwparamatpoint (LW PT / DATA DPA PA PARS EL V K NEWEL A)
  (setq data (entget lw) dpa 0)
  (while (setq pa (vlax-curve-getParamAtPoint lw pt))
......   
 

Good solution !