Topic: Filtering strings . . .

[jbuzbee]

How would I accomplish the following:

I read in a list of strings from a text file including blank lines - the blank lines help with reading the info:

Code: [Select]

01          INTERIOR KEYNOTES

01.001    SCHEDULED DOOR
01.002    WALL PARTITION

01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME
01.101    TEMPERED GLASS

01.200    BLH, BLAH, BLAH

02          EXTERIOR KEYNOTES 

. . .
So in a listbox control I only want to show the 01 keynotes.  The code I have doesn't recognize the blank spaces so it messes up the formating.  I think I need to use a while loop to know when I've left the 01 keynotes and stop looking but can't figure it out.  I don't need code, maybe a pseudo code outline.

Thanks for any help!

[T.Willey]

Why not use ' wcmatch ' with a pattern of ' 01* '?

[CAB]

If the blank line come in as "" then use
(vl-remove "" lst-of-strings)

[JohnK]

^^ Or dont even store it in the first place (use T.Willey's idea).

[Mark]

read in a list of strings from a text file including blank lines - the blank lines help with reading the info:

The code I have doesn't recognize the blank spaces so it messes up the formating.

Sounds like they need the blank lines to me.

[CAB]

I though he meant that the blank line helped reading that data file when editing it. 

[CAB]

My file reader. Reads the entire file into a list before processing the list.

Code: [Select]

;;  return only lines that start with "01"
(defun c:frtest (/ fname fn ln AllLines lst)
  (setq fname "MyFile.txt"
        prefix "01"
        pflen  (strlen prefix))
 
  (if (setq fn (findfile fname)) ; only if the file is found
    (progn ; fn contains the full path
      (setq fn (open fn "r")) ; open file for reading
      ;;  for speed read all the lines in the file
      (while (setq ln (read-line fn))
(setq AllLines (cons ln AllLines))
      )
      (close fn) ; close the open file handle
      (foreach ln AllLines ; note AllLines is reversed
        ;;  remove leading and trailing tabs & spaces
        (setq ln (vl-string-trim " \t" ln))
        ;;  exclude empty & non numeric lines
        (if (and (/= ln "")
                 (= (substr ln 1 pflen) prefix)
            )
          (setq lst (cons ln lst)) ;  collect the line
        )
      )
    )
  )
 lst
)

[jbuzbee]

I think I'm confusing everyone 

When "filtered" I want this:

Code: [Select]

01.001    SCHEDULED DOOR
01.002    WALL PARTITION

01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME
01.101    TEMPERED GLASS

01.200    BLH, BLAH, BLAH

not this:

Code: [Select]

01.001    SCHEDULED DOOR
01.002    WALL PARTITION
01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME
01.101    TEMPERED GLASS
01.200    BLH, BLAH, BLAH

Does that make any more sense?

[Matt__W]

"Peanut butter"... silly architects.   

[JohnK]

jbuzbee , I could have sworn that i gave you a file reader once in a PM but anyways...

Code: [Select]

(defun filereader (str file)
  ;; filereader
  ;;
  ;; Reads all lines in a file into a list.
  ;;
  ;;
  ;;      ( (lambda ( / f my-list )
  ;;          (setq f (open "c:\\Example.ini" "R"))
  ;;          (setq my-list
  ;;              (apply
  ;;                'append
  ;;                   (iniread (read-line f) f)))
  ;;          (close f)
  ;;          my-list ) )
  ;;     
  ;; => ("var1=val1" "var2=val2" "var4=val4")
  ;;
  ;; By: John (7) K
  ;;
  ( (lambda (s f)
      (if s
        (cons
            (list s)
          (filereader (read-line f) f))))
   str
   file ) )

;; one example of how to read from one file and write to another.

 ( (lambda ( / f )
     (setq f (open "c:\\Test.txt" "R"))
     (setq my-list
         (apply
            'append
               (filereader (read-line f) f)))
           (close f)

         (setq f (open "c:\\Test-output.txt" "W"))
         (foreach s my-list
   (write-line s f))
     (close f)) )

[CAB]

OK, maybe this

Code: [Select]

;;  return only lines that start with "01"
(defun c:frtest (/ fname fn ln AllLines lst blank)
  (setq fname "MyFile.txt"
        prefix "01"
        pflen  (strlen prefix))
  
  (if (setq fn (findfile fname)) ; only if the file is found
    (progn ; fn contains the full path
      (setq fn (open fn "r")) ; open file for reading
      ;;  for speed read all the lines in the file
      (while (setq ln (read-line fn))
(setq AllLines (cons ln AllLines))
      )
      (close fn) ; close the open file handle
      (foreach ln (reverse AllLines)
        ;;  remove leading and trailing tabs & spaces
        (setq ln (vl-string-trim " \t" ln))
        ;;  filter
        (cond
          ((and (not blank) (= ln ""))
           (setq lst (cons " " lst)) ;  add one space line
           (setq blank t)
          )
          ((= (substr ln 1 pflen) prefix)
           (setq lst (cons ln lst)) ;  collect the line
           (setq blank nil)
          )
          (blank (setq blank t))
        )
      )
    )
  )
 (reverse lst)
)

[MP]

Perhaps I'm not understanding, but given a list of strings, perhaps harvested from a file, this is all that's needed:

Code: [Select]

(vl-remove-if-not
   '(lambda ( x ) (wcmatch (vl-string-trim " \t" x) "01`.###*"))   
   '(
        "01          INTERIOR KEYNOTES"
        ""
        "01.001    SCHEDULED DOOR"
        "01.002    WALL PARTITION"
        ""
        "01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
        "01.101    TEMPERED GLASS"
        ""
        "01.200    BLH, BLAH, BLAH"
        ""
        "02          EXTERIOR KEYNOTES "
        "..."
    )
)
"01.001    SCHEDULED DOOR"
"01.002    WALL PARTITION"
"01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
"01.101    TEMPERED GLASS"
"01.200    BLH, BLAH, BLAH"

If you want to retain the blank lines just change the wcmatch pattern to "01`.###*,".

[CAB]

Michael he wants the blank lines included, I think.
Although they need to be of one space character.

John, it is the filtering he is struggling with.

[MP]

Yep, ergo the last sentence.

But thanks for the heads up Alan.

[JohnK]

Michael he wants the blank lines included, I think.
Although they need to be of one space character.

John, it is the filtering he is struggling with.

Code: [Select]

(defun filereader (str file)
      (if str
        (cons
  (if (or (wcmatch str "01`.###*" ) (eq str ""))
            (list str))
          (filereader (read-line file) file))))Like this? ...im lost.

[JohnK]

Michael he wants the blank lines included, I think.
Although they need to be of one space character.

John, it is the filtering he is struggling with.

Code: [Select]

(defun filereader (str file)
      (if str
        (cons
  (if (or (wcmatch str "01`.###*" ) (eq str ""))
            (list str))
          (filereader (read-line file) file))))Like this? ...im lost.

EDIT:
MP has a better filter!
> If you want to retain the blank lines just change the wcmatch pattern to "01`.###*,".
Good one!

[CAB]

Let's play "What If"
What if there are 100 lines in the data file & 20% are blank lines?
I don't think he wanted ALL the blank lines. 

[JohnK]

...Im going home.

[CAB]

Was it something I said?
Just kidding.

My strategy is to allow the first & last blank line to be added to the list as well as any single blank line found within the target prefix.
You could strip off the first & last easy enough. I don't allow for two or more blank lines in secession.
My test file:

Code: [Select]

00          Header
00.001    Subheader

01          INTERIOR KEYNOTES

01.001    SCHEDULED DOOR
01.002    WALL PARTITION

01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME
01.101    TEMPERED GLASS

01.200    BLH, BLAH, BLAH

02          EXTERIOR KEYNOTES 

03

04



. . .
Result:

Code: [Select]

(     " "
     "01          INTERIOR KEYNOTES"  
     " "
     "01.001    SCHEDULED DOOR"  
     "01.002    WALL PARTITION"
     " "
     "01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
     "01.101    TEMPERED GLASS"  
     " "
     "01.200    BLH, BLAH, BLAH"  
     " "
    )

[MP]

allow the first & last blank line to be added to the list as well as any single blank line found within the target prefix.

Is that really what he wants? If so perhaps:

Code: [Select]

(defun CleanUpIsleFour ( lst / flag )
    (vl-remove-if-not
       '(lambda ( x )
            (or
                (and
                    (wcmatch (setq x (vl-string-trim " \t" x)) "01`.###*")
                    (null (setq flag nil))
                )
                (and
                    (eq x "")
                    (null flag)
                    (setq flag t)
                )
            )
        )
        lst
    )
)

Code: [Select]

(CleanUpIsleFour
   '(
        ""
        ""
        ""
        "01          INTERIOR KEYNOTES"
        ""
        ""
        ""
        "01.001    SCHEDULED DOOR"
        "01.002    WALL PARTITION"
        ""
        ""
        ""
        "01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
        "01.101    TEMPERED GLASS"
        ""
        ""
        ""
        "01.200    BLH, BLAH, BLAH"
        ""
        ""
        ""
        "02          EXTERIOR KEYNOTES "
        ""
        ""
        ""
    )
)
""
"01.001    SCHEDULED DOOR"
"01.002    WALL PARTITION"
""
"01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
"01.101    TEMPERED GLASS"
""
"01.200    BLH, BLAH, BLAH"
""

/shrug

[T.Willey]

Maybe this?

Code: [Select]

(defun ReadFile ( fullPath ftrPat / Opened tempStr StrList)
   
    (setq Opened (open fullPath "r"))
    (while (setq tempStr (read-line Opened))
        (if (wcmatch tempStr ftrPat)
            (progn
                (setq StrList
                    (cons
                        (if (= tempStr "")
                            " "
                            tempStr
                        )
                        StrList
                    )
                )
                (while (setq tempStr (read-line Opened))
                    (if
                        (or
                            (wcmatch tempStr ftrPat)
                            (= tempStr "")
                        )
                        (setq StrList
                            (cons
                                (if (= tempStr "")
                                    " "
                                    tempStr
                                )
                                StrList
                            )
                        )
                    )
                )
            )
        )
    )
    (close Opened)
    StrList
)


[CAB]

Very nice Michael.
Yes I think that is it.
See example.
http://www.theswamp.org/index.php?topic=27880.msg334605#msg334605

[MP]

Thanks Alan. I wonder though if the leading and trailing "" items are acceptable.

[Daniel J. Ellis]

Bit beyond my real code, but in pseudo code would:

print out your header information
read all the lines into a list
process the list, line at a time
   If the line starts "01" grab that line into a variable
   bolt on a carriage return preceding the variable, outputting the two to a new variable
move onto the next item in the list
when finished, output the whole lot enmasse to wherever it needs to go

not do the trick?

Adding the carriage return *before* the line gives you a preceding line between your header and the first line, and eliminates a probably undesirable trailing line at the end

dJE

[CAB]

Thanks Alan. I wonder though if the leading and trailing "" items are acceptable.

I'd say not because he is going to use the list in a DCL list box.

[CAB]

One more attempt. Using "01." as the prefix and this new version eliminated leading & trailing blank lines.
Though not near as eloquent as Michael's it gets the job done. Michael's gives me something to strive for.

Code: [Select]

;;  return only lines that start with "01."
(defun c:frtest (/ fname fn ln AllLines lst blank)
  (setq fname "MyFile.txt"
        prefix "01."
        pflen  (strlen prefix))
 
  (if (setq fn (findfile fname)) ; only if the file is found
    (progn ; fn contains the full path
      (setq fn (open fn "r")) ; open file for reading
      ;;  for speed read all the lines in the file
      (while (setq ln (read-line fn))
(setq AllLines (cons ln AllLines))
      )
      (close fn) ; close the open file handle
      (foreach ln (reverse AllLines)
        ;;  remove leading and trailing tabs & spaces
        (setq ln (vl-string-trim " \t" ln))
        ;;  filter
        (cond
          ((and blank (= ln ""))
           (setq lst (cons " " lst)) ;  add one space line
           (setq blank nil) ; disallow another blank line
          )
          ((= (substr ln 1 pflen) prefix)
           (setq lst (cons ln lst)) ;  collect the line
           (setq blank t) ; allow one blank line to follow
          )
        )
      )
    )
  )
 (if (= " " (car lst))
   (reverse (cdr lst))
   (reverse lst)
 )
)

[MP]

I'd say not because he is going to use the list in a DCL list box.

If so then perhaps:

Code: [Select]

(defun CleanUpIsleFour ( lst / result flag )

    (if
        (eq ""
            (car
                (setq result
                    (vl-remove-if-not
                       '(lambda ( x )
                            (or
                                (and
                                    (wcmatch x "01`.###*")
                                    (null (setq flag nil))
                                )
                                (and
                                    (eq x "")
                                    (null flag)
                                    (setq flag t)
                                )
                            )
                        )
                        (mapcar '(lambda ( x ) (vl-string-trim " \t" x)) lst)
                    )
                )
            )
        )
        (setq result (cdr result))
    )

    (if (eq "" (last result))
        (reverse (cdr (reverse result)))
        result
    )

)

Code: [Select]

(CleanUpIsleFour
   '(
        ""
        ""
        ""
        "01          INTERIOR KEYNOTES"
        ""
        ""
        ""
        "01.001    SCHEDULED DOOR"
        "01.002    WALL PARTITION"
        ""
        ""
        ""
        "01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
        "01.101    TEMPERED GLASS"
        ""
        ""
        ""
        "01.200    BLH, BLAH, BLAH"
        ""
        ""
        ""
        "02          EXTERIOR KEYNOTES "
        ""
        ""
        ""
    )
)
"01.001    SCHEDULED DOOR"
"01.002    WALL PARTITION"
""
"01.100    USE PEANUT BUTTER TO CAULK WINDOW FRAME"
"01.101    TEMPERED GLASS"
""
"01.200    BLH, BLAH, BLAH"

PS: Thanks for the undeserved nice words Alan.

[jbuzbee]

You guys are hopeless!  I said psuedo code, but no - you guy's can't pass up the oppurtunity can you?  I think there is a twelve step program for this sort of thing.



 

Just kidding!  There's some pretty good code here guys, thankyou very much.  I'm not at my computer with all my source code so I'll have to try some of this stuff out tonight.  Thanks again.


(CleanUpIsleFour - pretty funny stuff MP)