Topic: get the distance between two points on pline

[subbup]

Hello All,

I need to find distance between two points on pline.
I will supply entity and two points on pline.
It should return the distance.Any Ideas.
  I know that if we supply distance it will give the point on pline.

[SMadsen]

I will supply entity and two points on pline.

If you supply two points on the pline, it'll be as easy as using the DISTANCE function.
Somehow I think there's more to your question, though? If so, can you explain further what the problem is?

[subbup]

I could'e have given the clear description.

If the pline have number of vertexs we can't use that Distance function.

[SMadsen]

Are you supplying the vertex number of the two points? Like: I want the distance between vertex no. 2 and vertex no. 4?

If so, is it the distance along the pline or the direct distance?

I promise that if I don't get it a third time then I won't bother you again

[subbup]

The supplied points always may not be the vertexs. Those points may fall inbetween vertexs on pline.

I want to get the distance along the pline inbetween these two points.

[SMadsen]

Oh ok. I think I get it. The pointsOnPline below will accept two points located on the polyline (or any curve object, actually) and return the distance along the object. If the points are not exactly on the object it will return nil (this can be adjusted so that points are projected onto the object if you wish).

The command function is just for testing it.

Code: [Select]

(defun pointsOnPline (obj p1 p2 / pd1 pd2)
  (vl-load-com)
  (if (= (type obj) 'ENAME)
    (setq obj (vlax-ename->vla-object obj))
  )
  (cond ((and (setq pd1 (vlax-curve-getDistAtPoint obj p1))
              (setq pd2 (vlax-curve-getDistAtPoint obj p2))
         )
         (- pd2 pd1)
        )
  )
)

(defun C:POP (/ ent p1 p2 dist)
  (setq ent (car (entsel "\nPick a polyline: ")))
  (setq p1 (getpoint "\nFirst point on pline: ")
        p2 (getpoint "\nSecond point on pline: ")
  )
  (and p1
       p2
       (if (setq dist (pointsOnPline ent p1 p2))
         (princ (strcat "\nDistance along pline: " (rtos dist)))
         (princ "\nOne or both points was not on pline")
       )
  )
  (princ)
)

[subbup]

Thank you
It's working fine.

[SMadsen]

Excellent!

[whdjr]

[In my best Japanese accent]
Thank you master stig for that enlightening
code on relaxed curves.
[/In my best Japanese accent]
   

[SMadsen]

オーケーです (no problem)