Topic: Comparing List Variables

[dustinthiesse]

I'm sure there's a simple way to do this...

What I've got is a list of filenames like:  (setq dwgs (list "aaa" "bbb" "ccc"))....etc....
What I am trying to do is if the current drawing exists within the list, remove it and then do some stuff...

Code: [Select]

(if (/= dwgs
         (setq dwgs (vl-remove-if
                          '(lambda (x)
                             (eq x (getvar 'dwgname))
                           )
                         dwgs
                         )
         )
    )
  (write-line(strcat "(load\""lisprun"\") " lisprun) scrfile)
)

It seems my main issue is the "/=" operator always returns T when comparing two lists.
I need this statement to return T ONLY when the current dwg is a member of the 'dwgs' variable.
Is there a function that will acheive this?

I know, i could probably do this by saying:

Code: [Select]

(if (member (getvar 'dwgname) dwgs)
  (progn
    (write-line(strcat "(load\""lisprun"\") " lisprun) scrfile)
    (setq dwgs (vl-remove (getvar 'dwgname) dwgs))
  )
)
But I don't want to!

[T.Willey]

If you want to use ' vl-remove... ', then just check the length of the list before and after.  If it's less, than the list was there, if equal than not.

[dustinthiesse]

Good idea Tim.

I figured it out tho.
I needed to use (not(equal....))
instead of (/=.....)

[Andrea]

Code: [Select]

(setq dwgs '( "aaa" "bbb" "ccc"))
(setq count1 (vl-list-length dwgs))

(setq dwgs (vl-remove (strcase "ccc")  (mapcar 'strcase dwgs)))
(setq count2 (vl-list-length dwgs))

(if (/= count1 count2)
  (alert "Current drawing name removed from the list")
  (alert "Current drawing name not found on the list")
)

[ronjonp]

Another way:

Code: [Select]

(if (and (vl-position (getvar 'dwgname) dwgs)
         (setq dwgs (vl-remove-if '(lambda (x) (eq x (getvar 'dwgname))) dwgs))
    )
  (write-line (strcat "(load\"" lisprun "\") " lisprun)
              scrfile
  )
)
I think this would work too (not tested)

Code: [Select]

(and (vl-position (getvar 'dwgname) dwgs)
     (setq dwgs (vl-remove-if '(lambda (x) (eq x (getvar 'dwgname))) dwgs))
     (write-line (strcat "(load\"" lisprun "\") " lisprun)
                 scrfile
     )
)


[JohnK]

Your homework for the night is to construct similar Auto Lisp versions; one which uses an iterative process. Then one that uses a recursive process.  ...Class dismissed.


~

[dustinthiesse]

Your homework for the night is to construct similar Auto Lisp versions; one which uses an iterative process. Then one that uses a recursive process.  ...Class dismissed.

Sounds like a fun challenge for the next time I have a little downtime (or need a distraction...ADD).
I'll have to put off checking this thread so I don't see the answers though 

[dustinthiesse]

I'm sure there's a more elegant way of doing this, but here's what I've got for the iterative version.
I've not been schooled in programming so the recursive version is a little above me at the moment.
I'd be interested to see one for educational purposes though.

Code: [Select]

;;;removes all instances of itm from lst
;;;returns newlst with itm removed
(defun remove-if(lst itm / newlst)

  (foreach n lst
    (if(/= n itm)
      (setq newlst(cons n newlst))
    )
  )
  (reverse newlst)
)

;;;returns T if itm exists in lst
;;;returns nil if itm does not exist
;
;;;basically is a (member) function
(defun remove-if-p(lst itm)

  (if(equal lst (remove-if lst itm))
    nil
    T
  )
)


[gile]

Hi,

Here's a recursive way for remove (vl-remove)

Code: [Select]

(defun remove (item lst)
  (if lst
    (if (equal item (car lst))
      (remove item (cdr lst))
      (cons (car lst) (remove item (cdr lst)))
    )
  )
)
For remove-if, an argument should be a predicate function:

Code: [Select]

(defun remove-if (fun lst)
  (if lst
    (if (apply fun (list (car lst)))
      (remove-if fun (cdr lst))
      (cons (car lst) (remove-if fun (cdr lst)))
    )
  )
)
To search an item in a list, you'd rather stop the process when the first occurence is found
A recursive way

Code: [Select]

(defun countains (item lst)
  (if lst
    (or (equal item (car lst))
      (countains1 item (cdr lst))
    )
  )
)An iterative way

Code: [Select]

(defun countains (item lst / found)
  (while (and (not found) lst)
    (if (equal item (car lst))
      (setq found T)
      (setq lst (cdr lst))
     
    )
  )
  found
)

[dustinthiesse]

Thank you very much for the examples! 

[gile]

Another iterative way

Code: [Select]

(defun countains (item lst)
  (and
    (while (and lst (not (equal item (car lst))))
      (setq lst (cdr lst))
    )
    lst
  )
)

[JohnK]

My most favorite iterative version:

Code: [Select]

;;; Author: Matt Stachoni
(defun list:Remove (e l)
  (apply 
    'append
    (subst nil (list e) (mapcar 'list l))
    )
  )


[MP]

Truth be told, that one looks like something Tony wrote around 1692. PS: It's not iterative.

[dustinthiesse]

PS: It's not iterative.

I still like it.  Good stuff.

[JohnK]

Truth be told, that one looks like something Tony wrote around 1692. PS: It's not iterative.

yeah i guess your right. ...meh.

It does? Well i got it off a post from Matt so i don't really know where it came from before that so sorry Tony, if its your's.