Topic: attach multiples with outlook

[paul_s]

Does anybody know thru coding if we can attached multiple files with outlook?

This is how we open outlook and attached a file..
(startapp (strcat "outlook.exe " "/a "  "P:\\Project Name\\Docs\\Document1.Doc"))

[ronjonp]

I can't get your example to work with even one attachment 
"the command line argument is not valid"

[paul_s]

How about this, with "my" path to outlook.exe

(startapp (strcat "c:\\program files\\Microsoft Office\\Office12\\outlook.exe " "/a "  "P:\\Project Name\\Docs\\Document1.Doc"))

[ronjonp]

How about this, with "my" path to outlook.exe

(startapp (strcat "c:\\program files\\Microsoft Office\\Office12\\outlook.exe " "/a "  "P:\\Project Name\\Docs\\Document1.Doc"))

I had already tried that...but still got switch errors.

[dustinthiesse]

How about this, with "my" path to outlook.exe

(startapp (strcat "c:\\program files\\Microsoft Office\\Office12\\outlook.exe " "/a "  "P:\\Project Name\\Docs\\Document1.Doc"))

I had already tried that...but still got switch errors.

I got it to work using this syntax     EDIT:  Just to clarify...I got the one attachment to work with this syntax.  Still working on multiples!!!

Code: [Select]

(startapp "outlook.exe" (strcat "/a" " " "path_in_quotes"))

Notes:  make sure there is a space between the switch and the path,
and if the path has any embedded spaces, you may have to literally quote it like so "\"path with spaces\""

[paul_s]

Hmmm..It works for me. The only thing I can think of is that do you have a "space" between
outlook.exe and the quotation mark?. And a space between the switch /a and the quotation mark.

....\\outlook.exe "
"/a "

[ronjonp]

Strange..I've tried 5 or 6 variants including the examples posted and this is what i get:

[paul_s]

This is exactly the error box I get too if the switch is  .."/a", instead of "/a ".

[dustinthiesse]

May have something to do with different versions of MS Office.
I am using Outlook 2007.

[paul_s]

I tried it both for Outlook 2003 & 2007. It works.

"c:\\program files\\Microsoft Office\\Office12\\outlook.exe "...for Outlook 2007
"c:\\program files\\Microsoft Office\\Office11\\outlook.exe "...for Outlook 2003

[ronjonp]

Ditched that route and came up with this  ...let me know if it works for you.

Code: [Select]

;;Usage
(rjp-OutlookMessage
  ;;email address (multiple separated by semicolon)
  "johndoe@nowhere.com;johndoewife@nowhere.com"
  ;;Subject
  "Test Email"
  ;;Attachments as a list of strings
  '("C:\\test\\file1.txt" "C:\\test\\file2.txt" "C:\\test\\file3.txt")
  ;;Text in body of email
  "Nothing to read here :)"
  ;;nil will open email to edit...T will send email in the background
  nil
)

(defun rjp-OutlookMessage
       (To Subject AttachmentList Body Send / objMail objOL)
  (if (and (setq objOL (vlax-get-or-create-object "Outlook.Application"))
   (setq objMail (vlax-invoke-method objOL 'CreateItem 0))
      )
    (progn
      (vlax-put objMail 'To To)
      (vlax-put objMail 'Subject Subject)
      (vlax-put objMail 'Body Body)
      (foreach file AttachmentList
(vl-catch-all-apply
  'vlax-invoke
  (list (vlax-get objMail 'Attachments)
'Add
file
  )
)
      )
      (if send
(vlax-invoke objMail 'Send)
(vlax-invoke objMail 'Display :vlax-true)
      )
      (vlax-release-object objOL)
      (vlax-release-object objMail)
    )
  )
  (princ)
)


[dustinthiesse]

Yeah ron, I've come to realize it's just not possible using the "startapp" command.

I found a thread on the AUGI forums that covers this.
Attached is some code from there, slightly modified to allow the selection of multiple attachments.

[paul_s]

Ronjonp,

WOW!..It worked!!!! So short & simple.Thank you!

D-Unit,
Thank you for your post. I will study this too.

[ronjonp]

Ronjonp,

WOW!..It worked!!!! So short & simple.Thank you!

D-Unit,
Thank you for your post. I will study this too.

You're welcome Glad to help out.

[dustinthiesse]

Ronjonp,

WOW!..It worked!!!! So short & simple.Thank you!

D-Unit,
Thank you for your post. I will study this too.

No prob.  Don't know if I will ever use this information but it is pretty neat.
I don't think there will ever be a shortage of stuff to learn in this lisp world.