Topic: Layer filter wildcards

[MP]

Krushert,

Me again. From the coding examples, I'm able to create "~M*".
But not the second  line "*|*". Do you know how?

Code: [Select]

(defun c:EagerToLearnCAD ( / xdict dict xrecname )

    (setq xdict
        (vlax-vla-object->ename
            (vla-getextensiondictionary
                (vla-get-layers
                    (vla-get-activedocument (vlax-get-acad-object))
                )
            )
        )   
    )
   
    (setq dict
        (if (setq dict (dictsearch xdict "ACAD_LAYERFILTERS"))
            (cdr (assoc -1 dict))
            (dictadd xdict "ACAD_LAYERFILTERS"
                (entmakex
                   '(
                        (0 . "dictionary")
                        (100 . "AcDbDictionary")
                        (280 . 0)
                        (281 . 1)
                    )
                )
            )
        )
    )
   
    (princ
        (if (dictsearch dict (setq xrecname "EagerToLearnCAD"))
            (strcat
                "Layer filter named <"
                xrecname
                "> already exists."
            )
            (if
                (dictadd dict xrecname
                    (entmakex
                        (append
                           '(
                                (0 . "xrecord")
                                (100 . "AcDbXrecord")
                                (280 . 1)
                            )   
                            (list (cons 1 xrecname))
                           '(
                                (1 . "~M*,*|*")
                                (1 . "*")
                                (1 . "*")
                                (70 . 0)
                                (1 . "*")
                                (1 . "*")
                                (-3         
                                    (
                                        "ACAD"
                                        (1000 . "( NAME== \"~M*\" or NAME== \"*|*\" )")
                                    )
                                )
                            )   
                        )
                    )
                )
                (strcat
                    "Created layer filter named <"
                    xrecname
                    ">."
                )
                "Doh! Something horrible happened: Call mommy."
            )   
        )   
    )   
   
    (princ)
   
)

[EagerToLearnCad]

Thanks guys!

MP,

One last. Do you know how to check/select the "Invert Filter" checkbox with lisp? I would
like to be able to toggle it (check/unchecked) in my small program.

[mkweaver]

Thanks guys!

MP,

One last. Do you know how to check/select the "Invert Filter" checkbox with lisp? I would
like to be able to toggle it (check/unchecked) in my small program.

When you figure out the toggle code, have it email you a penny each time its run, then post the code.  You'll be able to retire!

[MP]

I'm likely wrong but I don't believe it's available to lispers. I've scanned the system variables, environment variables, atoms family, the registry, ini files ad infinitum, no can find.

[EagerToLearnCad]

MP,

Thanks for checking.

[MP]

You're most welcome ETLC.

[alanjt]

couldn't you use the NOT?

Code: [Select]

(ssget '((-4 . "<not")(8 . "*|*")(-4 . "not>"))))