Topic: Auto Number feedback

[quamper]

I'm not much of a LISP programmer so I just stumbled through writing a real quick and dirty autonumber/increment routine thing. I'm sure this is a duplication of something I could have googled and found. I guess it was a learning experience. Anyways any suggestions or feedback on something I did wrong or could have done better? I'd love to learn for future efforts.

It seems to work fine for me other than I have to hit escape and repeat the command when I want to change to a new Prefix, but that doesn't really bother me.

Code: [Select]

(defun c:lb( / PREFIX SUFFIX TXTINSERT)
    (command "layer" "set" "label" "")
    (setq PREFIX (getstring "\nEnter Label Prefix: "))
    (setq SUFFIX 1)
    (while T
        (setq TXTINSERT (getpoint "\nSelect Text Placement: "))
        (command "text" TXTINSERT "" "" (strcat PREFIX "_"
            (if (< SUFFIX 10) "0" "")
            (itoa SUFFIX))
        )
        (setq SUFFIX (+ SUFFIX 1))
    )
)


[ronjonp]

Here would be my quick comments

Code: [Select]

(defun c:lb (/ prefix suffix txtinsert)
  ;;use make and the layer will be created otherwise will bomb if layer does not exist
  (command "-layer" "make" "label" "")
  ;;If you have a prefix you use regularly, you could make a default if enter is pressed like so
  (if (and (setq prefix (getstring "\nEnter Label Prefix<MYPRE>: "))
           (= prefix "")
      )
    (setq prefix "MYPRE")
  )
  (setq suffix 1)
  (while (setq txtinsert (getpoint "\nSelect Text Placement: "))
    ;;allows to hit enter to get out of loop
    (command "text"
             txtinsert
             ""
             ""
             (strcat prefix
                     "_"
                     (if (< suffix 10)
                       "0"
                       ""
                     )
                     (itoa suffix)
             )
    )
    (setq suffix (+ suffix 1))
  )
  (princ);;to exit quietly
)

[quamper]

I never realized that you could use make with the layer command for existing layers making them current at the same time. That's great!

I like the default prefix, unfortunately for my usage I don't have ones that are used regularly, but I see what you were doing there so that's great feedback. Thanks!

[ronjonp]

Did you want the suffix count to reset to 1 when 10 is hit? If so you need to change this portion:

             (strcat prefix
                     "_"
                     (if (> suffix 10)
                       (itoa (setq suffix 1))
                       (itoa suffix)
                     )
             )

[quamper]

Did you want the suffix count to reset to 1 when 10 is hit? If so you need to change this portion:

No I wanted the 0 prefixing when it was less than 10

so Label_01, Label_02, Label_03 ... etc

[ronjonp]

Gotcha