Topic: Wblock with ObjectDBX and Visual Lisp

[mmalbr]

What's wrong in the code below?

Should export a new drawing for a block contained in another design without opening it

(setq
*acad* (vlax-get-acad-object)
doc (vla-get-activedocument *acad*)
desenho "C:\\Arquivos de programas\\AutoCAD 2007\\support\\db_samp.dwg"
)
(setq oDBX (vla-GetInterfaceObject *acad* "ObjectDBX.AxDbDocument.17"))
(vla-open oDBX desenho)

(vlax-for layout (vla-get-layouts oDBX)
(vlax-for blk (vla-get-block layout)
(if (and
(= (vla-get-objectname blk) "AcDbBlockReference")
(= (strcase (vla-get-name blk)) "CHAIR7")
)
(setq nomes_lst (cons blk nomes_lst))
)
)
nomes_lst
)
(setq SAwallobj (vlax-make-safearray vlax-vbObject '(0 . 0)))
(vlax-safearray-fill SAwallobj (car nomes_lst)) ; error here
(vla-wblock oDBX "c:/bloco.dwg" SAwallobj) ; and error here too



Marcos Mendes
Visit my site:
http://www.autolisp.com.br/

[ronjonp]

It looks like vla-wblock is looking for a selection set rather than a safearray

[mmalbr]

(vla-wblock oDBX "c:/bloco.dwg" SAwallobj)

SAwallobj is SAFEARRAY, but is not it working!

[CAB]

Welcome to the Swamp.

[Jeff_M]

Hi Marcos. Welcome to the Swamp!

As Ronjonp noted, you are passing an array to the WBLOCK method which is expecting a SelectionSet. Since you cannot create or use selection sets in an ObjectDBX document wou will need to do this another way. Try creating the new drawing, then use the CopyObjects (which CAN use the array you created) method to get the entities into that new drawing

[efernal]

ei, marcos, em menos de uma hora você já obteve 4 respostas...
aqui é o lugar, cara...
abs...
e.fernal

[mmalbr]

Pois é ... gostei daqui!

valeu mesmo!

[ronjonp]

See if this help you out some....no error checking included.

Code: [Select]


(defun copytocurrentdwg (copydoc blkname / *acad* doc objlst odbx)
  (setq *acad* (vlax-get-acad-object)
doc    (vla-get-activedocument *acad*)
  )

  (setq oDBX (vla-GetInterfaceObject *acad* "ObjectDBX.AxDbDocument.17"))
  (vl-catch-all-apply 'vla-open (list odbx copydoc))

  (vlax-for layout (vla-get-layouts oDBX)
    (vlax-for blk (vla-get-block layout)
      (if (and
    (= (vla-get-objectname blk) "AcDbBlockReference")
    (= (strcase (vla-get-name blk)) (strcase blkname))
  )
(setq objlst (cons blk objlst))
      )
    )
  )
  (vla-copyobjects
    odbx
    (vlax-safearray-fill
      (vlax-make-safearray
vlax-vbobject
(cons 0 (1- (length objlst)))
      )
      objlst
    )
    (vla-get-modelspace
      (vla-get-activedocument (vlax-get-acad-object))
    )
  )
  (vla-saveas odbx (vla-get-name odbx))
  (vlax-release-object odbx)
  (princ)
)
;;Lets run it (this copies to the current open drawing)
(copytocurrentdwg
  "C:\\Arquivos de programas\\AutoCAD 2007\\support\\db_samp.dwg"
  "CHAIR7"
)


[Spike Wilbury]

and for those of us, that do not speak Portuguese...

I think Marcos, is saying:

In less than an hour, I got four answers, I like this place...

That's why I like here!!!

It Worth's !

[mmalbr]

Hi Marcos. Welcome to the Swamp!

As Ronjonp noted, you are passing an array to the WBLOCK method which is expecting a SelectionSet. Since you cannot create or use selection sets in an ObjectDBX document wou will need to do this another way. Try creating the new drawing, then use the CopyObjects (which CAN use the array you created) method to get the entities into that new drawing

Thanks .. I will try this way!

[mmalbr]

See if this help you out some....no error checking included.

Thanks .. I will try