Topic: ( Challenge ) How fast can you convert these?

[Mark]

Using the attached .dwg, show us how fast you can convert the existing entities/objects into something else. i.e. from points to circles.

the .dwg contains about 10,000 ACAD points.

[Notsober]

i turned it into an empty drawing...

was that fast, or was that fast??

 

[MP]

[MP]

PS: Isn't the count more like 11336?

[Mark]

that was fast!

[CAB]

My routine took about 12 seconds on my old machine.

[It's Alive!]

mine 

Code: [Select]

(defun c:doit ( / activedocument c e iacadapplication modelspace s)
  (vl-load-com)
  (setq IAcadApplication (vlax-get-acad-object)
ActiveDocument (vla-get-ActiveDocument IAcadApplication)
ModelSpace (vla-get-ModelSpace ActiveDocument)
  )
  (setq s (ssget "X" (list (cons 0 "POINT"))))
  (setq c 0)
  (if s
    (progn
      (While (< c (sslength s))
       (setq e (vlax-ename->vla-object (cdr (car (entget (ssname s c))))))
(vla-Addcircle ModelSpace (vlax-3d-point (vlax-get e 'Coordinates )) 15)
(vla-Erase e)
(setq c (1+ c))
      )
    )
    (alert (strcat "Could Not find any Points"))
  )
  (princ)
)


[Keith™]

about 8 second

[Matt__W]

About 2 seconds using VBA.

Code: [Select]

Public Sub ConverterPoints()
    Dim objPoint As AcadPoint
    Dim objCircle As AcadCircle
    Dim StartTime, EndTime As Date
   
    StartTime = Now
    For Each objPoint In ThisDrawing.ModelSpace
        Set objCircle = ThisDrawing.ModelSpace.AddCircle(objPoint.Coordinates, 30)
        objPoint.Delete
    Next objPoint
    EndTime = Now
    Debug.Print DateDiff("s", StartTime, EndTime)
End Sub

[Hedgehog]

I changed 'em all to crosses instantly... pdmode 

... just don't set it to 4... sends yer eyes wappy

[CAB]

Hey Matt this is a LISP forum.
 

[ronjonp]

< Elapsed time: 0.953000 seconds. > 

Code: [Select]

(defun c:test (/ ss *time*)
  (setq *time* (getvar 'MILLISECS)
ss     (mapcar 'cadr (ssnamex (ssget "_x" '((0 . "POINT")))))
  )
  (while ss
    (entmakex (list '(0 . "CIRCLE")
    (assoc 10 (entget (car ss)))
    '(40 . 1.0)
      )
    )
    (entdel (car ss))
    (setq ss (cdr ss))
  )
  (princ
    (strcat "\n < Elapsed time: "
    (rtos (/ (- (getvar 'MILLISECS) *time*) 1000.0) 2 6)
    " seconds. > "
    )
  )
)

[It's Alive!]

nice 

[CAB]

Looks like the vla-add method is the fastest lisp. Twice as fast as my entmake.

[ronjonp]

< Elapsed time: 0.687000 seconds. > 

*updated per MP's comment

Code: [Select]

(defun c:test (/ *time* n e ss)
  (setq *time* (getvar 'millisecs)
ss     (ssget "_x" '((0 . "POINT")))
n      -1
  )
  (repeat (sslength ss)
    (entmakex
      (list '(0 . "CIRCLE")
    '(62 . 1)
    (assoc 10 (entget (setq e (ssname ss (setq n (1+ n))))))
    '(40 . 1.0)
      )
    )
    (entdel e)
  )
  (princ
    (strcat "\n < Elapsed time: "
    (rtos (/ (- (getvar 'millisecs) *time*) 1000.0) 2 6)
    " seconds. > "
    )
  )
)