Topic: "simulate" pick point

[Daniel J. Ellis]

Is there a way to feed a point (variable) to simulate clicking on an object to select it?

DJE

[Kerry]

yes,
say
( setq yourPoint '(0 0 0))

try (setq ent (car (nentselp yourPoint)))

OR
Have a look at ssget

using either the point  ie
 (ssname (ssget yourPoint ) 0)
OR
with a crossing
 (ssname (ssget "_C" '(0 0) '(1 1)) 0)

OR
try (setq ent (car (nentselp yourPoint)))

[Daniel J. Ellis]

nentselp sounds the way to go

I'll have a play with that and let you know how I get on.

[cjw]

Very nice!
Just search for it.
It's not accurate code I use before:

(setq ent (entsel "\nget the point:"))
(setq e  (car ent)
        pt (cadr ent)
        pt (vlax-curve-getclosestpointto e pt)
)

[Daniel J. Ellis]

Experimenting with NENTSELP, this is my code:
(DEFUN c:obj ( / )
   (SETQ
      select (ENTSEL "\nSelect object: ")
      ent (CAR select)
      hpt (CDR select)
   )
   (PRINC "\nent: ")(PRINC ent)
   (PMAKE)
   (SETQ ent2 (CAR(NENTSELP hpt)))
   (PRINC "\nent2: ")(PRINC ent2)
)

(defun pmake () (command "PEDIT" ent "YES" "" "")(princ))

But I only ever get an error message:
error: bad argument type: 2D/3D point: ((142.318 200.826 0.0))

Any ideas?

DJE

[Kerry]

Dan,
what do you think that code should be doing ?

[Daniel J. Ellis]

It's a test routine

Select an object, saving as a variable
split out the entity itself and the selection point into two other variables
Print the entity name to the command line
Turn the entity into a polyline
Select the entity at the original coordinates
Print the new entity name to screen

DJE

[Daniel J. Ellis]

Figured it out

I need to set hpt to (CAR(CDR select)) not just (CDR select)!!  That can be shortened to (CADR select) can't it?

DJE (in glory!)

[Alan Cullen]

I believe so....I'm a bit sloppy at the moment.....
but (CAR(CDR select)) = (CADR select)

Too lazy to check my notes at the moment. (getting too drunk...well it IS Friday night)

[ronjonp]

Maybe some food for thought:

Code: [Select]

(defun c:obj (/ ent ent2 hpt select)
  (if (and (setq select (entsel "\nselect object: "))
   (setq ent (car select))
   (setq hpt (cadr select))
   (not (wcmatch (cdr (assoc 0 (entget ent))) "*POLYLINE"))
      )
    (progn
      (pmake ent)
      (setq ent2 (entlast))
      (princ (strcat "\nent: "
     (vl-princ-to-string ent)
     "  ent2: "
     (vl-princ-to-string ent2)
     )
      )
    )
    (princ
      "\nYou either missed your pick or the object was already a polyline!"
    )
  )
)

(defun pmake (ent)
  (command "pedit" ent "yes" "" "")
)

[Kerry]

Figured it out
<<

great !

<<
I need to set hpt to (CAR(CDR select)) not just (CDR select)!!  That can be shortened to (CADR select) can't it?
>>

Yes
here are enough cars to start a sales yard ..

Code: [Select]

(car theList) Returns the first element of a theList.
(cdr theList) Returns the theList minus the first element.
(caar theList) The car of the car of theList
(cadr theList) The car of the cdr of theList
(cdar theList) The cdr of the car of theList
(cddr theList) The cdr of the cdr of theList
(caaar theList) The car of the car of the car of theList
(caadr theList) The car of the car of the cdr of theList
(cadar theList) The car of the cdr of the car of theList
(caddr theList) The car of the cdr of the cdr of theList
(cdaar theList) The cdr of the car of the car of theList
(cdadr theList) The cdr of the car of the cdr of theList
(cddar theList) The cdr of the cdr of the car of theList
(cdddr theList) The cdr of the cdr of the cdr of theList
(caaaar theList) The car of the car of the car of the car of theList
(caaadr theList) The car of the car of the car of the cdr of theList
(caadar theList) The car of the car of the cdr of the car of theList
(caaddr theList) The car of the car of the cdr of the cdr of theList
(cadaar theList) The car of the cdr of the car of the car of theList
(cadadr theList) The car of the cdr of the car of the cdr of theList
(caddar theList) The car of the cdr of the cdr of the car of theList
(cadddr theList) The car of the cdr of the cdr of the cdr of theList
(cdaaar theList) The cdr of the car of the car of the car of theList
(cdaadr theList) The cdr of the car of the car of the cdr of theList
(cdadar theList) The cdr of the car of the cdr of the car of theList
(cdaddr theList) The cdr of the car of the cdr of the cdr of theList
(cddaar theList) The cdr of the cdr of the car of the car of theList
(cddadr theList) The cdr of the cdr of the car of the cdr of theList
(cdddar theList) The cdr of the cdr of the cdr of the car of theList
(cddddr theList) The cdr of the cdr of the cdr of the cdr of theList
so ..
(caar theList)  is equivalent to (car (car theList))
(cdar theList)  is equivalent to (cdr (car theList))
(cadar theList) is equivalent to (car (cdr (car theList)))
(cadr theList)  is equivalent to (car (cdr theList))
(cddr theList)  is equivalent to (cdr (cdr theList))
(caddr theList) is equivalent to (car (cdr (cdr theList)))