Topic: Interesting DCL Problem...

[Columbia]

I've got an interesting DCL problem that I'm hoping one of the experts in the lost art of DCL can show me where I wandered off the beaten path.

I'm using VLIDE in 2004 to preview the following DCL code:

Code: [Select]


//--------------------------------------------------------------
// BACK button
//--------------------------------------------------------------

back_button : button { label = "<- Back"; key = "back"; }

//--------------------------------------------------------------
// BACK button
//--------------------------------------------------------------

next_button : retirement_button { label = "Next ->"; key = "next"; }

//--------------------------------------------------------------
// BACK-NEXT-CANCEL-HELP cluster
//--------------------------------------------------------------

back_next_cancel_help : column {
  : row { fixed_width = true; alignment = centered;
    back_button;
    : spacer {width = 2;}
    next_button;
    : spacer {width = 10;}
    cancel_button;
    : spacer {width = 2;}
    help_button;
  }
}

//--------------------------------------------------------------
// WIZARD image tile
//--------------------------------------------------------------

wizard_image : image {
  key = "wizard_pic";
  fixed_width = true;
  fixed_height = true;
  alignment = top;
  width = 30;
  aspect_ratio = 1.0;
  color = 0;
}

wizard1 : dialog {
  label = "Project Creation Wizard";
  : boxed_row {
    fixed_height = true;
    fixed_width = true;
    width = 65;
    height = 15;
    wizard_image;
    : column {
      : paragraph {
        : text_part { label = "Welcome to the Project Wizard."; }
        : text_part { label = ""; }
        : text_part { label = "Please choose a method of Project Creation."; }
        : text_part { label = ""; }
     }
    : row {
      spacer_1;
      : radio_column {
        key = "method";
        alignment = centered;
        fixed_height = true;
        height = 5;
        : radio_button { key = "scratch"; label = "Create Project from Scratch"; }
        : radio_button { key = "copy"; label = "Create Project by Copying Existing File"; }
      }
    }
    spacer_1;
    }
  }
  back_next_cancel_help;
}


What happens is that with the "back_next_cancel_help;" line in the code, AutoCAD will lock-up tighter than a drum.  If I comment out the line, and put an "ok_only;" tile in its place, then everything is peachy.
I've tried both the Back and Next buttons as retirement_button tiles and as just plain button tiles, as well as just the one as a retirement_button.  Neither makes a difference.

Can any of you shed any light??  Thanks, all...

[Mark]

this works for me, see line No. 24

Code: [Select]


//--------------------------------------------------------------
// BACK button
//--------------------------------------------------------------

back_button : button { label = "<- Back"; key = "back"; }

//--------------------------------------------------------------
// BACK button
//--------------------------------------------------------------

next_button : retirement_button { label = "Next ->"; key = "next"; }


//--------------------------------------------------------------
// BACK-NEXT-CANCEL-HELP cluster
//--------------------------------------------------------------

back_next_cancel_help : column {
  : row { fixed_width = true; alignment = centered;
    back_button;
    : spacer {width = 2;}
    next_button;
    : spacer {width = 10;}
    : cancel_button { is_default = true; } // < -- here
    : spacer {width = 2;}
    help_button;
  }
}

//--------------------------------------------------------------
// WIZARD image tile
//--------------------------------------------------------------

wizard_image : image {
  key = "wizard_pic";
  fixed_width = true;
  fixed_height = true;
  alignment = top;
  width = 30;
  aspect_ratio = 1.0;
  color = 0;
}

wizard1 : dialog {
  label = "Project Creation Wizard";
  : boxed_row {
    fixed_height = true;
    fixed_width = true;
    width = 65;
    height = 15;
    wizard_image;
    : column {
      : paragraph {
        : text_part { label = "Welcome to the Project Wizard."; }
        : text_part { label = ""; }
        : text_part { label = "Please choose a method of Project Creation."; }
        : text_part { label = ""; }
     }
    : row {
      spacer_1;
      : radio_column {
        key = "method";
        alignment = centered;
        fixed_height = true;
        height = 5;
        : radio_button { key = "scratch"; label = "Create Project from Scratch"; }
        : radio_button { key = "copy"; label = "Create Project by Copying Existing File"; }
      }
    }
    spacer_1;
    }
  }
  back_next_cancel_help;
  }


[Columbia]

Thanks, Mark!  This is definitely what I needed.  Everything is all better now...