Topic: Region

[ImaJayhawk]

If I've got a selection set of LWPolylines and have converted them to vla-objects, what is a good way to change the LWPolylines into Regions.

Code: [Select]


(foreach bos ss
    (if (= "AcDbPolyline" (vlax-get-property bos 'objectname))
..........

Thanks.


--ImaJayhawk

[Jeff_M]

I'm guessing that "ss" is not a selection set but rather a list of vla-objects....
If so, this should do it:

Code: [Select]


(foreach bos ss
  ;; assumes that "space" is set to the vla-object of the space that the plines are in
  ;; eg: (setq space (vla-get-modelspace *doc*))

  (setq new-region (vlax-invoke space "addregion" (list bos)))
  ;; do whatever you want with this region..layer, color, etc.
);next


[SMadsen]

Just cooked up the example below while Jeff replied and didn't want it to go to vaste.

It's worth noticing, though, that VLAX-INVOKE works with most native AutoLISP data types - such as the list in Jeff's example - while VLAX-INVOKE-METHOD and the VLA-xxx functions don't. Hence the safearray below.

Code: [Select]

(defun pl2reg (/ ss a obj objarray ms)
  (vl-load-com)
  (cond ((setq ss (ssget '((0 . "LWPOLYLINE"))))
         (setq a        0
               objarray (vlax-make-safearray vlax-vbObject '(0 . 0))
               ms       (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
         )
         (repeat (sslength ss)
           (setq obj (vlax-ename->vla-object (ssname ss a))
                 a   (1+ a))
           (vlax-safearray-fill objarray (list obj))
           (vla-addregion ms objarray)
         )
        )
  )
)

[ImaJayhawk]

Thanks that's what I needed.  Although I had to read the example using safearrays several times....




--ImaJayhawk

[Jeff_M]

... had to read the example using safearrays several times....

Which is why I avoid them as much as possible by using vlax-get, vlax-put & vlax-invoke. There are a few methods/properties I've found that don't work properly this way, but they are so few that I usually don't remember which ones until I try to use it.