Topic: How to Create a Dialog Box

[bmossman]

Can someone steer me in the right direction on creating a dialog box with check boxes that run script files?

[CAB]

By Script Files, do you mean other lisp routines?

I would think you would want buttons for each routine. But do you want to check several & have then run concurrently?

More explanation is needed. Can you describe the process you want the user to do & what the dialog box is to do for the user?

[bmossman]

By Script Files, do you mean other lisp routines?

I would think you would want buttons for each routine. But do you want to check several & have then run concurrently?

More explanation is needed. Can you describe the process you want the user to do & what the dialog box is to do for the user?

I have a series of script files that manipulate layering to achieve a certain plan. I would like for a user to  bring up the dialog box and have the option to check multiple plan options that would call the corresponding script commands. See below:

[X]     Site Plan
[  ]     Landscape Plan
[X]     Utility Plan

[CAB]

Here's a quick example of how to set up the lisp & dcl file.
Download the dcl into a folder in the ACAD search path.
Then load & run the lisp.
You will need to fill in what script action is needed.

Code: [Select]

(defun c:LayerSetUp(/ dclfile dcl# action layers2load)
  (vl-load-com)
  (defun get_checks(/ result)
    (if (= (get_tile "ck1") "1")
      (setq result (cons "Site Plan" result))
    )
    (if (= (get_tile "ck2") "1")
      (setq result (cons "Landscape Plan" result))
    )
    (if (= (get_tile "ck3") "1")
      (setq result (cons "Utility Plan" result))
    )
    result
  )
  ;;================================================================
  ;;                    Start of Routine                           
  ;;================================================================
  (setq dclfile "LayersSetUp.dcl")
  (cond
    ((< (setq dcl# (load_dialog dclfile)) 0) (prompt (strcat "\nCannot load " dclfile ".")))
    ((not (new_dialog "layersetup" dcl#)) (prompt (strcat "\nProblem with " dclfile ".")))
    (t ; No DCL problems: fire it up
      ;;  set actions
      (action_tile "accept" ; DCL OK exit action
                   "(setq layers2load (get_checks)) (done_dialog 1)")
       (setq action (start_dialog))
       (unload_dialog dcl#)
       (if (= action 1) ; OK was pressed
         (progn
           (print "OK was pressed")
           ;;  do you scripr files here
           ;; layers2load = a list of checked items
         )
         (print "User Quit.")
       )
    )
  ) ; end cond
  (princ)
)
(prompt "\nLayer Setup loaded, enter LayerSetUp to run.")
(princ)

[Patrick_35]

Hi

You have this great site

@+

[jbuzbee]

This one is better:

http://www.opendcl.com

http://sourceforge.net/projects/opendcl/

[bmossman]

Here's a quick example of how to set up the lisp & dcl file.
Download the dcl into a folder in the ACAD search path.
Then load & run the lisp.
You will need to fill in what script action is needed.

Code: [Select]

(defun c:LayerSetUp(/ dclfile dcl# action layers2load)
  (vl-load-com)
  (defun get_checks(/ result)
    (if (= (get_tile "ck1") "1")
      (setq result (cons "Site Plan" result))
    )
    (if (= (get_tile "ck2") "1")
      (setq result (cons "Landscape Plan" result))
    )
    (if (= (get_tile "ck3") "1")
      (setq result (cons "Utility Plan" result))
    )
    result
  )
  ;;================================================================
  ;;                    Start of Routine                           
  ;;================================================================
  (setq dclfile "LayersSetUp.dcl")
  (cond
    ((< (setq dcl# (load_dialog dclfile)) 0) (prompt (strcat "\nCannot load " dclfile ".")))
    ((not (new_dialog "layersetup" dcl#)) (prompt (strcat "\nProblem with " dclfile ".")))
    (t ; No DCL problems: fire it up
      ;;  set actions
      (action_tile "accept" ; DCL OK exit action
                   "(setq layers2load (get_checks)) (done_dialog 1)")
       (setq action (start_dialog))
       (unload_dialog dcl#)
       (if (= action 1) ; OK was pressed
         (progn
           (print "OK was pressed")
           ;;  do you scripr files here
           ;; layers2load = a list of checked items
         )
         (print "User Quit.")
       )
    )
  ) ; end cond
  (princ)
)
(prompt "\nLayer Setup loaded, enter LayerSetUp to run.")
(princ)

Thanks Cab...That worked beautifully

[bmossman]

How do you call a script file from within lisp?

[CAB]

If you are talking about another lisp you use
(my-lisp-name) when the lisp starts like this (defun my-lisp-name
or this
(c:my-lisp-name) when the lisp starts like this (defun c:my-lisp-name

[bmossman]

It's actually a command. Don't I have to call the command function similar to this:

(command "script" "script file name here")

[Alan Cullen]

(sorry CAB...about time I joined in here...hope you don't mind)

For invocing a script file...which is a series of commands, then you must issue each command as you would issue a command from within lisp. In other words you have a lisp within a lisp, but not as the same stucture you would use as a script file......

Use this format for each command.....

(command "CHANGE" sspipe "" "P" "C" pen12 "")
(command "chprop" "L" "" "C" ptc "LA" ptlay "" )
(command "COPY" name "" p1 p6)
(command "ELLIPSE" p1 p2 p3)
(command "ERASE" sstxt "")

call it whatever...but comply with CAB's advise...and call it in as CAB suggested.

A script ceases to be a script if you want to invoke it from within a lisp routine.

I really hope that makes sense.........

[bmossman]

Ok, I inserted the the command to call the script files, but how do i associate the script file to the corresponding function in the dialog box?

ie, line 5 corresponds to line 33
and line 6 corresponds to line 34

(defun c:LayerSetUp(/ dclfile dcl# action layers2load)
  (vl-load-com)
  (defun get_checks(/ result)
    (if (= (get_tile "ck1") "1")
      (setq result (cons "Site Plan" result))
    )
    (if (= (get_tile "ck2") "1")
      (setq result (cons "GEOMETRY Plan" result))
    )
    (if (= (get_tile "ck3") "1")
      (setq result (cons "Utility Plan" result))
    )
    result
  )
  ;;================================================================
  ;;                    Start of Routine                           
  ;;================================================================
  (setq dclfile "LayersSetUp.dcl")
  (cond
    ((< (setq dcl# (load_dialog dclfile)) 0) (prompt (strcat "\nCannot load " dclfile ".")))
    ((not (new_dialog "layersetup" dcl#)) (prompt (strcat "\nProblem with " dclfile ".")))
    (t ; No DCL problems: fire it up
      ;;  set actions
      (action_tile "accept" ; DCL OK exit action
                   "(setq layers2load (get_checks)) (done_dialog 1)")
       (setq action (start_dialog))
       (unload_dialog dcl#)
       (if (= action 1) ; OK was pressed
         (progn
           (print "OK was pressed")
      (command "script" "M:/Resources/Acad/Scripts/S-SITE.scr")
      (command "script" "M:/Resources/Acad/Scripts/S-GEOM.scr")
          ;;  do you scripr files here
           ;; layers2load = a list of checked items
         )
         (print "User Quit.")
       )
    )
  ) ; end cond
  (princ)
)
(prompt "\nLayer Setup loaded, enter LayerSetUp to run.")
(princ)

[CAB]

Alan, thank you for juping in.

I already typed this so here are my comments:

Usually you would supply the COMMAND with the same information you type at the
ACAD Command Line. Like this:

Code: [Select]

Command: zoom                                                 
                                                             
Specify corner of window, enter a scale factor (nX or nXP), or
[All/Center/Dynamic/Extents/Previous/Scale/Window] <real time>: e        
So the lisp code would look like this:

Code: [Select]

(command "zoom" "e")
You may use Lisp variables to supply arguments to the commands.
Using the ACAD LINE command you might want to have the Lisp supply the points
needed to draw the line. Something like this:

Code: [Select]

(setq pt1 '(0 0))
(setq pt2 '(10 20))
(command "line" pt1 pt2 "")Note that the "" is the same as pressing the ENTER key when you are entering
information at the command line.

Alan feel free to continue, please.

[CAB]

Perhaps this will do what you want.
Note that there are many ways to set this up and this is only one example:

Code: [Select]

(defun c:LayerSetUp(/ dclfile dcl# action layers2load)
  (vl-load-com)
  (defun get_checks(/ result)
    (if (= (get_tile "ck1") "1")
      (setq result (cons "Site Plan" result))
    )
    (if (= (get_tile "ck2") "1")
      (setq result (cons "Landscape Plan" result))
    )
    (if (= (get_tile "ck3") "1")
      (setq result (cons "Utility Plan" result))
    )
    result
  )
  ;;================================================================
  ;;                    Start of Routine                           
  ;;================================================================
  (setq dclfile "LayersSetUp.dcl")
  (cond
    ((< (setq dcl# (load_dialog dclfile)) 0) (prompt (strcat "\nCannot load " dclfile ".")))
    ((not (new_dialog "layersetup" dcl#)) (prompt (strcat "\nProblem with " dclfile ".")))
    (t ; No DCL problems: fire it up
      ;;  set actions
      (action_tile "accept" ; DCL OK exit action
                   "(setq layers2load (get_checks)) (done_dialog 1)")
       (setq action (start_dialog))
       (unload_dialog dcl#)
       (if (= action 1) ; OK was pressed
         (progn
           (print "OK was pressed")
           ;;  do you scripr files here
           ;; layers2load = a list of checked items
           (if (member "Site Plan" layers2load)
             (command "script" "M:/Resources/Acad/Scripts/S-SITE.scr")
           )
           (if (member "Landscape Plan" layers2load)
             (command "script" "M:/Resources/Acad/Scripts/S-GEOM.scr")
           )
           (if (member "Utility Plan" layers2load)
             (princ)
           )
         )
         (print "User Quit.")
       )
    )
  ) ; end cond
  (princ)
)
(prompt "\nLayer Setup loaded, enter LayerSetUp to run.")
(princ)

[Alan Cullen]

Yup...thanks CAB...I reckon you nailed it

I just thought it was time I earnt my place here...so I will try to help with lisp where I can. I'm still trying to come to grips with the level of knowledge that exists here with regard to lisp.

[Alan Cullen]

bmossman,

Care to chuck up the script file that you are trying to call in? We will have a look at it and see if it needs any modification. 

[CAB]

All help is welcome
Thanks
CAB

[bmossman]

Here are a few of them...
Thank you all for your help!

bmossman,

Care to chuck up the script file that you are trying to call in? We will have a look at it and see if it needs any modification. 

[Alan Cullen]

oops...didn't help...it was coded.....can you shoot me the ascii format?

[bmossman]

oops...didn't help...it was coded.....can you shoot me the ascii format?

Is there a way to convert to Ascii in notepad?

[Alan Cullen]

Doesn't matter....just me being stupid and not looking properly. I opened the zip file in the text editor...that's why it was coded. 

Yup, your script files need to be re-written so they'll work in a lisp routine. Change this.......

-layer
off
*
Y
on
0,*|0,*DEFPOINTS,*A-COMN-*,*S-COMN-*,*S-GEOM-*
ON
*FEMA*,*PROPERTY*,*LANDLINE*,*WETLAND*,*SAFE*UPLAND*
OFF
*D-*TAG*
S
0
C 1 *MAIN*FH*
C 252 *D-*P-*POND*TOB*

To something like this.....

(command "LAYER" "off" "*" "Y" "on" "0,*|0,*DEFPOINTS,*A-COMN" .....ETC, ETC "")

[bmossman]

Doesn't matter....just me being stupid and not looking properly. I opened the zip file in the text editor...that's why it was coded. 

Yup, your script files need to be re-written so they'll work in a lisp routine. Change this.......

-layer
off
*
Y
on
0,*|0,*DEFPOINTS,*A-COMN-*,*S-COMN-*,*S-GEOM-*
ON
*FEMA*,*PROPERTY*,*LANDLINE*,*WETLAND*,*SAFE*UPLAND*
OFF
*D-*TAG*
S
0
C 1 *MAIN*FH*
C 252 *D-*P-*POND*TOB*

To something like this.....

(command "LAYER" "off" "*" "Y" "on" "0,*|0,*DEFPOINTS,*A-COMN" .....ETC, ETC "")

I got the dialog to work with the external script files, however when calling the dialog I can't select multiple script files without it saying

"Command: --layer
Unknown command "--LAYER".  Press F1 for help."

For some reason when selecting multiple script files it's attempting to execute the layer command again . (see attachments)

[CAB]

Code: [Select]

"Command: [color=red]--[/color]layer
Unknown command "--LAYER".  Press F1 for help."
This is a typo error. There must be only one minus sign in front of Layer.

[bmossman]

Code: [Select]

"Command: [color=red]--[/color]layer
Unknown command "--LAYER".  Press F1 for help."
This is a typo error. There must be only one minus sign in front of Layer.

That's what I thought, but each script file calls the layer command like this:

-Layer

[jbuzbee]

bmossman,

looks like your making "layer states" on the fly?  what exactly do these scripts do that you can't do with layer states??

[CAB]

Your script files contain extra empty lines at the end and some have  TAB character.
I believe that something is causing the script file to issue an extra ENTER which attempts to execute the last command which is LAYER.

[CAB]

Try these revised script files. I eliminated any extra characters at the end.

[bmossman]

Try these revised script files. I eliminated any extra characters at the end.

It needs the two spaces at the end to complete the layer command.

[bmossman]

bmossman,

looks like your making "layer states" on the fly?  what exactly do these scripts do that you can't do with layer states??

I'm old school and have been using scripts for layering since the stone age.
The advantage to using the scripts is it allows the user some flexibility when creating layers on the fly...the scripts will turn on all appropriate layers as long as they have an appropriate prefix.

It's a pain in Layer States manager to continuously update when a new layer is added.



 

[jbuzbee]

It's a pain in Layer States manager to continuously update when a new layer is added.

Yes it is.

We have pretty nazi-like standards around here so we try not to change to much stuff.  We use a program that was written in-house that uses the Projects Standards DWS file as a "database" for all our approved layers and layer states.

[bmossman]

Ended up adding the commands to the lisp routine in lieu of calling the script files as Allan suggested and it works fine now. Thanks you all for your help!

Code: [Select]

;;==========================================================
           (if (member "Site Plan" layers2load)
             (command "-layer"
"on" "0,*|0,*DEFPOINTS,*A-COMN-*,*S-COMN-*,*S-SITE-*,*P-*TOB*,*MAIN*FH*
*FEMA*,*PROPERTY*,*LANDLINE*,*WETLAND*,*SAFE*UPLAND*"
"C" "1" "*MAIN*FH*"
"C" "252" "*D-*P-*POND*TOB*"
"C" "81" "*S-SITE*P-*TREE* LW 0.50 *S-*P-*TREE*"
"C" "74" "*S-SITE*P-*SHRUB* LW 0.35 *S-*P-*SHRUB*"
"")
   )

[CAB]

Here is another version to try:

Code: [Select]

(defun c:CP(/ dclfile dcl# action layers2load ScrLst MaxChecks)
  (vl-load-com)
 
  ;;  Start with all layers off
  ;(command "-layer" "off" "*" "y" "")
  (command "-layer" "off" "*" "" "")
 
  ;;  Get the check box reference if checked
  (defun get_checks(ckMax / idx sList result)
    ;; Order must match check boxes
    (setq sList '("Site Plan"
                  "Geometry Plan" 
                  "Landscape Plan"   
                  "Water Plan" 
                  "Sanitary Sewer Plan" 
                  "Reuse Water Plan" 
                  "Lift Station Site Plan" 
                  "All Utilities On" 
                  "Mass Grading Plan" 
                  "Predevelopment Plan" 
                  "Surface Water Mgmt Plan" 
                  "Detailed Drainage Plan" 
                  "Roadway Profiles" 
                  "Roadway Details" 
                  "Roadway Sections" 
                 ))
    (setq idx 1) ; 1 through ckMax
    (While (and (<= (setq idx (1+ idx)) ckMax)
           (<= idx (length sList)))
      (if (= (get_tile (strcat "ck" (itoa idx))) "1")
        (setq result (cons (nth (1- idx) sList) result))
      )
    )
    result
  )
  ;;================================================================
  ;;                    Start of Routine                           
  ;;================================================================
  (setq dclfile "ChangePlan.dcl")
  (setq MaxChecks 15) ; check boxes 1-15  <---<< update this number
  (cond
    ((< (setq dcl# (load_dialog dclfile)) 0) (prompt (strcat "\nCannot load " dclfile ".")))
    ((not (new_dialog "ChangePlan" dcl#)) (prompt (strcat "\nProblem with " dclfile ".")))
    (t ; No DCL problems: fire it up
      ;;  set actions
      (action_tile "accept" ; DCL OK exit action
                   "(setq layers2load (get_checks MaxChecks)) (done_dialog 1)")
      (setq action (start_dialog))
      (unload_dialog dcl#)
      (if (= action 1) ; OK was pressed
        (progn
          (print "OK was pressed")
          ;;  do you scripr files here
          (setq path "M:/Resources/Acad/Scripts/Beta/")
          ;;  This list order does not matter, Case must match
          (setq ScrLst '(("Site Plan"               "S-SITE.scr")
                         ("Geometry Plan"           "Geometry Plan"); <===<< error
                         ("Landscape Plan"          "S-LAND.scr")
                         ("Water Plan"              "u-wat.scr")
                         ("Lift Station Site Plan"  "u-ssls.scr")
                         ("All Utilities On"        "u-allon.scr")
                         ("Mass Grading Plan"       "d-grad.scr")
                         ("Predevelopment Plan"     "d-pred.scr")
                         ("Surface Water Mgmt Plan" "d-swm.scr")
                         ("Detailed Drainage Plan"  "d-dra.scr")
                         ("Roadway Profiles"        "r-prof.scr")
                         ("Roadway Details"         "r-detl.scr")
                         ("Roadway Sections"        "r-sect.scr")
                        ))
          (foreach itm layers2load
            (if (setq scr (cadr (assoc itm ScrLst)))
              (if (vl-catch-all-error-p
                    (setq err (vl-catch-all-apply
                                '(lambda() (command "script" (strcat path scr))))))
                (alert (vl-catch-all-error-message err))
                (princ (strcat "\nLayers set for " itm))
              )
              (princ (strcat "\nNot Found - " itm))
            )
          )

           (princ)
        )
        (print "User Quit.")
      )
    )
  ) ; end cond
  (princ)
)
(prompt "\nLayer Setup loaded, enter CP to run.")
(princ)

[bmossman]

your latest code works when I select just one script file at a time, but when i select multiple ones it seems to terminate subsequent of turning off all layers.

[CAB]

I'm still kicking this around. I'll let you know what I come up with.

[CAB]

Yet another version.
Rather than call the Script File, this version reads the script file & attempts to execute each
item in the script as a command.

Code: [Select]

;;  CAB 07/30/2008 Version 1.3
;;  Dialog Box for layer setups
;;  Reads a Script file & executes each item as a COMMAND

(defun c:CP(/ dclfile dcl# action layers2load ScrLst err path scr
            lst nlst File2list sparser)
  (vl-load-com)
 
  ;;  TxtFile2List by CAB
  (defun File2list (filename / handle stream FileData)
    (if
      (and
        (eq 'str (type filename))
        (setq filename (findfile filename))
        (setq handle (open filename "r"))
      )
       (progn
         (while (setq stream (read-line handle))
                  (setq  FileData (cons stream FileData))
         ) ; while
         (close handle)
       ) ; progn
    ) ; endif
    (reverse FileData)
  )
 
  ;;  CAB 10.22.2007
  ;;  ignore quoted sections of the string
  (defun sparser (str delim / ok c new$ plst)
    (setq ok t
          new$ ""
    )
    (while (/= str "")
      (setq c   (substr str 1 1)
            str (substr str 2))
      (cond
        ((= c "\"")
         (setq new$ (strcat new$ c)
               ok (null ok)))
        ((and ok (= c delim))
         (setq plst   (cons new$ plst)
               new$ ""))
        ((setq new$ (strcat new$ c)))
      )
    )
    (reverse (cons new$ plst))
  )
 
  ;;  Start with all layers off
  ;(command "-layer" "off" "*" "y" "")
  (command "-layer" "off" "*" "" "")
 
  ;;  Get the check box reference if checked
  (defun get_checks(/ idx sList result ckMax)
    ;; Order must match check boxes
    (setq sList '("Site Plan"
                  "Geometry Plan" 
                  "Landscape Plan"   
                  "Water Plan" 
                  "Sanitary Sewer Plan" 
                  "Reuse Water Plan" 
                  "Lift Station Site Plan" 
                  "All Utilities On" 
                  "Mass Grading Plan" 
                  "Predevelopment Plan" 
                  "Surface Water Mgmt Plan" 
                  "Detailed Drainage Plan" 
                  "Roadway Profiles" 
                  "Roadway Details" 
                  "Roadway Sections" 
                 ))
    (setq ckMax (length sList))
    (setq idx 0) ; 1 through ckMax
    (While (and (<= (setq idx (1+ idx)) ckMax)
           (<= idx (length sList)))
      (if (= (get_tile (strcat "ck" (itoa idx))) "1")
        (setq result (cons (nth (1- idx) sList) result))
      )
    )
    result
  )
  ;;================================================================
  ;;                    Start of Routine                           
  ;;================================================================
  (setq dclfile "ChangePlan.dcl")
  (cond
    ((< (setq dcl# (load_dialog dclfile)) 0) (prompt (strcat "\nCannot load " dclfile ".")))
    ((not (new_dialog "ChangePlan" dcl#)) (prompt (strcat "\nProblem with " dclfile ".")))
    (t ; No DCL problems: fire it up
      ;;  set actions
      (action_tile "accept" ; DCL OK exit action
                   "(setq layers2load (get_checks)) (done_dialog 1)")
      (setq action (start_dialog))
      (unload_dialog dcl#)
      (if (= action 1) ; OK was pressed
        (progn
          (print "OK was pressed")
          ;;  do you scripr files here
          ;(setq path "M:/Resources/Acad/Scripts/Beta/")
          (setq path "C:/Program Files/ACAD2000/LISP Routines/SubRoutines/temp/")
          ;;  This list order does not matter, Case must match
          (setq ScrLst '(("Site Plan"               "S-SITE.scr")
                         ("Geometry Plan"           "Geometry Plan"); <===<< error
                         ("Landscape Plan"          "S-LAND.scr")
                         ("Water Plan"              "u-wat.scr")
                         ("Lift Station Site Plan"  "u-ssls.scr")
                         ("All Utilities On"        "u-allon.scr")
                         ("Mass Grading Plan"       "d-grad.scr")
                         ("Predevelopment Plan"     "d-pred.scr")
                         ("Surface Water Mgmt Plan" "d-swm.scr")
                         ("Detailed Drainage Plan"  "d-dra.scr")
                         ("Roadway Profiles"        "r-prof.scr")
                         ("Roadway Details"         "r-detl.scr")
                         ("Roadway Sections"        "r-sect.scr")
                        ))
          (foreach itm layers2load
            (if (setq scr (cadr (assoc itm ScrLst)))
              (progn
                (setq lst (File2list (strcat path scr))) ; read the script file
                ;; create a list of command entries as a list of strings
                ;; uses space as a delimiter except within quotes and will
                ;; ignore comment lines in the script
                (mapcar '(lambda(x) (cond
                                      ((= (substr x 1 1) "(") ; LISP in this line
                                       (if nLst
                                         (setq nlst (append nlst (list (read x))))
                                         (setq nlst (list (read x)))
                                       )
                                      )
                                      ((/= (substr x 1 1) ";") ; ignore comment line
                                      (if nlst
                                        (setq nlst (append nlst (sparser x " ")))
                                        (setq nlst (sparser x " "))
                                    )))) lst)
                ;; Execute each command entry from the script file
                (if (vl-catch-all-error-p
                      (setq err (vl-catch-all-apply
                                  '(lambda()
                                     (foreach ln nlst
                                       (if (listp ln)
                                         (eval ln)
                                         (command ln)
                                       )
                                     )
                                     ;;(command) ; make sure command is terminated
                                     ))))
                (alert (vl-catch-all-error-message err))
                (princ (strcat "\nLayers set for " itm))
              )
              )
              (princ (strcat "\nNot Found - " itm))
            )
          )
          (princ)
        ) ; progn
        (print "User Quit.")
      )
    )
  ) ; end cond
  (princ)
)
(prompt "\nLayer Setup loaded, enter CP to run.")
(princ)
<edit: fixed typo>

[CAB]

I did find this in the help file:

If the SCRIPT command is used with the command function, it should be the last function call in the AutoLISP routine.

So that may be the reason you can not run more than one script from within a lisp.

[bmossman]

Thanks for your help CAB
How do you format the dcl file to include tabs, borders, etc...
Is there a program that will allow you to graphically build the dialog box? 

[jbuzbee]

Is there a program that will allow you to graphically build the dialog box?

http://sourceforge.net/projects/opendcl/

http://www.opendcl.com/

and to get you started:

http://www.theswamp.org/index.php?topic=24215.0

http://www.theswamp.org/index.php?topic=24217.0

[CAB]

Thanks for your help CAB
How do you format the dcl file to include tabs, borders, etc...
Is there a program that will allow you to graphically build the dialog box? 

You're welcome.

With DCL it is trial and error.
Open the DCL in VLIDE & use the pull down Tools/Interface Tools/Preview DCL in Editor
Note that you must save any changes before you can view them.

[CAB]

Here is a simple change

Code: [Select]

ChangePlan : dialog { label = "  Drawing Layer Setup" ;
: boxed_row { label = "Check all that apply" ;
 : column {
  : toggle { key = "ck1" ; label = "S-Site Plan" ;}
  : toggle { key = "ck2" ; label = "S-Geometry Plan" ;}
  : toggle { key = "ck3" ; label = "S-Landscape Plan" ;}
  : toggle { key = "ck4" ; label = "U-Water Plan" ;}
  : toggle { key = "ck5" ; label = "U-Sanitary Sewer Plan" ;}
  : toggle { key = "ck6" ; label = "U-Reuse Water Plan" ;}
  : toggle { key = "ck7" ; label = "U-Lift Station Site Plan" ;}
  : toggle { key = "ck8" ; label = "U-All Utilities On" ;}
 }
 : column {
  : toggle { key = "ck9" ; label = "D-Mass Grading Plan" ;}
  : toggle { key = "ck10" ; label = "D-Predevelopment Plan" ;}
  : toggle { key = "ck11" ; label = "D-Surface Water Mgmt Plan" ;}
  : toggle { key = "ck12" ; label = "D-Detailed Drainage Plan" ;}
  : toggle { key = "ck13" ; label = "R-Roadway Profiles" ;}
  : toggle { key = "ck14" ; label = "R-Roadway Details" ;}
  : toggle { key = "ck15" ; label = "R-Roadway Sections" ;}
  spacer_1;
 }
}
ok_cancel;
}   

[CAB]

This is the result.