Topic: Fraction equivalent chart

[ELOQUINTET]

Hey guys,

I am looking for a fraction equivalent chart but let me explain this in detail. Our Dimension style Precision and Roundoff are set to 1/32 but our unit Precision is set to 1/256.

I am having to take drawings sent to us from our vendors and make them buildable. which means that none of the dimensions should read less than a 1/16".

I was plugging along and came across a situation where The overall was 9" and all of the interior dimensions were adding up except one which was 1/32 off. I went in and measured the model and discovered that the model was all screwed up and this was causing the descepency.

What I have done now is created a dimension style with it's precision set to 1/256 and roundoff set to zero which I will use to check the model's correctness.

The problem I am having is that sometimes the dimension will read in /256ths and other times in /64ths and sometimes in /128ths and so on.

So I guess what I would need is some sort of routine or chart which would show me 1/16ths on one side and ranges of the equivalents in the other fractions on the other side so I know how far I need to stretch the model to fix it.

Does this make sense?

[M-dub]

For what it's worth... Here's a little chart I made in Excel years ago...

[ELOQUINTET]

Thanks MDub but that's not exactly what I'm after. What I am looking for is all fractions. In other words, I need a range of say 113-?/256 = 7/16. Does that make sense?

[daron]

Perfect world meet imperfect world.



Sorry, couldn't be much more help. I absolutely hate fractions and that people expect perfection when it isn't feasible.

[M-dub]

I can't tell exactly what it is you're after Dan, but if it is what I think it is, Excel is likely your best bet for creating something like this.

Again, don't know exactly what you're looking for.

[ELOQUINTET]

Mike,

I created a sample drawing to illustrate what I'm trying to say but how do I get to the pond again to upload it?

[David Hall]

what about using the decimal equivalent and doing ranges = ?/16  like 0.000001 -> 0.625=1/16

[David Hall]

I snaged this from Cadalyst tips to do roundoff, maybe it will help

Code: [Select]

(defun tepRNDoff (x y)
  (* (fix (/ (+ x (/ y 2.0)) y)) y)
)X is the number, and Y is the part you want to round off to.  It always rounds down from what I can see

[Josh Nieman]

Mike,

I created a sample drawing to illustrate what I'm trying to say but how do I get to the pond again to upload it?

You can attach it to your post.

Just below-and-to-the-left of the text box where you type your reply is a blue text toggle that says "Additional Options"

Expand that and wah-lah.

[ELOQUINTET]

wow that is sweet. is that new functionality in the swamp or am i just a retard, wait don't answer that. i'd always thought i had to upload it to the pond the paste the link then do cartwheels  thanks for the tip

[T.Willey]

Maybe this will work for you.

Code: [Select]

(defun c:Test (/ MinDist MaxDist tempDist)
   
    (if
        (and
            (setq MinDist (getdist "\n Enter starting distance: "))
            (setq MaxDist (getdist "\n Enter ending distance: "))
            (setq tempDist MinDist)
            (not
                (prompt
                    (strcat
                        "\n"
                        (rtos MinDist 4 16)
                        " [ "
                        (vl-string-trim "0" (rtos MinDist 2 16))
                        " ]"
                    )
                )
            )
        )
        (while (< tempDist MaxDist)
            (setq tempDist (+ (/ 1. 256) tempDist))
            (prompt
                (strcat
                    "\n"
                    (rtos tempDist 4 16)
                    " [ "
                    (vl-string-trim "0" (rtos tempDist 2 16))
                    " ]"
                )
            )
        )
    )
    (princ)
)
Returned

Command: test

 Enter starting distance: 3/8

 Enter ending distance: 7/16

3/8" [ .375 ]
97/256" [ .37890625 ]
49/128" [ .3828125 ]
99/256" [ .38671875 ]
25/64" [ .390625 ]
101/256" [ .39453125 ]
51/128" [ .3984375 ]
103/256" [ .40234375 ]
13/32" [ .40625 ]
105/256" [ .41015625 ]
53/128" [ .4140625 ]
107/256" [ .41796875 ]
27/64" [ .421875 ]
109/256" [ .42578125 ]
55/128" [ .4296875 ]
111/256" [ .43359375 ]
7/16" [ .4375 ]

[ELOQUINTET]

thanks tim i will give it a try tomorrow. what i'm ultimately looking for is a way to figure out which 1/16" dimensions the actual dimension falls between and give me the distance i would need to adjust it to correct it. Whether I round up or down will depend on which is a nice round number. For instance I would round it up to 1/4" even if it was closer to 3/16". If there was a way I could select the amount I wanted from a dialogue and it would issue the stretch command and plug that number in as the distance that would be the ultimate solution. If I have to copy and paste the results that would still be better than nothing. Thanks for your help everyone.

[TimSpangler]

Here is what I use.  I type VF at the cmd and it shows the slide full screen.  It only goes down to /64 but I have also include the .dwg so if you feel the need you can add the rest to it.  I think it came from here (theswamp)  dont remeber exactly.  Pretty simple


[Edit] I did a search on the swamp and found this post, but I know it wasn't this one. (maybe adesk forums)  Anywho it looks like it may have come from the same author so in any case I'll give creadit to him http://www.theswamp.org/index.php?topic=1536.0

[Rob...]

Eloquintet,

Just a little advice. To be truly accurate, try this approach. Instead of using the difference of the actual length and the target length, use the full length that you need. What you are describing will only lessen the problem that your are trying to fix. Your source measurements are still rounded off, albeit a very small number. Given enough continuous dimensions you will end up with the same problem you started with. The sum of the parts will be different than the whole.

[ELOQUINTET]

Tim that's a cool chart but this is not really what i am looking for. I think I explained what I need in my last post pretty clearly. Also take a look at the drawing I attached. Rob I guess you're right that my dimensions are still being rounded off but this distance is so small and would not be distinguishable from either our distance command or dimensions so I don't see the descrepancy showing up in our drawings. This is the best I can do without redrawing the whole thing which I cannot do. Do you have any other ideas of how I can make it perfect without redrawing. I'm open to suggestions.

[T.Willey]

See if this is what you are looking for.

Code: [Select]

(defun c:Test (/ Sel DimEntData DimDist tempStr LowDist HighDist DistOpt Ang)
   
    (defun FindNextSixteenth (StValue GoHigher)
        (while
            (not
                (equal
                    (rem
                        (setq StValue
                            (
                                (eval (if GoHigher + -))
                                StValue
                                (/ 1. 256)
                            )
                        )
                        (/ 1. 16)
                    )
                    0.0
                )
            )
        )
        StValue
    )
    ;--------------------------------------------------------
    (if
        (and
            (setq Sel (entsel "\n Select dimension: "))
            (setq DimEntData (entget (car Sel)))
            (= (cdr (assoc 0 DimEntData)) "DIMENSION")
            (setq DimDist
                (if (= (setq tempStr (cdr (assoc 1 DimEntData))) "")
                    (cdr (assoc 42 DimEntData))
                    (distof tempStr)
                )
            )
            (setq LowDist (FindNextSixteenth DimDist nil))
            (setq HighDist (FindNextSixteenth DimDist T))
            (not (initget "High Low"))
            (setq DistOpt
                (cond
                   (
                        (getkword
                            (strcat "\n Which way to go [High/Low] from "
                                (rtos DimDist 4 16)
                                " (High = "
                                (rtos HighDist 4 4)
                                ", Low = "
                                (rtos LowDist 4 4)
                                "): "
                            )
                        )
                    )
                    (T nil)
                )
            )
            (setq Ang (getangle "\n Enter angle to stretch at: "))
        )
        (command
            "_.stretch"
            (ssget)
            ""
            '(0. 0. 0.)
            (strcat
                "@"
                (rtos
                    (abs
                        (-
                            (if (= DistOpt "High")
                                HighDist
                                LowDist
                            )
                            DimDist
                        )
                    )
                    2
                    16
                )
                "<"
                (angtos Ang 2 16)
            )
        )
    )
    (princ)
)


[Kate M]

Dan, when I run into those situations I use object snap tracking, rather than a straight move/stretch.

Because you realize that you're still limited to 1/256 precision, right? I ran into something the other day with dimensions of 300.0099999 -- doesn't get caught by fractions, but was still off enough to prevent me from trimming properly.

[t-bear]

I have had the same problem Kate...it's a real pain with 3D objects!  We draft to 8 decimal points here in an attempt to control that.

Back on topic...I think what Dan is looking for is a chart that gives him the 8 digit equivelant of all 256 divisions of an inch.  Autocad will give you  13/32" which is actually 104/256".  He's hunting a chart in all/256"....right, Dan?  He wants to be able to stretch/move/whatever in 256ths of an inch....

Of course, I've been wrong before.....once....no, twice....LOL

[ELOQUINTET]

yeeeeeah baby tim you pretty much nailed it buddy. The only thing I was thinking about is could the angle be built in and there be 2 routines, one for stretching horizontally and another for stretching vertically? These would be the only 2 angles I would be stretching, I think.

[T.Willey]

yeeeeeah baby tim you pretty much nailed it buddy. The only thing I was thinking about is could the angle be built in and there be 2 routines, one for stretching horizontally and another for stretching vertically? These would be the only 2 angles I would be stretching, I think.

Yes it could be changed to do that, but I can't get to it right now, w**k.  If you issue it by two commands, then getting the angle to stretch is easier.  All you would have to do is see which value is large for dxf codes 10 (start point) and 13 (end point), because if you are stretching it lower, then it will move them closer, so you know the angles.

[ELOQUINTET]

hmmm strange. The routine worked fine when i tried it out but now when i run it i get to select dimension and when i select the dimension it totally freezes up my pc. i haven't been able to get it to do anything now. i'm trying to figure out what is going on here???

[M-dub]

Back on topic...I think what Dan is looking for is a chart that gives him the 8 digit equivelant of all 256 divisions of an inch.  Autocad will give you  13/32" which is actually 104/256".  He's hunting a chart in all/256"....right, Dan?  He wants to be able to stretch/move/whatever in 256ths of an inch....

If that's the case, (maybe it is, maybe it isn't) I made this in about 2 minutes.

It's there for the taking, anyway.

[T.Willey]

hmmm strange. The routine worked fine when i tried it out but now when i run it i get to select dimension and when i select the dimension it totally freezes up my pc. i haven't been able to get it to do anything now. i'm trying to figure out what is going on here???

The only thing that I can think of is a situation that Kate described, as there is no point in the code which should freeze you comp.  I guess the code could check to make sure the first value given is divisible by 256, and if so proceed.  Did you try the esc button to exit the command?  I see no reason why that wouldn't work.

I was thinking that it wouldn't be easy to add in the angle part.  How would you know which way to stretch it?  You would have to get the points of the selection to see which way to stretch, which can be done, but I'm not sure how easy it would be to code.

[ELOQUINTET]

yes i can escape out of it tim. so you are saying it is probably trying to divide it by 256 and it cannot so it keeps trying and trying. the angle part is just a bonus but i asked as i'd thought we had it working. forget about the angle for now. mdub i'll look at your file and reply tomorrow as i'm about to leave. thanks guys

[T.Willey]

See if this gives any notice on the dimension you selected.  Now it will prompt you if the dimension selected is not divisible by 1/256.

Edit: Added the selection set to the and statement.

Code: [Select]

(defun c:Test (/ Sel DimEntData DimDist tempStr LowDist HighDist DistOpt Ang ss)
   
    (defun FindNextSixteenth (StValue GoHigher)
        (while
            (not
                (equal
                    (rem
                        (setq StValue
                            (
                                (eval (if GoHigher + -))
                                StValue
                                (/ 1. 256)
                            )
                        )
                        (/ 1. 16)
                    )
                    0.0
                )
            )
        )
        StValue
    )
    ;--------------------------------------------------------
    (if
        (and
            (setq Sel (entsel "\n Select dimension: "))
            (setq DimEntData (entget (car Sel)))
            (= (cdr (assoc 0 DimEntData)) "DIMENSION")
            (setq DimDist
                (if (= (setq tempStr (cdr (assoc 1 DimEntData))) "")
                    (cdr (assoc 42 DimEntData))
                    (distof tempStr)
                )
            )
            (equal (rem DimDist (/ 1. 256)) 0.0)
            (setq LowDist (FindNextSixteenth DimDist nil))
            (setq HighDist (FindNextSixteenth DimDist T))
            (not (initget "High Low"))
            (setq DistOpt
                (cond
                   (
                        (getkword
                            (strcat "\n Which way to go [High/Low] from "
                                (rtos DimDist 4 16)
                                " (High = "
                                (rtos HighDist 4 4)
                                ", Low = "
                                (rtos LowDist 4 4)
                                "): "
                            )
                        )
                    )
                    (T nil)
                )
            )
            (setq Ang (getangle "\n Enter angle to stretch at: "))
            (setq ss (ssget))
        )
        (command
            "_.stretch"
            ss
            ""
            '(0. 0. 0.)
            (strcat
                "@"
                (rtos
                    (abs
                        (-
                            (if (= DistOpt "High")
                                HighDist
                                LowDist
                            )
                            DimDist
                        )
                    )
                    2
                    16
                )
                "<"
                (angtos Ang 2 16)
            )
        )
        (cond
            ((not ss) (prompt "\n No entities selected to stretch."))
            (Ang (prompt "\n No angle selected."))
            (DistOpt (prompt "\n No angle selected."))
            (HighDist (prompt "\n No new dimension value selected."))
            (DimDist (prompt "\n Dimension value selected is not divisible by 1/256."))
            (DimEntData (prompt "\n Entity selected was not a dimension."))
            ((not Sel) (prompt "\n No entity selected."))
        )
    )
    (princ)
)


[ELOQUINTET]

mdub that is very useful but i am having situations where my fractions in my dimensions are reading in /128" and /64ths of an inch so I guess I need several charts. How did you produce this in 2 minutes :kewl:

[Josh Nieman]

mdub that is very useful but i am having situations where my fractions in my dimensions are reading in /128" and /64ths of an inch so I guess I need several charts. How did you produce this in 2 minutes :kewl:

Probably using Excel and it's loverly formatting.

[ELOQUINTET]

ummm care to elaborate i'm a bit of a novice when it comes to excel.

[ELOQUINTET]

you know i was thinking about this last night and some of the input about it still rounding and the model not being completely accurate got me to thinking. I have this routine for drawing reference lines (sorry I don't know who wrote it). I had been using it to offset to the correct distance then stretch the model and erase it after. Here's some psuedo code of what it might do:

you pick the dimension
it would return the range and ask if you want to go high or low
it would ask you to pick the origin point
it would get the offset distance based on the answer high or low
it will ask you to pick a side to offset
then it will start the stretch command
it would be a bonus if it erased the reference line after

incorporating the reference line is the only way i could think of that would insure that the distance is true.
does this make sense and is this doable?

Code: [Select]

;;; DRAWS A LINE THEN ASKS WHICH SIDE TO OFFSET AND DISTANCE, REFERENCE LINE

(defun c:rl (/ usercmd en1 clay dist)
  ;; -------  Some Housekeeping   ------------------
  (setq usercmd (getvar "CMDECHO"))
  (setvar "CMDECHO" 0)
  (setq clay (getvar 'clayer))
  (command "_.layer" "m" "0" "C" BLACK "" "")
  (setq useros (getvar "osmode"))
  (setvar "osmode" 175)
  (prompt "/nPick points, Enter when done.")
  ;; Draw the pline
  (command "PLINE") ;_ COMMAND
  (while (> (getvar "CMDACTIVE") 0)
    (command pause)
  )
  (setq en1 (entlast))
  (initget 1)
  (setq pto (getpoint "\nSide to offset:"))
  (setq dist (getreal "\nEnter offset distance:"))
  (command "_.offset" dist en1 pto "")
  (entdel en1) ; remove the user drawn line

  ;;==========  Exit Sequence  ============
  (setvar "CMDECHO" usercmd)
  (setvar "clayer" clay)
  ;; Exit quietly
  (princ)

) ;_end of defun

[M-dub]

mdub that is very useful but i am having situations where my fractions in my dimensions are reading in /128" and /64ths of an inch so I guess I need several charts. How did you produce this in 2 minutes :kewl:

Probably using Excel and it's loverly formatting.

You got 'er, Josh.

The explaination will make it sound like a lot of work, but it's really very simple.

All I did was to put the number 1 in cell A1.  Put the cursor in cell A1, then right click & drag the tiny black square at the bottom right corner of it all the way down to cell A256, release the right mouse button and select "Fill Series".  You will then have them all filled out from 1 to 256.

Then, in cell B1, just put "256" and hit enter.  Again, place the cursor back on B1 and double click the tiny black square at the bottom right corner and excel should fill the number "256" all the way down to B256.  (The double click trick will fill whatever you have down to the last adjacent populated cell, if that makes sense)

In cell C1, type "=sum(a1/b1)" and hit enter.  Again, place the cursor back on C1 and double click the tiny black square at the bottom right corner and excel will perform the calculation all the way down, giving you the decimal equivelent.

Now, highlight cells C1 to C256 and hit Ctrl+C.  Place cursor in C1, right click and select Paste Special.  Check "Values" from the popup and hit Ok.

The method I used to get the fraction was to place the cursor in D1 and type "=CONCATENATE(a1,"/",b1)" and hit enter.  Again, place the cursor back on D1 and double click the tiny black square at the bottom right corner and excel will combine the strings from column A, then add the forward slash, followed by the string from column B.  Once that's done, highlight cells D1 to D256 and hit Ctrl+C.  Place cursor in D1, right click and select Paste Special.  Check "Values" from the popup and hit Ok.

Now you can delete columns A and B and you can arrange it however you want.  If you wanted a similar chart for other fractions (*/128, */64, etc.), just change the number 256 in the description above to whatever it is you're looking for and the rest of it still applies.

Clear as mud?

[ELOQUINTET]

ok may have to play around with that later. thanks for the explaination dub

[ELOQUINTET]

mdub i got it created but i'm wondering how you got the justification working when you split it into columns. i tried using concatenate and put a space equal space inside my quotes but it the fractions and decimals are center justified not left justified like yours. how did you combine these?

[M-dub]

Oh yeah!  Forgot about the column I had the equal sign in!  My bad.  That is three separate columns.  Want me to send you the original spreadsheet?

[ELOQUINTET]

or you can just uplaod it here and i'll take a look. thanks

[M-dub]

I emailed it to you a while ago.

(Can't attach .xls files to posts)

[MP]

(Can't attach .xls files to posts)

Can to.

[M-dub]

(Can't attach .xls files to posts)

Can to.

o, I didn't know that.

Actually, I know for a fact that it wasn't possible yesterday.

Thanks MP 

[M-dub]

or you can just uplaod it here and i'll take a look. thanks

Well, there ya go!

[MP]

Actually, I know for a fact that it wasn't possible yesterday.

Wasn't possible until 1 minute ago; hope it's ok with Mark. I tried to guess what he'd do. If the "(perceived) threat is worse than the convenience" I'll have to revert said ability.

:whistle:

Thanks MP

Me pleasure.

[ELOQUINTET]

mdub perhaps i need to go into my profile and change my email as I'm not sure which I have there. I just started a new job and don't check my personal email so that would explain my not receiving it. Thanks MP for all that you do. I won't tell if you don't shhhhhh.

[MP]

Thanks MP for all that you do.

It's a pleasure and honor to be able to help out this community, however small the ways may be, and to be entrusted to same. Priceless. You're most welcome Dan.