Topic: Toggle Xref layers utility ( just give me the fish, I'm hungry )

[Mark]

Anyone have a app that will toggle ( freeze/thaw ) the layer(s) for every xref in the dwg? I'm talking about the layer the xref was inserted on, not every layer in the xref itself.

thanks.

[David Hall]

nope, but i will try to whip something up

[Mark]

nope, but i will try to whip something up

thanks I just don't have time at the moment.

[T.Willey]

Code: [Select]

(defun c:ToggleForMark (/ ActDoc tempLay LayList LayCol LayObj)

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vlax-for blk (vla-get-Blocks ActDoc)
(if (= (vla-get-IsXref blk) :vlax-true)
(foreach lst (entget (vlax-vla-object->ename blk))
(if (equal (car lst) 331)
(if
(not
(vl-position
(setq tempLay (cdr (assoc 8 (entget (cdr lst)))))
LayList
)
)
(setq LayList (cons tempLay LayList))
)
)
)
)
)
(setq LayCol (vla-get-Layers ActDoc))
(foreach name LayList
(setq LayObj (vla-Item LayCol name))
(if (equal (vla-get-Freeze LayObj) :vlax-true)
(vla-put-Freeze LayObj :vlax-false)
(vla-put-Freeze LayObj :vlax-true)
)
)
(princ)
)


[Mark]

thanks a bunch Tim.

PS I've added a "regen" on the end.

[T.Willey]

thanks a bunch Tim.

PS I've added a "regen" on the end.

You're welcome.