Topic: Select everything in modelspace EXCEPT xrefs

[Guest]

How?

I assume I'm going to need some type of selection set, right?  But I'm not sure how to filter out just xrefs.

[deegeecees]

In "Developer Help", do a search on "Relational Tests", this should getcha goin'.

[ronjonp]

Give this a try:

Code: [Select]

(defun getallbutxrefs (/ ss lst)
  (if (setq ss (ssget "x"))
    (progn
      (setq ss (mapcar 'cadr (ssnamex ss)))
      (mapcar '(lambda (x)
(if (and (not (vlax-property-available-p
(vlax-ename->vla-object x)
'Path
       )
  )
  (equal (cdr (assoc 410 (entget x))) "Model")
     )
   (setq lst (cons x lst))
)
       )
      ss
      )
      lst
    )
  )
)
*updated to only select modelspace objects

[Jeff_M]

Cycle through the blocks collection looking for Xrefs. When found, add the names to a string variable such that the final string looks like: "Block1,Block2,Block3" This will be the Name portion of your filter to exclude.

[ASMI]

Or

Code: [Select]

(defun notXRefsList(/ objLst)
  (vl-load-com)
  (vlax-for itm(vla-get-ModelSpace
(vla-get-ActiveDocument
   (vlax-get-acad-object)))
    (if(not(vlax-property-available-p itm 'Path))
      (setq objLst(cons itm objLst))
      ); and if
    ); end vlax -for
  ); end of notXRefsList
Maybe need selection set not list?

[ASMI]

With SelectionSet:

Code: [Select]

(defun notXrefsSet(/ sSet cObj fStr)
  (setq cObj(tblnext "BLOCK" T)
fStr ""); end setq
  (while cObj
    (if(=(logand(cdr(assoc 70 cObj))4)4)
      (setq fStr(strcat fStr(cdr(assoc 2 cObj))","))
      ); end if
      (setq cObj(tblnext "BLOCK"))
    ); end while
  (if(/= fStr "")
    (ssget "_X" (list '(410 . "Model")
  '(-4 . "<NOT")(cons 2 fStr)'(-4 . "NOT>")))
    ); end if
  ); end of notXrefsSet
Does anyone know, is restriction for filter strings length or not? (cons 2 fStr) can be very long if many Xrefs...