Topic: how can I put ActiveViewport layer to freeze

[Dream.Fei]

Code: [Select]

(defun c:test (/ *laysel* layname layobj)
  (setq    layname "test"
*laysel* (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
layobj (vla-item *laysel* layname)
  )
  (vla-put-freeze layobj :vlax-true)
)
This code made layer "Test" to frezze, but I only want freeze it on the activeviewport . how?

[CAB]

http://www.theswamp.org/index.php?topic=4002.msg47771#msg47771

[Dream.Fei]

 
That code is to get.
how about Put?

Code: [Select]

;; put layer on activeviewport to freeze
(defun c:x2 (/ date en ent-date layname lst tmp-date)
  ;;_Freeze layername on this viewport to freeze
  (setq layname "F_LINE")

  ;; viewport Ename
  (setq en (car (entsel "\nSelect ViewPort:")))

  (setq ent-date (entget en))

  ;; list of DXF -3
  (setq date (cdadr (assoc -3 (entget en '("acad")))))

  ;; Remove last 2 part (1002 . }) (1002 .})
  (setq tmp-date (fei-lst-cut date (- (length date) 3) t))

  ;; Freeze Layer
  (setq lst (list (cons 1003 layname) '(1002 . "}") '(1002 . "}")))

  ;; How to update this date?
  (setq tmp-date (list -3 (cons "acad" (append tmp-date lst))))
  (setq ent-date (append ent-date (list tmp-date)))
  (entmod ent-date)
  (entupd en)
  (princ)
)
(defun fei-lst-cut (lst num notif / index loop nlst)
  (setq loop t)
  (if notif
    (setq index -1)
    (setq index 0)
  )
  (while (and loop (cdr lst))
    (setq index (1+ index))
    (setq nlst (cons (car lst) nlst))
    (setq lst (cdr lst))
    (if (= index num)
      (setq loop nil)
    )
  )
  (if notif
    (reverse nlst)
    lst
  )
)
I haved try,but no work....

[Adesu]

Hi Dream.Fei,
How about this code

Code: [Select]

(defun c:test (/ *laysel* layname layobj)
  (setq layname "test")
  (setq *laysel* (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
  ;(vlax-dump-object *laysel*)
  (setq layobj (vla-item *laysel* layname))
  ;(vlax-dump-object layobj)
  (vlax-put layobj 'LayerOn 0)
  )


[Dream.Fei]

Thank you ades.
but not "LayerOn". it's "Freeze on AcitveViewport".

Freeze & On Acitveviewport

[Adesu]

Hi Dream.Fei,
Do you mean like this, I'm not sure.

Code: [Select]

(defun c:test (/ *laysel* layname layobj tm)
  (setq tm (getvar "tilemode"))
  (if
    (> tm 0)
    (setvar "tilemode" 0)
    ) ; if
  (setq layname "test")
  (setq *laysel* (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
  ;(vlax-dump-object *laysel*)
  (setq layobj (vla-item *laysel* layname))
  ;(vlax-dump-object layobj)
  (vlax-put layobj 'Freeze -1)
  ;(setvar "tilemode" tm)
  (princ)
  )


Thank you ades.
but not "LayerOn". it's "Freeze on AcitveViewport".

Freeze & On Acitveviewport

[VVA]

Look command "_.VPLAYER"
As an example - a command freeze  a current layer on all viewports

Code: [Select]

;;_Freeze current layer on all viewport
;;ViewPort Current Layer Freeze
(defun C:VPCLF ( )
(if (zerop (getvar "tilemode"))
  (progn
    (if (/= (getvar "cvport") 1)(command "_.PSPACE"))
    (command "_.VPLAYER" "_Freeze" (getvar "CLAYER") "_ALL" "")
    )
  (princ "\nNot worked in model space")
  )
(princ)
)

[Dream.Fei]

Freeze on all viewport is very easy.
the question is "On Active Viewport" or mean "Select Viewport to freeze some layer on this viewport"

VVA's code can freeze , but I don't want use "Command"

[VVA]

I did not manage to achieve result with usage vla methods

Code: [Select]

(defun C:test ( )
  (setq    layname "test")
(if (zerop (getvar "tilemode"))
  (progn
    (if (/= (getvar "cvport") 1)
      (command "_.VPLAYER" "_Freeze" layname "_current" "")
      (princ "\nSelect viewport")
      )
    )
  (princ "\nNot worked in model space")
  )
(princ)
)

[CAB]

Adesu,
Your code freezes the layer in the drawing and not in the viewport only.

Dream.Fei,
I have not found a way to freeze the layer in the viewport without using the command.

Here is another version that freezes in all other viewports, not the current viewport.

http://www.theswamp.org/index.php?topic=3779.msg45863#msg45863

[Dream.Fei]

Thanks All.

VAA's last reply can modify the layer to freeze on select viewport.

This my lisp code, it isn't I wanted.

Code: [Select]

(defun c:x1 (/ en layname)
  (setvar "cmdecho" 0)
  (setq layname "t")
  (if (zerop (getvar "tilemode"))
    (while (setq en (car (entsel "\nSelect ViewPort Object:")))
      (if (= (cdr (assoc 0 (entget en))) "VIEWPORT")
(vl-cmdf "_.vplayer" "freeze" layname "s" en "" "")
(princ "   ** Selected is't a viewport object , Try again! **")
      )
    )
    (princ "** Not worked in model space **")
  )
  (princ)
)
I hope someone can find other way to freeze layer on select viewport without use command.

thanks.

[SomeCallMeDave]

Here is one that seems to work.  But you have to change back to modelspace or to another layout tab and THEN BACK TO original tab for the results to be apparent.

The programs assumes that you are already in paperspace (among other assumptions).  Error checking is left to the user -

 USE AT YOUR OWN RISK

Code: [Select]

(vl-load-com)
(defun c:lf( )
   
   ;assumes tilemode is currently 0
   (command "pspace")
   (setq VpEntName (car (entsel "\nSelect ViewPort in which to Freeze Layers:"))
         VpNumber (cdr (assoc 69 (entget VpEntName)))
         oVpEnt (vlax-ename->vla-object VpEntName)
         oVpXdata (vlax-invoke-method oVpEnt 'GetXData "ACAD" 'XdataType 'XDataValue)
         xDataUBound (vlax-safearray-get-u-bound xDataType 1)
   );setq
   (command "mspace")
   (if (not (= (getvar "CVPORT") VpNumber))
      (setvar "CVPORT" VpNumber)
   );if   
   (setq FreezeMeEntName (car (entsel "\nSelect Object on Layer to Freeze in Current Vport:"))
         FreezeMeLayerName (cdr (assoc 8 (entget FreezeMeEntName)))
   );setq
   ;;create new xdata arrays
   (setq NewTypeSA (vlax-make-safearray 2 (cons 0 (+ xDataUBound 1)))
         NewValueSA (vlax-make-safearray 12 (cons 0 (+ xDataUBound 1)))
         TypeList (vlax-safearray->list XDataType)
         ValueList (vlax-safearray->list XDataValue)
         ;;append a dummy value to the lists so we can use them on the new SafeArrays
         TypeList2 (append TypeList (list 1002))
         ValueList2 (append ValueList (list (vlax-make-variant "}" 8)))
         
   );setq

   ;fill up the new SA's with existing data
   (vlax-safearray-fill NewTypeSA TypeList2)
   (vlax-safearray-fill NewValueSA ValueList2)
   
   ;;change the 3rd from last element to 1003
   
   ; subtract only 1 since we added an element since we established xDataUBound
   (vlax-safearray-put-element NewTypeSA (- xDataUBound 1) 1003)
   ;change the 3rd from last element to our selected LayerName
   (setq ValVarLayer (vlax-make-variant FreezeMeLayerName 8)   )     
   ; subtract only 1 since we added an element since we established xDataUBound
   (vlax-safearray-put-element NewValueSA (- xDataUBound 1) ValVarLayer)
     
   ;add the new xdata
   (vlax-invoke-method oVpEnt 'SetXData NewTypeSa NewValueSA)
   (vlax-invoke oVpEnt 'Update)
   
   (vlax-release-object oVpEnt)
   (prin1)
 
);lf



And I'm sure the switch from paperspace to modelspace through the viewport can be made more elegant,  but this should give you an idea of what is involved.